DÜŞEYARA

 

E-tablonuzda bilinen bilgiler varsa ilgili bilgileri satıra göre aramak için DÜŞEYARA'yı kullanabilirsiniz. Örneğin, portakal satın almak istiyorsanız DÜŞEYARA'yı kullanarak portakalın fiyatını arayabilirsiniz.

BigQuery için DÜŞEYARA

Düşey arama. Veri sütunundaki değerleri, arama sütununda bir eşleşmenin bulunduğu konumda döndürür.

Örnek Kullanım

DÜŞEYARA("Apple";table_name!fruit;table_name!price)

Söz Dizimi

DÜŞEYARA(arama_anahtarı; aralık; dizin; sıralı)

• arama_anahtarı: Arama sütununda aranacak değer.
• arama_sütunu: Aranacak veri sütunu.
• sonuç_sütunu: Sonuç kapsamındaki veri sütunu.
• sıralı: [İSTEĞE BAĞLI] arama_anahtarı için eşleşme bulma yöntemi.
  • YANLIŞ: Tam eşleşme için önerilir.
  • DOĞRU: sıralı belirtilmediyse yaklaşık eşleşme için varsayılan değerdir.
    İpucu: Yaklaşık eşleşme kullanmadan önce arama anahtarınızı artan düzende sıralayın. Aksi takdirde yanlış bir değer döndürülebilir. Neden yanlış bir değer döndürülebileceğini öğrenin.

İpucu: BigQuery'de daha esnek veritabanı sorguları için XLOOKUP işlevini kullanın.

Söz Dizimi

=DÜŞEYARA(arama_anahtarı; aralık; dizin; [sıralı])

Girişler

1. arama_anahtarı: Aralığın ilk sütununda aranacak değerdir.
2. aralık: Arama için dikkate alınacak üst ve alt değerlerdir.
3. dizin: Aralıktaki döndürülen değeri içeren sütunun dizinidir. Dizin, pozitif bir tam sayı olmalıdır.
4. sıralı: İsteğe bağlı giriştir. Bir seçim yapın:
   • YANLIŞ = Tam eşleşmedir. Önerilen değerdir.
   • DOĞRU = Yaklaşık eşleşmedir. sıralı belirtilmediyse varsayılan değerdir.
     Önemli: Yaklaşık eşleşme kullanmadan önce arama anahtarınızı artan düzende sıralayın. Aksi takdirde yanlış bir değer döndürülebilir. Neden yanlış bir değer döndürülebileceğini öğrenin.

Döndürülen değer

Seçilen aralık içindeki eşleşen ilk değerdir.

Teknik ayrıntılar:

Örnek:

=DÜŞEYARA(G9; B4:D8; 3; YANLIŞ)

=DÜŞEYARA("Apple", B4:D8, 3, DOĞRU)

Girişler	Açıklama
arama_anahtarı	İlk aralık sütunda aradığınız değerdir. Hata olmayan bir değer bekliyorsanız arama anahtarı ilk aralık sütununda olmalıdır. Hücre başvurusu da desteklenir. Basit bir kontrol yapmak için: arama_anahtarı B3'te bulunuyorsa aralık B sütunuyla başlamalıdır.
aralık	Bu aralık için: İşlev, ilk sütunundaki belirtilen arama anahtarını arar. DÜŞEYARA, dizin tarafından belirtilen sütundaki değeri döndürür. Dilerseniz adlandırılmış aralık da kullanabilirsiniz. Hata olmayan bir değer döndürülmesi için arama anahtarınız ilk aralık sütununda olmalıdır. Basit bir kontrol yapmak için: arama_anahtarı B3'te bulunuyorsa aralık B sütunuyla başlamalıdır.
dizin	"Sütun numarası" olarak da adlandırılır. Döndürülen değeri içeren aralık içindeki sütunun dizinidir. Olası en küçük dizin 1'dir. Olası en büyük dizin, söz konusu aralık içindeki maksimum sütun sayısıdır. Aralık ayarlandıktan sonra DÜŞEYARA yalnızca arama anahtarı sütununda (dizin = 1 olduğunda) veya daha sağdaki sütunlarda arama yapar. İpucu: DÜŞEYARA'yı kullanıyorsanız aralık sütunlarının soldan sağa doğru numaralandığını ve 1'den başladığını varsayın.
sıralı	İsteğe bağlı bir giriştir. DOĞRU ve YANLIŞ olmak üzere iki seçenek kullanılabilir. sıralı DOĞRU ise DÜŞEYARA'da yaklaşık eşleşme kullanılır. Önemli: Yaklaşık eşleşme kullanmadan önce arama anahtarınızı artan düzende sıralayın. Aksi takdirde, beklenmedik bir değer döndürülebilir. Neden yanlış bir değer döndürülebileceğini öğrenin. sıralı YANLIŞ ise DÜŞEYARA'da tam eşleşme kullanılır. sıralı belirtilmemişse varsayılan olarak DOĞRU olur. Şunları yapmanızı kesinlikle öneririz: Arama anahtarı sütunu sıralı olsa da olmasa da sıralı için tutarlı sonuçlar döndüren YANLIŞ seçeneğini kullanın. Giriş isteğe bağlı olsa da okunabilirliği artırmak için sıralı değerini daima belirtin.

 

