PROCV

 

Se tiver informações conhecidas na folha de cálculo, pode usar a função PROCV para pesquisar informações relacionadas por linha. Por exemplo, se quiser comprar uma laranja, pode usar a função PROCV para pesquisar o preço.

PROCV para o BigQuery

Pesquisa vertical. Devolve os valores numa coluna de dados na posição em que uma correspondência foi encontrada na coluna de pesquisa.

Exemplos de utilização

PROCV("Apple";nome_da_tabela!fruta;nome_da_tabela!preço)

Sintaxe

PROCV(chave_pesquisa; intervalo;índice; é_ordenado)

• chave_pesquisa: o valor a pesquisar na coluna de pesquisa.
• coluna_pesquisa: a coluna de dados a considerar para a pesquisa.
• coluna_resultado: a coluna de dados a considerar para o resultado.
• é_ordenado: [OPCIONAL] a forma como se encontra uma correspondência para o argumento chave_pesquisa.
  • FALSO: esta opção é recomendada para uma correspondência exata.
  • VERDADEIRO: para uma correspondência aproximada, esta é a predefinição se o argumento é_ordenado não estiver especificado.
    Sugestão: antes de usar uma correspondência aproximada, ordene a chave de pesquisa por ordem ascendente. Caso contrário, é provável que obtenha um valor devolvido incorreto. Saiba por que motivo pode obter um valor devolvido incorreto.

Sugestão: para consultas de bases de dados mais flexíveis no BigQuery, use a função PROCV.

Sintaxe

=PROCV(chave_pesquisa; intervalo; índice; [é_ordenado])

Entradas

1. chave_pesquisa: o valor a pesquisar na primeira coluna do intervalo.
2. intervalo: os valores superior e inferior a considerar para a pesquisa.
3. índice: o índice da coluna com o valor devolvido do intervalo. O índice tem de ser um número inteiro positivo.
4. é_ordenado: entrada opcional. Escolha uma opção:
   • FALSO = correspondência exata. Esta opção é recomendada.
   • VERDADEIRO = correspondência aproximada. Esta é a predefinição se o argumento é_ordenado não estiver especificado.
     Importante: antes de usar uma correspondência aproximada, ordene a chave de pesquisa por ordem ascendente. Caso contrário, é provável que obtenha um valor devolvido incorreto. Saiba por que motivo pode obter um valor devolvido incorreto.

Valor devolvido

O primeiro valor correspondente do intervalo selecionado.

Detalhes técnicos:

Exemplo:

=PROCV(G9; B4:D8; 3; FALSO)

=PROCV("Apple"; B4:D8; 3; VERDADEIRO)

Entradas	Descrição
chave_pesquisa	Este é o valor que pesquisa na primeira coluna do intervalo. Se esperar um valor que não seja um erro, a chave de pesquisa tem de estar na primeira coluna do intervalo. A referência de célula também é suportada. Para fazer uma verificação simples: se chave_pesquisa estiver localizado em B3, o intervalo deve começar na coluna B.
intervalo	Este é o intervalo em que: A função pesquisa a chave de pesquisa especificada na respetiva primeira coluna. A função PROCV devolve o valor da coluna especificada pelo índice. Também pode usar um intervalo com nome. Para devolver um valor que não seja um erro, a chave de pesquisa tem de estar na primeira coluna do intervalo. Para fazer uma verificação simples: se chave_pesquisa estiver localizado em B3, o intervalo deve começar na coluna B.
índice	Também denominado "Número de coluna". Este é o índice da coluna no intervalo que contém o valor devolvido. O índice mais pequeno possível é 1. O maior índice possível é o número máximo de colunas nesse intervalo. Depois de configurar o intervalo, a função PROCV analisa apenas a coluna da chave de pesquisa, quando índice = 1, ou as colunas mais à direita. Sugestão: quando usar a função PROCV, imagine que as colunas do intervalo estão numeradas da esquerda para a direita e começam em 1.
é_ordenado	Esta é uma entrada opcional. As duas opções disponíveis são VERDADEIRO e FALSO. Se é_ordenado for VERDADEIRO, a função PROCV usa uma correspondência aproximada. Importante: antes de usar uma correspondência aproximada, ordene a chave de pesquisa por ordem ascendente. Caso contrário, pode ser devolvido um valor inesperado. Saiba por que motivo pode obter um valor devolvido incorreto. Se é_ordenado for FALSO, a função PROCV usa uma correspondência exata. Se é_ordenado não estiver especificado, é VERDADEIRO por predefinição. Recomendamos vivamente que: Use FALSO para é_ordenado devido ao respetivo comportamento consistente, independentemente de a coluna da chave de pesquisa estar ou não ordenada. Especifique sempre é_ordenado para uma melhor legibilidade, mesmo que a entrada seja opcional.

 

Saídas

Descrição

Valor devolvido

