BUSCARV

 

Si tienes información conocida en la hoja de cálculo, puedes usar BUSCARV para buscar información relacionada por fila. Por ejemplo, si quieres comprar una naranja, puedes utilizar BUSCARV para dar con el precio.

BUSCARV para BigQuery

Búsqueda vertical. Devuelve los valores de una columna de datos en la posición donde se haya encontrado una coincidencia en la columna de búsqueda.

Ejemplos de uso

=BUSCARV("Manzana";nombre_tabla!fruta;nombre_tabla!precio)

Sintaxis

BUSCARV(valor_búsqueda; intervalo; índice; está_ordenado)

• valor_búsqueda: valor que quieres buscar en la columna de búsqueda.
• columna_búsqueda: columna de datos que se debe tener en cuenta en la búsqueda.
• columna_resultado: columna de datos que se debe tener en cuenta para el resultado.
• está_ordenado (OPCIONAL): modo de buscar una coincidencia con valor_búsqueda.
  • FALSO: valor recomendado para encontrar una coincidencia exacta.
  • VERDADERO: para encontrar una coincidencia aproximada. Este es el valor predeterminado cuando está_ordenado no se ha especificado.
    Consejo: Antes de usar una coincidencia aproximada, ordena tus valores de búsqueda en orden ascendente. De lo contrario, es posible que se devuelva un valor incorrecto. Consulta por qué puedes obtener un valor incorrecto.

Consejo: Para enviar consultas más flexibles a una base de datos en BigQuery, usa XLOOKUP.

Sintaxis

=BUSCARV(valor_búsqueda; intervalo; índice; [está_ordenado])

Entradas

1. valor_búsqueda: valor que quieres buscar en la primera columna del intervalo.
2. intervalo: valores superior e inferior que se deben tener en cuenta en la búsqueda.
3. índice: índice de la columna con el valor que se devuelve del intervalo. El índice debe ser un número entero positivo.
4. está_ordenado: entrada opcional. Elige una opción:
   • FALSO = coincidencia exacta. Esta es la opción recomendada.
   • VERDADERO = coincidencia aproximada. Es la opción predeterminada si está_ordenado no se especifica.
     Importante: Antes de usar una coincidencia aproximada, ordena tus valores de búsqueda en orden ascendente. De lo contrario, es posible que se devuelva un valor incorrecto. Consulta por qué puedes recibir un valor incorrecto.

Valor devuelto

El primer valor coincidente del intervalo seleccionado.

Información técnica

Ejemplo:

=BUSCARV(G9; B4:D8; 3; FALSO)

=BUSCARV("Manzana"; B4:D8; 3; VERDADERO)

Entradas	Descripción
valor_búsqueda	Es el valor que buscas en la primera columna del intervalo. Si esperas obtener un valor sin errores, el valor de búsqueda debe estar en la primera columna del intervalo. También se admite la referencia de la celda. Haz una comprobación sencilla: si tu valor_búsqueda está en B3, tu intervalo debería empezar por la columna B.
intervalo	Este es el intervalo en el que: La función busca el valor de búsqueda especificado en su primera columna. BUSCARV devuelve el valor de la columna especificada por índice. También puedes usar un intervalo con nombre. Para que se devuelva un valor sin errores, el valor de búsqueda debe estar en la primera columna del intervalo. Haz una comprobación sencilla: si tu valor_búsqueda está en B3, tu intervalo debería empezar por la columna B.
índice	También se denomina "número de columna". Es el índice de la columna del intervalo que contiene el valor que se devuelve. El índice más pequeño posible es 1. El índice más grande es el número máximo de columnas de ese intervalo. Una vez que has configurado el intervalo, BUSCARV solo busca en la columna del valor de búsqueda, cuando el índice = 1, o en las columnas que están más a la derecha. Consejo: Cuando uses BUSCARV, imagina que las columnas del intervalo están numeradas de izquierda a derecha y empiezan por 1.
está_ordenado	Esta es una entrada opcional. Sus dos valores son VERDADERO y FALSO. Si el valor de está_ordenado es VERDADERO, BUSCARV utiliza una coincidencia aproximada. Importante: Antes de usar una coincidencia aproximada, ordena tus valores de búsqueda en orden ascendente. De lo contrario, es posible que se devuelva un valor inesperado. Consulta por qué puedes obtener un valor incorrecto. Si el valor de está_ordenado es FALSO, BUSCARV utiliza una coincidencia exacta. Si está_ordenado no se especifica, el valor predeterminado es VERDADERO. Te recomendamos lo siguiente: Usa FALSO para está_ordenado, ya que ofrece resultados coherentes independientemente de si la columna del valor de búsqueda está ordenada o no. Especifica siempre está_ordenado para facilitar la lectura, aunque se trate de una entrada opcional.

 

Resultados

Descripción

Valor devuelto