Çıkışlar

Açıklama

Döndürülen değer

DÜŞEYARA'nın girişlerinize göre döndürdüğü değerdir. Her DÜŞEYARA işlevi yalnızca bir değer döndürür. Eşleşen birden fazla arama anahtarı değeri varsa döndürülen değer sütununda bulunan ve arama anahtarı sütunundaki arama anahtarıyla ilk eşleşen değer döndürülür. #N/A döndürülürse bir değer bulunmamış demektir. Beklenen bir değerle veya #N/A ya da #VALUE! gibi bir hatayla karşılaşırsanız sorun gidermeye başlayın. #N/A değerini başka bir değerle değiştirmek istiyorsanız DÜŞEYARA() işlevinde EĞERYOKSA() işlevini nasıl kullanacağınız hakkında daha fazla bilgi edinin.

DÜŞEYARA ile ilgili başlıca örnekler:

Farklı arama anahtarlarında DÜŞEYARA işlevi

"Orange" (Portakal) ve "Apple"ın (Elma) fiyatını bulmak için DÜŞEYARA'yı kullanın.

Deneyin

Açıklama:

DÜŞEYARA işlevinde "Apple" ve "Orange" gibi farklı arama anahtarları kullanabilirsiniz.

Hata olmayan bir değer döndürülmesi için bu arama anahtarları ilk aralık sütununda olmalıdır. Arama anahtarları için değer girmek istemiyorsanız "G9" gibi bir hücre başvurusu da kullanabilirsiniz.

arama_anahtarı = "Orange"	=DÜŞEYARA("Orange"; B4:D8; 3; YANLIŞ) Döndürülen değer = $1.01
arama_anahtarı = "Apple"	=DÜŞEYARA("Apple"; B4:D8; 3; YANLIŞ) Döndürülen değer = $1.50
Hücre başvurusu olarak G9'daki "Apple" değerinin kullanıldığı arama_anahtarı	=DÜŞEYARA(G9; B4:D8; 3; YANLIŞ) Döndürülen değer = $1.50

Farklı sütun dizinlerinde DÜŞEYARA işlevi

İkinci dizin sütununda "Orange" miktarını bulmak için DÜŞEYARA'yı kullanın.

Deneyin

Açıklama:

DÜŞEYARA'yı kullanıyorsanız aralık sütunlarının soldan sağa doğru numaralandığını ve 1'den başladığını varsayın. Bulmak istediğiniz bilginin sütun dizinini belirtmeniz gerekir. Örneğin, miktar için 2. sütunu belirtin.

Dizin = 2 İkinci aralık sütununda yer alan "Orange" miktarını bulun.

=DÜŞEYARA(G3; B4:D8; 2; YANLIŞ) Döndürülen değer = 5

DÜŞEYARA'da tam eşleşme veya yaklaşık eşleşme

• Tam eşleşen kimliği bulmak için DÜŞEYARA'da tam eşleşme kullanın.
• Yaklaşık eşleşen kimliği bulmak için DÜŞEYARA'da yaklaşık eşleşme kullanın.

Deneyin

Açıklama:

Tam eşleşme yerine en iyi eşleşmeyi arıyorsanız yaklaşık eşleşme veya sıralı = DOĞRU seçeneğini kullanın.

Tabloda bulunmayan 102 kimliğini aramak istiyorsanız yaklaşık eşleşme kullandığınızda sonuç olarak bir önceki 101 kimliği döndürülür. Bunun nedeni, arama anahtarı sütununda 101'in, 102'den küçük olan en büyük değer olmasıdır.

Yaklaşık eşleşme kullanırsanız arama anahtarınızdan daha yüksek bir değer bulunana kadar arama anahtarı sütununda arama yapılır. Arama, daha yüksek değerden önceki satırda durur ve bu satırın döndürülen değer sütunundaki değeri döndürür. Bu durum, arama anahtarı sütununuz artan düzende sıralı değilse büyük olasılıkla yanlış bir değer döndürüleceği anlamına gelir.