Este é o valor que a função PROCV devolve com base nas suas entradas. Existe apenas um valor devolvido de cada função PROCV. Se existirem vários valores de chave de pesquisa correspondentes, é devolvido o valor na coluna do valor devolvido cuja chave de pesquisa associada tem a primeira correspondência na coluna da chave de pesquisa. Se for devolvido o erro #N/A, não é encontrado nenhum valor. Se encontrar um valor ou um erro inesperado como #N/A ou #VALUE!, dê início à resolução do problema. Se quiser substituir #N/A por outro valor, saiba como usar a função SEND() na função PROCV().

Exemplos básicos da função PROCV:

PROCV em chaves de pesquisa diferentes

Use a função PROCV para encontrar o preço de uma laranja (Orange) e de uma maçã (Apple).

Experimentar

Explicação:

Quando usa a função PROCV, pode usar diferentes chaves de pesquisa, como "Apple" e "Orange".

Para devolver um valor que não seja um erro, estas chaves de pesquisa têm de estar na primeira coluna do intervalo. Se não quiser preencher um valor para chaves de pesquisa, também pode usar uma referência de célula, por exemplo "G9".

A chave_pesquisa é "Orange"	=PROCV("Orange"; B4:D8; 3; FALSO) Valor devolvido = 1,01 $
A chave_pesquisa é "Apple"	=PROCV("Apple"; B4:D8; 3; FALSO) Valor devolvido = 1,50 $
A chave_pesquisa que usa a referência de célula de "Apple" em G9	=PROCV(G9; B4:D8; 3; FALSO) Valor devolvido = 1,50 $

PROCV em índices de colunas diferentes

Use a função PROCV para encontrar a quantidade de laranjas na segunda coluna de índice.

Experimentar

Explicação:

Quando usar a função PROCV, imagine que as colunas do intervalo estão numeradas da esquerda para a direita e começam em 1. Para encontrar as informações pretendidas, tem de especificar o índice de colunas correspondente. Por exemplo, a coluna 2 para quantidade.

Índice = 2 Encontre a quantidade de laranjas, que é a segunda coluna do intervalo.

=PROCV(G3; B4:D8; 2; FALSO) Valor devolvido = 5

Correspondência exata ou correspondência aproximada da função PROCV

• Use a correspondência exata da função PROCV para encontrar um ID exato.
• Use a correspondência aproximada da função PROCV para encontrar o ID aproximado.

Experimentar

Explicação:

Use uma correspondência aproximada ou é_ordenado = VERDADEIRO quando pesquisar uma melhor correspondência, mas não uma correspondência exata.

Se quiser pesquisar ID = 102, que não existe na tabela, uma correspondência aproximada retrocede uma célula e indica ID = 101 como resultado. Isto deve-se ao facto de na coluna da chave de pesquisa 101 ser o valor mais próximo que também é inferior a 102.

Uma correspondência aproximada pesquisa na coluna da chave de pesquisa até encontrar um valor superior ao da chave de pesquisa. Em seguida, para na linha antes do valor maior e devolve o valor da coluna do valor devolvido nessa linha. Isto significa que, se a coluna da chave de pesquisa não estiver ordenada por ordem ascendente, é provável que obtenha um valor devolvido incorreto.

Importante: antes de usar uma correspondência aproximada, ordene a chave de pesquisa por ordem ascendente para devolver o valor correto. Caso contrário, pode ser devolvido um valor inesperado.

Quando pesquisa a correspondência exata, como é_ordenado = FALSO, devolve uma correspondência exata. Por exemplo, o nome da fruta para ID = 103 é "Banana". Se não existir uma correspondência exata, recebe um erro #N/A. Devido ao comportamento mais previsível, recomendamos que use a correspondência exata.

Correspondência exata	=PROCV(G6; A4:D8; 2; FALSO) Valor devolvido = "Apple"
Correspondência aproximada	=PROCV(G3; A4:D8; 2; VERDADEIRO) OU =PROCV(G3; A4:D8; 2) Valor devolvido = "Banana"

Aplicações comuns da função PROCV

Substitua o valor de erro de PROCV

É recomendável substituir um valor de erro devolvido pela função PROCV quando a chave de pesquisa não existe. Neste caso, se não quiser obter o erro #N/A, pode usar a função SEND() para substituir #N/A. Saiba mais sobre a função SEND().

Experimentar

Originalmente, a função PROCV devolve o erro #N/A porque a chave de pesquisa "Pencil" não existe na coluna "Fruit". A função SEND() substitui o erro #N/A pela segunda entrada especificada na função. No nosso caso, é "NÃO ENCONTRADO".

=SEND(PROCV(G3; B4:D8; 3; FALSO);"NÃO ENCONTRADO") Valor devolvido = "NÃO ENCONTRADO"

Sugestão: se quiser substituir outros erros, como #REF!, saiba mais sobre a função SE.ERRO().

PROCV com vários critérios

Não é possível aplicar diretamente a função PROCV a vários critérios. Em vez disso, crie uma nova coluna auxiliar para aplicar diretamente a função PROCV a vários critérios para combinar várias colunas existentes.

Experimentar