Es el valor que devuelve BUSCARV según los datos que hayas introducido. Solo se devuelve un valor por cada función BUSCARV. Si hay varios valores de búsqueda coincidentes, el valor que se devolverá será el de la columna del valor devuelto cuyo valor de búsqueda asociado sea la primera coincidencia de la columna del valor de búsqueda. Si no se encuentra ningún valor, se devolverá #N/A. Si encuentras un valor o un error inesperados, como #N/A o #VALUE!, empieza a solucionar los problemas. Si quieres sustituir #N/A por otro valor, consulta más información sobre cómo usar SI.ND() en BUSCARV().

Ejemplos básicos de BUSCARV:

BUSCARV en diferentes valores de búsqueda

Usa BUSCARV para buscar el precio de una naranja y una manzana.

Pruébalo

Explicación

Con BUSCARV, puedes usar diferentes valores de búsqueda, como "Manzana" y "Naranja".

Para que se devuelva un valor sin errores, estos valores de búsqueda deben estar en la primera columna del intervalo. Si no quieres introducir un valor para los valores de búsqueda, también puedes usar una referencia a una celda, como "G9".

valor_búsqueda es "Naranja"	=BUSCARV("Naranja"; B4:D8; 3; FALSO) Valor devuelto = 1,01 $
valor_búsqueda es "Manzana"	=BUSCARV("Manzana"; B4:D8; 3; FALSO) Valor devuelto = 1,50 $
valor_búsqueda que usa la referencia de celda de "Manzana" en G9	=BUSCARV(G9; B4:D8; 3; FALSO) Valor devuelto = 1,50 $

BUSCARV en diferentes índices de columnas

Usa BUSCARV para buscar la cantidad de naranjas en la segunda columna del índice.

Pruébalo

Explicación

Cuando uses BUSCARV, imagina que las columnas del intervalo están numeradas de izquierda a derecha y empiezan por 1. Para buscar la información deseada, debes especificar el índice de su columna. Por ejemplo, la columna 2 representa la cantidad.

Índice = 2 Busca la cantidad de naranjas, que se corresponde con la segunda columna del intervalo.

=BUSCARV(G3; B4:D8; 2; FALSO) Valor devuelto = 5

Coincidencia exacta o coincidencia aproximada de BUSCARV

• Usa la coincidencia exacta de BUSCARV para encontrar un ID exacto.
• Usa la coincidencia aproximada de BUSCARV para encontrar un ID aproximado.

Pruébalo

Explicación

Usa una coincidencia aproximada o está_ordenado = VERDADERO cuando busques la mejor coincidencia, pero no una coincidencia exacta.

Si quieres buscar el ID = 102, que no existe en la tabla, con una coincidencia aproximada se retrocede un paso para devolver el ID = 101. Esto se debe a que, en la columna del valor de búsqueda, 101 es el valor más próximo por debajo de 102.

Una coincidencia aproximada busca en la columna del valor de búsqueda hasta que encuentra un valor mayor que tu valor de búsqueda. A continuación, se detiene en la fila de antes del valor superior y devuelve el valor de la columna del valor devuelto de esa fila. Esto significa que, si la columna del valor de búsqueda no está ordenada en sentido ascendente, es muy probable que se devuelva un valor incorrecto.

Importante: Antes de usar una coincidencia aproximada, ordena los valores de búsqueda en orden ascendente para que se devuelva el valor correcto. De lo contrario, es posible que se devuelva un valor inesperado.

Cuando buscas la coincidencia exacta, como está_ordenado = FALSO, se devuelve una coincidencia exacta. Por ejemplo, el nombre de la fruta del ID = 103 es "Plátano". Si no hay coincidencias exactas, se mostrará un error #N/A. Debido a que su comportamiento es más predecible, te recomendamos que utilices la coincidencia exacta.

Coincidencia exacta	=BUSCARV(G6; A4:D8; 2; FALSO) Valor devuelto = "Manzana"
Coincidencia aproximada	=BUSCARV(G3; A4:D8; 2; VERDADERO) O =BUSCARV(G3; A4:D8; 2) Valor devuelto = "Plátano"

Aplicaciones habituales de BUSCARV

Sustituir el valor de error de BUSCARV

Te recomendamos sustituir un valor de error devuelto por BUSCARV cuando el valor de búsqueda no exista. En este caso, si no quieres recibir un error #N/A, puedes usar la función SI.ND() para reemplazar #N/A. Consulta más información sobre SI.ND().

Pruébalo

Inicialmente, BUSCARV devuelve #N/A porque el valor de búsqueda "Lápiz" no existe en la columna "Fruta". SI.ND() sustituye el error #N/A por la segunda entrada especificada en la función. En nuestro caso, es "NO ENCONTRADO".

=SI.ND(BUSCARV(G3; B4:D8; 3; FALSO);"NO ENCONTRADO") Valor devuelto = "NO ENCONTRADO"

Nota: Si quieres sustituir otros errores, como #REF!, consulta más información sobre SI.ERROR().

BUSCARV con varios criterios

BUSCARV no se puede aplicar directamente a varios criterios. En su lugar, crea una columna auxiliar para aplicar directamente BUSCARV a varios criterios y combinar varias columnas existentes.

Pruébalo

