CERCA.VERT

 

Se nel foglio di lavoro sono disponibili informazioni note, puoi utilizzare la funzione CERCA.VERT per cercare informazioni correlate per riga. Ad esempio, se vuoi acquistare un'arancia, puoi utilizzare CERCA.VERT per cercare il prezzo.

CERCA.VERT per BigQuery

Ricerca verticale. Restituisce i valori in una colonna di dati che si trovano nella posizione in cui è stata rilevata una corrispondenza nella colonna di ricerca.

Esempi di utilizzo

CERCA.VERT("Mela",nome_tabella!frutto,nome_tabella!prezzo)

Sintassi

CERCA.VERT(chiave_ricerca; intervallo; indice; è_ordinata)

• chiave_ricerca: il valore da ricercare nella colonna di ricerca.
• colonna_ricerca: la colonna di dati da considerare per la ricerca.
• colonna_risultato: la colonna di dati da considerare per il risultato.
• è_ordinata: [FACOLTATIVO] il modo in cui trovare una corrispondenza per la chiave_ricerca.
  • FALSE: consigliato per una corrispondenza esatta.
  • TRUE: valore predefinito per una corrispondenza approssimativa se è_ordinata non è specificato.
    Suggerimento: prima di utilizzare una corrispondenza approssimativa, ordina la chiave di ricerca in ordine crescente. In caso contrario, potresti ottenere un valore restituito errato. Scopri i motivi per cui potresti ottenere un valore restituito errato.

Suggerimento: per query più flessibili sui database in BigQuery, utilizza CERCA.X.

Sintassi

=CERCA.VERT(chiave_ricerca, intervallo, indice, [è_ordinata])

Input

1. chiave_ricerca: il valore da ricercare nella prima colonna dell'intervallo.
2. intervallo: i valori superiore e inferiore da considerare per la ricerca.
3. indice: l'indice della colonna con il valore restituito dell'intervallo. L'indice deve essere un numero intero positivo.
4. è_ordinata: input facoltativo. Scegli un'opzione:
   • FALSE = corrispondenza esatta. Consigliato.
   • TRUE = corrispondenza approssimativa. Impostazione predefinita se il valore è_ordinata non è specificato.
     Importante: prima di utilizzare una corrispondenza approssimativa, ordina la chiave di ricerca in ordine crescente. In caso contrario, potresti ottenere un valore restituito errato. Scopri i motivi per cui potresti riscontrare un valore restituito errato.

Valore restituito

Il primo valore corrispondente dell'intervallo selezionato.

Dettagli tecnici

:

Esempio:

=CERCA.VERT(G9; B4:D8; 3; FALSE)

=CERCA.VERT("Mela", B4:D8, 3, TRUE)

Input	Descrizione
chiave_ricerca	Questo è il valore da ricercare nella prima colonna dell'intervallo. Se prevedi un valore diverso da "errore", la chiave di ricerca deve trovarsi nella prima colonna dell'intervallo. È supportato anche il riferimento di cella. Per eseguire un semplice controllo: se la chiave_ricerca si trova nella posizione B3, l'intervallo deve iniziare con la colonna B.
intervallo	Questo è l'intervallo in cui: La funzione cerca la chiave di ricerca specificata nella prima colonna. CERCA.VERT restituisce il valore dalla colonna specificata dall'indice. Puoi anche utilizzare un intervallo denominato. Per restituire un valore diverso da errore, la chiave di ricerca deve trovarsi nella prima colonna dell'intervallo. Per eseguire un semplice controllo: se la chiave_ricerca si trova nella posizione B3, l'intervallo deve iniziare con la colonna B.
indice	Chiamato anche "Numero colonna". È l'indice della colonna nell'intervallo che contiene il valore restituito. L'indice più piccolo possibile è 1. L'indice più grande possibile corrisponde al numero massimo di colonne in quell'intervallo. Dopo aver configurato l'intervallo, CERCA.VERT esamina solo la colonna della chiave di ricerca, quando l'indice è uguale a 1, o le colonne più a destra. Suggerimento: quando utilizzi la funzione CERCA.VERT, immagina che le colonne dell'intervallo siano numerate da sinistra a destra e inizino con 1.
è_ordinata	Input facoltativo. Le due opzioni disponibili sono TRUE e FALSE. Se è_ordinata è TRUE, CERCA.VERT utilizza una corrispondenza approssimativa. Importante: prima di utilizzare una corrispondenza approssimativa, ordina la chiave di ricerca in ordine crescente. In caso contrario, potresti ottenere un valore restituito imprevisto. Scopri i motivi per cui potresti ottenere un valore restituito errato. Se è_ordinata è FALSE, CERCA.VERT utilizza la corrispondenza esatta. Se è_ordinata non è specificato, il valore è TRUE per impostazione predefinita. Ti consigliamo vivamente di: Utilizzare FALSE per è_ordinata per via del suo comportamento coerente, indipendentemente dal fatto che la colonna della chiave di ricerca sia ordinata o meno. Specificare sempre è_ordinata per una migliore leggibilità, anche se l'input è facoltativo.

 