Önemli: Doğru değerin döndürülebilmesi için, yaklaşık eşleşme kullanmadan önce arama anahtarınızı artan düzende sıralayın. Aksi takdirde, beklenmedik bir değer döndürülebilir.

Tam eşleşmeyi (ör. sıralı = YANLIŞ) arıyorsanız tam eşleşme döndürülür. Örneğin, kimliği 103 olan meyvenin adı "Banana"dır (Muz). Tam eşleşme yoksa #N/A hatası alırsınız. Daha tahmin edilebilir sonuçlar döndürdüğü için tam eşleşmeyi kullanmanızı öneririz.

Tam eşleşme	=DÜŞEYARA(G6; A4:D8; 2; YANLIŞ) Döndürülen değer = "Apple"
Yaklaşık eşleşme	=DÜŞEYARA(G3; A4:D8; 2; DOĞRU) VEYA =DÜŞEYARA(G3; A4:D8; 2) Döndürülen değer = "Banana"

Sık kullanılan DÜŞEYARA uygulamaları

DÜŞEYARA'daki hata değerini değiştirme

Arama anahtarınız olmadığında DÜŞEYARA'nın döndürdüğü bir hata değerini değiştirmek isteyebilirsiniz. Bu durumda, #N/A değerini istemiyorsanız bu değeri değiştirmek için EĞERYOKSA() işlevlerini kullanabilirsiniz. EĞERYOKSA() işlevleri hakkında daha fazla bilgi edinin.

Deneyin

İlk başta "Pencil" (Kalem) arama anahtarı, "Fruit" (Meyve) sütununda yer almadığı için DÜŞEYARA işlevi #N/A değerini döndürür. EĞERYOKSA(), #N/A hatasını işlevde belirtilen ikinci girişle değiştirir. Burada örnek olarak "NOT FOUND" (BULUNAMADI) girişi verilmiştir.

=EĞERYOKSA(DÜŞEYARA(G3; B4:D8; 3; YANLIŞ);"NOT FOUND") Döndürülen değer = "NOT FOUND"

İpucu: #REF! gibi diğer hataları değiştirmek istiyorsanız EĞERHATA() işlevi hakkında daha fazla bilgi edinin.

DÜŞEYARA'da birden fazla ölçüt

DÜŞEYARA işlevi birden fazla ölçüte doğrudan uygulanamaz. Bunun yerine, mevcut birden fazla sütunu birleştirmek amacıyla DÜŞEYARA'yı birden fazla ölçüte doğrudan uygulamak için yeni bir "Helper" (Yardımcı) sütunu oluşturun.

Deneyin

1. First Name (Ad) ve Last Name (Soyadı) sütunlarını birleştirmek için "&" karakterini kullanarak bir "Helper" sütunu oluşturabilirsiniz.	=C4&D4 yazıp B4'ten B8'e doğru sürükleyerek "Helper" sütununu oluşturabilirsiniz.
2. Arama anahtarı olarak B7 hücre başvurusunu (JohnLee) kullanın.	=DÜŞEYARA(B7; B4:E8; 4; YANLIŞ) Döndürülen değer = "Support"

DÜŞEYARA'da joker karakterler veya kısmi eşleşmeler

DÜŞEYARA işlevinde joker karakterler veya kısmi eşleşmeler de kullanabilirsiniz. Şu joker karakterler kullanılabilir:

• Soru işareti (?) tek bir karakterle eşleşir.
• Yıldız işareti (*) bir karakter dizisiyle eşleşir.

DÜŞEYARA'da joker karakter kullanmak için tam eşleşme kullanmanız gerekir: "sıralı = YANLIŞ".

Deneyin

"St*" değeri, karakter sayısı fark etmeksizin "St" ile başlayan tüm değerlerle (ör. "Steve", "St1", "Stock" veya "Steeeeeeve") eşleşir.

=DÜŞEYARA("St*"; B4:D8; 3; YANLIŞ) Döndürülen değer = "Marketing"

Sorun giderme ve en iyi uygulamalar:

Döndürülen değerin yanlış olması

• Beklenmeyen bir değer döndürülmesi: sıralı'yı DOĞRU olarak ayarlamanıza rağmen aralıktaki ilk sütununuz sayısal veya alfabetik olarak artan düzende sıralı değilse sıralı ayarını YANLIŞ olarak değiştirin.