1. Pode criar uma coluna Auxiliar se usar "&" para combinar o nome próprio (First Name) e o apelido (Last Name).	=C4&D4 e arrastar para baixo de B4 para B8 apresenta a coluna auxiliar.
2. Use a referência de célula B7, JohnLee, como a chave de pesquisa.	=PROCV(B7; B4:E8; 4; FALSO) Valor devolvido = "Support"

Função PROCV com carateres universais ou correspondências parciais

Na função PROCV, também pode usar carateres universais ou correspondências parciais. Pode usar estes carateres universais:

• Um ponto de interrogação "?" corresponde a qualquer caráter individual.
• Um asterisco "*" corresponde a qualquer sequência de carateres.

Para usar carateres universais na função PROCV, tem de usar uma correspondência exata: "é_ordenado = FALSO".

Experimentar

"St*" é usado para corresponder a tudo o que comece por "St" independentemente do número de carateres, como "Steve", "St1", "Stock" ou "Steeeeeeve".

=PROCV("St*"; B4:D8; 3; FALSO) Valor devolvido = "Marketing"

Resolução de erros e práticas recomendadas:

Valor devolvido incorreto

• Devolve um valor inesperado: se definir é_ordenado como VERDADEIRO, mas a primeira coluna no intervalo não estiver ordenada numérica ou alfabeticamente por ordem ascendente, altere é_ordenado para FALSO.

• A função PROCV apresenta a primeira correspondência: a função PROCV devolve apenas a primeira correspondência. Se tiver várias chaves de pesquisa com correspondência, é devolvido um valor, mas pode não ser o valor esperado.
• Dados não limpos: por vezes, os valores com espaços à frente e atrás podem parecer semelhantes, mas a função PROCV trata-os de forma diferente. Por exemplo, os exemplos seguintes são considerados diferentes para a função PROCV:
  • " Apple"
  • "Apple "
  • "Apple"

Para obter os resultados esperados, remova os espaços antes de usar a função PROCV.

Para saber mais, consulte a nossa secção de práticas recomendadas.

#N/A

• Se aproximado ou é_ordenado = VERDADEIRO for usado e se a chave de pesquisa na função PROCV for inferior ao valor mais pequeno na primeira coluna, a função PROCV devolve o erro #N/A.
• Se correspondência exata ou é_ordenado = FALSO for usado, a correspondência exata da chave de pesquisa na função PROCV não é encontrada na primeira coluna. Se não quiser obter o erro #N/A quando a chave de pesquisa não é encontrada na primeira coluna, pode usar a função SEND().

#REF!

Pode especificar por engano um intervalo com um número superior ao número máximo de colunas do intervalo. Para evitar esta situação, certifique-se de que:

• Conta as colunas do intervalo selecionado e não da tabela inteira.
• Começa a contar a partir de 1 em vez de 0.

#VALUE!

Se obtiver o erro #VALUE!, pode ter:

• Introduzido incorretamente o texto ou o nome da coluna para o índice.
• Introduzido um número inferior a 1 para o índice. O índice tem de ser, pelo menos, igual a 1 e inferior ao número máximo de colunas do intervalo. A função PROCV só pode pesquisar na coluna de chave de pesquisa, quando índice = 1, nas ou colunas que estão mais à direita.

Importante: o índice só aceita um número.

#NAME?

• Pode-se ter esquecido de aspas na chave de pesquisa quando chave_pesquisa são dados de texto.

Práticas recomendadas

 

A fazer	Motivo
Use referências absolutas para o intervalo	Deve usar: Referência absoluta para o intervalo da função PROCV PROCV(G3; $B$3:$D$7; 3; FALSO) Não deve usar: PROCV(G3; B3:D7; 3; FALSO) Isto impede alterações imprevisíveis no intervalo quando é copiado ou arrastado para baixo.
Ordene a primeira coluna por ordem ascendente quando usar uma correspondência aproximada, como é_ordenado = VERDADEIRO.	Se usar uma correspondência aproximada ou é_ordenado = VERDADEIRO, tem de ordenar a primeira coluna por ordem ascendente. Caso contrário, é muito provável que obtenha um valor devolvido incorreto. Saiba como ordenar.
Limpe os dados antes de usar a função PROCV	Antes de usar a função PROCV, não se esqueça de limpar os dados. Dados não limpos podem fazer com que a função PROCV devolva um valor imprevisível. Seguem-se alguns problemas comuns de dados não limpos: Espaços atrás: " apple" Espaços à frente: "apple " Espaços em branco ou espaços: "" e " " não são equivalentes Para cortar espaços em branco à frente e atrás, pode usar a opção Dados Limpeza de dados Cortar espaços em branco.
Não armazene valores de número ou data como texto	Certifique-se de que os valores de data ou número na primeira coluna do intervalo PROCV, como a coluna de chave de pesquisa, não estão armazenados como valores de texto. Pode obter um valor devolvido inesperado. Na parte superior do Sheets, selecione a coluna da chave de pesquisa. Toque em Menu Formatar Número. Escolha uma opção consoante o tipo de dados pretendido: Data Número