Output

Descrizione

Valore restituito

Il valore restituito da CERCA.VERT in base ai tuoi input. Esiste un solo valore restituito da ogni funzione CERCA.VERT . Se più valori della chiave di ricerca corrispondono, viene restituito il valore della colonna del valore restituito la cui chiave di ricerca associata corrisponde per prima nella colonna della chiave di ricerca. Se viene restituito #N/A, non è stato trovato alcun valore. Se ottieni un valore o un errore imprevisto, come #N/A o #VALUE!, avvia la risoluzione dei problemi. Se vuoi sostituire #N/A con un altro valore, scopri di più su come utilizzare SE.NON.DISP.() su CERCA.VERT().

Esempi di base di CERCA.VERT:

CERCA.VERT su diverse chiavi di ricerca

Utilizza CERCA.VERT per trovare il prezzo di un arancia e di una mela.

Prova

Spiegazione:

Quando usi la funzione CERCA.VERT, puoi utilizzare diverse chiavi di ricerca, ad esempio "Mela" e "Arancia".

Per restituire un valore diverso da errore, queste chiavi di ricerca devono trovarsi nella prima colonna dell'intervallo. Se non vuoi inserire un valore per le chiavi di ricerca, puoi anche utilizzare un riferimento di cella, ad esempio "G9".

La chiave_ricerca è "Arancia"	=CERCA.VERT("Arancia", B4:D8, 3, FALSE) Valore restituito = $1,01
La chiave_ricerca è "Mela"	=CERCA.VERT("Mela", B4:D8, 3, FALSE) Valore restituito = $1,50
La chiave_ricerca che utilizza il riferimento di cella di "Mela" in G9	=CERCA.VERT(G9; B4:D8; 3; FALSE) Valore restituito = $1,50

CERCA.VERT su diversi indici di colonna

Utilizza CERCA.VERT per trovare la quantità di arance nella seconda colonna di indice.

Prova

Spiegazione:

Quando utilizzi la funzione CERCA.VERT, immagina che le colonne dell'intervallo siano numerate da sinistra a destra e inizino da 1. Per trovare le informazioni di destinazione, devi specificare il relativo indice di colonna. Ad esempio, colonna 2 per la quantità.

Indice = 2 Trova la quantità di arance, ovvero la seconda colonna dell'intervallo.

=CERCA.VERT(G3; B4:D8; 2; FALSE) Valore restituito = 5

Corrispondenza esatta o corrispondenza approssimativa di CERCA.VERT

• Utilizza la corrispondenza esatta di CERCA.VERT per trovare un ID esatto.
• Utilizza la corrispondenza approssimativa di CERCA.VERT per trovare l'ID approssimativo.

Prova

Spiegazione:

Utilizza una corrispondenza approssimativa o è_ordinata = TRUE quando cerchi una corrispondenza migliore, ma non una esatta.

Se vuoi cercare l'ID = 102, che non esiste nella tabella, una corrispondenza approssimativa ti fornisce come risultato l'ID = 101. Questo perché, nella colonna della chiave di ricerca, 101 è il valore più vicino e inferiore a 102.

