行と列のオフセットで指定したセルのコンテンツを返します。
例
| 招待客名 | 食事制限 | 招待済み | テーブルの番号 |
|---|---|---|---|
| デビッド | ベジタリアン | × | 3 |
| ボブ | なし | × | 5 |
| デビッド | なし | ○ | 1 |
| ナンシー | なし | × | 4 |
| メアリー | ベジタリアン | ○ | 2 |
| 数式 | 数式の出力 |
|---|---|
| =INDEX(A2:D6, 2, 1) | ボブ |
| =INDEX(A2:D6, 4, 4) | 4 |
| =INDEX(A2:D6,1,1) | デビッド |
| =INDEX(A1:D6, 6, 2) | ベジタリアン |
| 数式 | 数式の出力 | |||
|---|---|---|---|---|
| =INDEX(A2:D6, 2, 0) | ボブ | なし | × | 5 |
| 数式 | 数式の出力 |
|---|---|
| =INDEX(A2:D6, 0, 4) | 3 |
| 5 | |
| 1 | |
| 4 | |
| 2 |
参照するセル範囲内で、インデックス値で指定したセルのコンテンツを返します。
使用例
INDEX(A1:C20, 5, 1)
構文
INDEX(参照, [行], [列])
-
参照- 値を返すセルの範囲です。 -
行- [省略可 - デフォルトは 0] - 参照するセル範囲から返される行のインデックスです。 -
列- [省略可 - デフォルトは0] - 参照するセル範囲から返される列のインデックスです。
INDEX と MATCH の使用
INDEX と MATCH を組み合わせて使用すると、より高度で動的な参照が可能です。
| 招待客名 | 食事制限 | 招待済み | テーブルの番号 |
|---|---|---|---|
| デビッド | ベジタリアン | × | 3 |
| ボブ | なし | × | 5 |
| デビッド | なし | ○ | 1 |
| ナンシー | なし | × | 4 |
| メアリー | ベジタリアン | ○ | 2 |
| 目的 | 数式 | 数式の出力 | コメント |
|---|---|---|---|
| メアリーの食事制限を確認する | =VLOOKUP("メアリー", A1:D6, 2, false) | ベジタリアン | 検索キーとインデックスがどちらもハードコードされています |
| メアリーの食事制限を確認する | =INDEX(A1:D6, MATCH("メアリー", A1:A6, 0), 2) | ベジタリアン | 行番号が動的で、列番号がハードコードされている |
| メアリーの食事制限を確認する | =INDEX(A1:D6, MATCH("メアリー", A1:A6, 0), MATCH("食事制限", A1:D1, 0)) | ベジタリアン | 行番号と列番号がどちらも動的です |
| 2 番テーブルの招待客名を調べる | VLOOKUP を使用して調べることはできません。 | なし | VLOOKUP を使用できるのは、参照値が検索するセル範囲の左端の列にある場合に限られます。 |
| 2 番テーブルの招待客名を調べる | =INDEX(A1:D6, MATCH(2, D1:D6, 0), MATCH("招待客名", A1:D1, 0)) | メアリー | INDEX と MATCH は、参照値が検索するセル範囲内のどの列にあっても使用できます |
関連情報
MATCH: 指定した値と一致する範囲内のアイテムの相対的な位置を返します。
OFFSET: 開始セル参照から指定した行数と列数だけシフトした位置にあるセル範囲の参照を返します。
メモ
- 行または列に 0 を指定すると、
INDEXは列全体または行全体の値の配列をそれぞれ返します。