• DÜŞEYARA'nın ilk eşleşmeyi döndürmesi: DÜŞEYARA yalnızca ilk eşleşmeyi döndürür. Eşleşen birden fazla arama anahtarınız varsa bir değer döndürülür ancak bu, beklediğiniz değer olmayabilir.
• Verilerin temiz olmaması: Başında veya sonunda boşluk olan değerler benzer görünse de bunlar DÜŞEYARA işlevinde farklı şekilde ele alınır. Örneğin, aşağıdakiler DÜŞEYARA işlevi için farklı değerlerdir:
  • " Apple"
  • "Apple "
  • "Apple"

Beklediğiniz sonuçların döndürülebilmesi için DÜŞEYARA'yı kullanmadan önce boşlukları kaldırın.

Daha fazla bilgi edinmek için en iyi uygulamalar bölümüne göz atın.

#N/A

• Yaklaşık eşleşme veya sıralı = DOĞRU seçeneğini kullanıyorsanız ve DÜŞEYARA'daki arama anahtarı ilk sütundaki en küçük değerden azsa DÜŞEYARA işlevi #N/A değerini döndürür.
• Tam eşleşme veya sıralı = YANLIŞ seçeneğini kullanıyorsanız DÜŞEYARA'daki arama anahtarının tam eşleşmesi ilk sütunda bulunamaz. Arama anahtarı ilk sütunda bulunamadığında #N/A değerinin döndürülmesini istemiyorsanız EĞERYOKSA() işlevini kullanabilirsiniz.

#REF!

Yanlışlıkla aralık içindeki maksimum sütun sayısından büyük bir sayı içeren bir aralık belirtebilirsiniz. Bunun olmaması için:

• Tüm tablodaki değil, seçilen aralık içindeki sütunları sayın.
• Saymaya 0 yerine 1'den başlayın.

#VALUE!

#VALUE! hatasını almanız aşağıdakilerin göstergesi olabilir:

• dizin için metin veya sütun adı yanlış girilmiştir.
• dizin için 1'den küçük bir sayı girilmiştir. dizin en az 1'e eşit ve aralık içindeki maksimum sütun sayısından küçük olmalıdır. DÜŞEYARA yalnızca arama anahtarı sütununda (dizin = 1 olduğunda) veya daha sağdaki sütunlarda arama yapabilir.

Önemli: dizin için yalnızca sayı kabul edilir.

#NAME?

• arama_anahtarı metin verilerinden oluşuyorsa arama anahtarında tırnak işareti eksik olabilir.

En iyi uygulamalar

 

Yapılacaklar	Neden
aralık için mutlak başvurular kullanın.	Şunları kullanmalısınız: DÜŞEYARA aralığı için mutlak referans DÜŞEYARA(G3; $B$3:$D$7; 3; YANLIŞ) Şunu kullanmamalısınız: DÜŞEYARA(G3; B3:D7; 3; YANLIŞ) Bu sayede, kopyalanan veya aşağı sürüklenen aralık içinde öngörülemeyen değişiklikler yapılması engellenir.
Yaklaşık eşleşme kullanıyorsanız (ör. sıralı = DOĞRU) ilk sütunu artan düzende sıralayın.	Yaklaşık eşleşme veya sıralı = DOĞRU seçeneğini kullanıyorsanız ilk sütunu artan düzende sıralamanız gerekir. Aksi takdirde büyük olasılıkla yanlış bir değer döndürülür. Nasıl sıralama yapacağınız hakkında daha fazla bilgi edinin.
DÜŞEYARA işlevini kullanmadan önce verilerinizi temizleyin.	DÜŞEYARA işlevini kullanmadan önce verilerinizi temizlemeyi unutmayın. Veriler temiz olmazsa DÜŞEYARA işlevi öngörülemeyen bir değer döndürebilir. Temiz olmayan verilere yol açan bazı yaygın hatalar aşağıda verilmiştir: Değerin başında boşluk olması: " apple" Değerin sonunda boşluk olması: "apple " Boş değerler veya boşluklar: "" ve " " aynı değildir. Baştaki ve sondaki boşlukları kaldırmak için Veri Veri temizliği Boşlukları kaldır'ı kullanabilirsiniz.
Sayı veya tarih değerlerini metin olarak depolamayın.	DÜŞEYARA aralığınızın ilk sütunundaki tarih veya sayı değerlerinin (ör. arama anahtarı sütunu) metin değeri olarak depolanmadığından emin olun. Aksi takdirde beklenmeyen bir değer döndürülebilir. E-Tablolar'ın en üst kısmında arama anahtarı sütununuzu seçin. Biçim menüsü Sayı'ya dokunun. İstediğiniz veri türüne bağlı olarak bir seçenek belirleyin: Tarih Sayı