Una corrispondenza approssimativa esegue una ricerca dall'alto verso il basso nella colonna della chiave di ricerca finché non trova un valore superiore a quello della chiave di ricerca. Si ferma nella riga che precede il valore superiore e restituisce il valore indicato nella colonna Valore restituito su quella riga. Ciò significa che se la colonna della chiave di ricerca non è in ordine crescente, è probabile che il valore restituito sia errato.

Importante: prima di utilizzare una corrispondenza approssimativa, ordina la chiave di ricerca in ordine crescente per restituire il valore corretto. In caso contrario, potresti ottenere un valore restituito imprevisto.

Quando cerchi la corrispondenza esatta, ad esempio è_ordinata = FALSE, viene restituita una corrispondenza esatta. Ad esempio, il nome della frutta per l'ID = 103 è "Banana". Se non esiste una corrispondenza esatta, viene visualizzato un errore #N/A. Dato il suo comportamento più prevedibile, consigliamo di utilizzare la corrispondenza esatta.

Corrispondenza esatta	=CERCA.VERT(G6; A4:D8; 2; FALSE) Valore restituito = "Mela"
Corrispondenza approssimativa	=CERCA.VERT(G3; A4:D8; 2; TRUE) O =CERCA.VERT(G3; A4:D8; 2) Valore restituito = "Banana"

Applicazioni comuni della funzione CERCA.VERT

Sostituire il valore di errore della funzione CERCA.VERT

Può essere consigliabile sostituire un valore di errore restituito da CERCA.VERT quando la chiave di ricerca non esiste. In questo caso, se non vuoi il valore #N/A, puoi usare le funzioni SE.NON.DISP.() per sostituire #N/A. Scopri di più sulle funzioni SE.NON.DISP.().

Prova

Inizialmente, la funzione CERCA.VERT restituisce #N/A perché la chiave di ricerca "Matita" non esiste nella colonna "Frutta". SE.NON.DISP.() sostituisce un errore #N/A con il secondo input specificato nella funzione. Nel nostro caso, si tratta di "NON TROVATO".

=SE.NON.DISP.(CERCA.VERT(G3; B4:D8; 3; FALSE),"NON TROVATO") Valore restituito = "NON TROVATO"

Suggerimento: se vuoi sostituire altri errori come #REF!, scopri di più su SE.ERRORE().

CERCA.VERT con più criteri

La funzione CERCA.VERT non può essere applicata direttamente a più criteri. Crea invece una nuova colonna di supporto per applicare direttamente la funzione CERCA.VERT su più criteri in modo da combinare più colonne esistenti.

Prova

1. Puoi creare una colonna di supporto se utilizzi "&" per combinare Nome e Cognome.	=C4&D4 e trascinalo verso il basso da B4 a B8 per visualizzare la colonna di supporto.
2. Utilizza il riferimento di cella B7, JohnLee, come chiave di ricerca.	=CERCA.VERT(B7; B4:E8; 4; FALSE) Valore restituito = "Supporto"

CERCA.VERT con caratteri jolly o corrispondenze parziali

In CERCA.VERT puoi utilizzare anche caratteri jolly o corrispondenze parziali. Puoi utilizzare i seguenti caratteri jolly:

• Un punto interrogativo "?" corrisponde a qualsiasi carattere singolo.
• Un asterisco "*" corrisponde a qualsiasi sequenza di caratteri.

Per utilizzare i caratteri jolly in CERCA.VERT, devi utilizzare una corrispondenza esatta: "è_ordinata = FALSE".

Prova

"St*" viene utilizzato per trovare qualsiasi corrispondenza che inizi con "St" indipendentemente dal numero di caratteri, ad esempio "Steve", "St1", "Stock" o "Steeeeeeve".

=CERCA.VERT("St*", B4:D8, 3, FALSE) Valore restituito = "Marketing"

Risoluzione degli errori e best practice:

Valore restituito errato

• Restituisce un valore imprevisto: se imposti è_ordinata su TRUE, ma la prima colonna nell'intervallo non è ordinata in ordine numerico o alfabetico crescente, modifica è_ordinata in FALSE.