1. Puedes crear una columna auxiliar si usas "&" para combinar nombre y apellidos.	=C4&D4 y arrastra el cursor de B4 a B8 para obtener la columna auxiliar.
2. Usa la referencia de celda B7, JuanLinares, como valor de búsqueda.	=BUSCARV(B7; B4:E8; 4; FALSO) Valor devuelto = "Asistencia"

BUSCARV con comodines o coincidencias parciales

En BUSCARV, también puedes usar comodines o coincidencias parciales. Puedes utilizar estos caracteres comodín:

• Un signo de interrogación "?" coincide con cualquier carácter.
• Un asterisco "*" coincide con cualquier secuencia de caracteres.

Para usar comodines en BUSCARV, debes utilizar una coincidencia exacta: "está_ordenado = FALSO".

Pruébalo

"La*" se utiliza para encontrar coincidencias con cualquier elemento que comience por "La", independientemente del número de caracteres, como "Laura", "Lab1", "Lanzamiento" o "Lauraaaaa".

=BUSCARV("La*"; B4:D8; 3; FALSO) Valor devuelto = "Marketing"

Solución de errores y prácticas recomendadas

Valor devuelto incorrecto

• Se devuelve un valor inesperado: si defines está_ordenado como VERDADERO, pero la primera columna del intervalo no está ordenada numérica ni alfabéticamente de forma ascendente, cambia está_ordenado a FALSO.

• BUSCARV devuelve la primera coincidencia: BUSCARV solo devuelve la primera coincidencia. Si tienes varios valores de búsqueda coincidentes, se devuelve un valor, pero puede que no sea el esperado.
• Datos sucios: a veces, los valores con espacios finales o iniciales pueden parecer similares, pero BUSCARV los trata de forma diferente. Por ejemplo, los siguientes ejemplos son distintos para BUSCARV:
  • " Manzana"
  • "Manzana "
  • "Manzana"

Para obtener los resultados previstos, quita los espacios antes de usar BUSCARV.

Para obtener más información, consulta nuestra sección de prácticas recomendadas.

#N/A

• Si se utiliza una coincidencia aproximada o está_ordenado = VERDADERO y el valor de búsqueda de BUSCARV es inferior al valor más pequeño de la primera columna, BUSCARV devuelve #N/A.
• Si se utiliza la coincidencia exacta o está_ordenado = FALSO, la coincidencia exacta del valor de búsqueda de BUSCARV no se encuentra en la primera columna. Si quieres evitar que se devuelva #N/A cuando el valor de búsqueda no se encuentre en la primera columna, puedes usar la función SI.ND().

#REF!

Puedes especificar por error un intervalo con un número mayor que el número máximo de columnas del intervalo. Para evitarlo, haz lo siguiente:

• Cuenta las columnas del intervalo seleccionado, no de la tabla completa.
• Empieza a contar desde 1 en vez de 0.

#VALUE!

Si obtienes #VALUE!, puede que:

• No hayas escrito bien el texto o el nombre de la columna de índice.
• Hayas introducido un número menor que 1 en índice. El índice debe ser, como mínimo, igual a 1 e inferior al número máximo de columnas del intervalo. BUSCARV solo puede buscar en la columna del valor de búsqueda, cuando índice = 1, o en las columnas que están más a la derecha.

Importante: índice solo acepta un número.

#NAME?

• Es posible que no hayas incluido las comillas en el valor de búsqueda si valor_búsqueda son datos de texto.

Prácticas recomendadas

 

Prácticas recomendadas	Motivo
Usa referencias absolutas en intervalo	Deberías utilizar: Una referencia absoluta para intervalo de BUSCARV BUSCARV(G3; $B$3:$D$7; 3; FALSO) No deberías utilizar: BUSCARV(G3; B3:D7; 3; FALSO) Esto evita los cambios impredecibles en intervalo cuando se copia o se arrastra hacia abajo.
Ordena la primera columna de forma ascendente cuando uses una coincidencia aproximada, como está_ordenado = VERDADERO.	Si utilizas una coincidencia aproximada o está_ordenado = VERDADERO, debes ordenar la primera columna de forma ascendente. De lo contrario, lo más probable es que se devuelva un valor incorrecto. Consulta más información sobre cómo ordenar los datos.
Limpia tus datos antes de usar BUSCARV	Antes de utilizar la función BUSCARV, asegúrate de limpiar tus datos. Los datos sucios pueden provocar que BUSCARV devuelva un valor impredecible. A continuación, te indicamos algunos problemas habituales que pueden surgir con los datos sucios: Espacios iniciales: " manzana" Espacios finales: "manzana " Espacios en blanco: "" y " " no son equivalentes Para quitar los espacios en blanco iniciales y finales, puedes seleccionar Datos Borrado de datos Recortar espacios en blanco.
No almacenes valores de número o fecha como texto	Comprueba que los valores de fecha o número de la primera columna del intervalo de BUSCARV, como la columna del valor de búsqueda, no estén almacenados como valores de texto. Puede que se devuelva un valor inesperado. En la parte superior de Hojas de cálculo, selecciona la columna del valor de búsqueda. Toca el menú Formato Número. Elige una opción según el tipo de datos que quieras: Fecha Número