• CERCA.VERT restituisce la prima corrispondenza: CERCA.VERT restituisce solo la prima corrispondenza. Se disponi di più chiavi di ricerca con corrispondenza, viene restituito un valore che potrebbe non essere quello previsto.
• Dati sporchi: a volte i valori con spazi iniziali e finali possono sembrare simili, ma CERCA.VERT li tratta in modo diverso. Ad esempio, i valori seguenti sono diversi per CERCA.VERT:
  • " Mela"
  • "Mela "
  • "Mela"

Per ottenere i risultati previsti, rimuovi gli spazi prima di utilizzare CERCA.VERT.

Per ulteriori informazioni, consulta la sezione relativa alle best practice.

#N/A

• Se viene utilizzata la corrispondenza approssimativa o è_ordinata = TRUE, e se la chiave di ricerca in CERCA.VERT è inferiore al valore più piccolo nella prima colonna, CERCA.VERT restituisce #N/A.
• Se viene utilizzata la corrispondenza esatta o è_ordinata = FALSE, la corrispondenza esatta della chiave di ricerca in CERCA.VERT non viene trovata nella prima colonna. Se non vuoi il valore #N/A quando la chiave di ricerca non viene trovata nella prima colonna, puoi utilizzare la funzione SE.NON.DISP.().

#REF!

Potresti specificare erroneamente un intervallo con un numero maggiore del numero massimo di colonne dell'intervallo. Per evitare che ciò accada, assicurati di:

• Contare le colonne dell'intervallo selezionato, non dell'intera tabella.
• Inizia a contare da 1 anziché 0.

#VALUE!

Se ottieni l'errore #VALUE! potresti:

• Avere inserito in modo errato il testo o il nome della colonna per l'indice.
• Avere inserito un numero inferiore a 1 per l'indice. Il valore dell'indice deve essere almeno uguale a 1 e inferiore al numero massimo di colonne dell'intervallo. CERCA.VERT può cercare solo nella colonna della chiave di ricerca, quando indice = 1, o nelle colonne più a destra.

Importante: l'indice accetta solo un numero.

#NAME?

• Potrebbero mancare delle virgolette nella chiave di ricerca quando la chiave_ricerca è composta da dati di testo.

Best practice

 

Da fare	Motivo
Utilizzare riferimenti assoluti per l'intervallo.	Cosa utilizzare: Riferimento assoluto per l'intervallo CERCA.VERT CERCA.VERT(G3, $B$3:$D$7, 3, FALSE) Cosa non utilizzare: CERCA.VERT(G3; B3:D7; 3; FALSE) Questo impedisce modifiche imprevedibili nell'intervallo quando viene copiato o trascinato verso il basso.
Ordinare la prima colonna in ordine crescente quando utilizzi una corrispondenza approssimativa, ad esempio is_sorted = TRUE.	Se utilizzi una corrispondenza approssimativa o è_ordinata = TRUE, devi ordinare la prima colonna in ordine crescente. In caso contrario, molto probabilmente otterrai un valore restituito errato. Scopri di più su come ordinare.
Pulire i dati prima di utilizzare CERCA.VERT	Ricordati di pulire i dati prima di utilizzare CERCA.VERT. Dati sporchi possono causare la restituzione di un valore imprevedibile da parte della funzione CERCA.VERT. Ecco alcuni inconvenienti comuni legati ai dati sporchi: Spazi iniziali: " mela" Spazi finali: "mela " Spazi vuoti o spazi: "" e " " non sono equivalenti. Per eliminare gli spazi iniziali e finali, puoi utilizzare Dati Pulizia dei dati Taglia lo spazio vuoto.
Non archiviare numeri o date come testo	Assicurati che i valori di date o numeri nella prima colonna dell'intervallo della funzione CERCA.VERT, ad esempio la colonna della chiave di ricerca, non siano archiviati come valori di testo. Potresti ottenere un valore restituito imprevisto. Nella parte superiore di Fogli, seleziona la colonna della chiave di ricerca. Tocca Menu Formato Numero. Scegli un'opzione in base al tipo di dati desiderato: Data Numero