RECHERCHEV

 
Si votre feuille de calcul contient des informations connues, vous pouvez rechercher des informations associées par ligne à l'aide de RECHERCHEV. Par exemple, si vous voulez acheter une orange, vous pouvez rechercher le prix grâce à RECHERCHEV.
VLOOKUP formula example
RECHERCHEV pour BigQuery

Recherche verticale. Renvoie les valeurs dans une colonne de données à la position à laquelle une correspondance a été trouvée dans la colonne de recherche.

Exemple d'utilisation

RECHERCHEV("Apple";nom_table!fruit;nom_table!price)

Syntaxe

RECHERCHEV(clé_recherche; plage; index; est_trié)

  • clé_recherche : valeur à rechercher dans la colonne de recherche.
  • colonne_recherche : colonne de données à prendre en compte pour la recherche.
  • colonne_résultat : colonne de données à prendre en compte pour le résultat.
  • est_trié : [FACULTATIF] manière de trouver une correspondance pour clé_recherche.
    • FALSE : recommandé pour une correspondance exacte.
    • TRUE : pour une correspondance proche, il s'agit de la valeur par défaut si est_trié n'est pas spécifié.
      Remarque : Avant d'utiliser une correspondance proche, triez votre clé de recherche par ordre croissant. Sinon, vous risquez d'obtenir une valeur renvoyée incorrecte. Découvrez pourquoi vous pouvez rencontrer une valeur renvoyée incorrecte.

Remarque : RECHERCHEX est plus adapté si vous souhaitez créer des requêtes de base de données plus flexibles dans BigQuery.

Syntaxe

=RECHERCHEV(clé_rechercheplage; index; [est_trié])

Entrées

  1. clé_recherche : valeur à rechercher dans la première colonne de la plage.
  2. plage : valeurs supérieure et inférieure à prendre en compte pour la recherche.
  3. index : index de la colonne contenant la valeur renvoyée pour la plage. L'index doit être un entier positif.
  4. est_trié : facultatif. Sélectionnez une option :
    • FALSE = correspondance exacte (option recommandée).
    • TRUE = correspondance proche. Il s'agit de la valeur par défaut si est_trié n'est pas spécifié.
      Important : Avant d'utiliser une correspondance proche, triez votre clé de recherche par ordre croissant. Sinon, vous risquez d'obtenir une valeur renvoyée incorrecte. Découvrez pourquoi vous pouvez rencontrer une valeur renvoyée incorrecte.

Valeur renvoyée

Il s'agit de la première valeur correspondante de la plage sélectionnée.
Détails techniques :
Exemple :
=RECHERCHEV(G9; B4:D8; 3; FALSE)
=RECHERCHEV("Apple"; B4:D8; 3; TRUE)
Entrées Description
clé_recherche
Il s'agit de la valeur que vous recherchez dans la première colonne de la plage. Pour que la valeur ne corresponde pas à une erreur, la clé de recherche doit figurer dans la première colonne de la plage. Vous pouvez aussi saisir une référence de cellule.
Par exemple, si la valeur de votre clé_recherche se trouve dans la cellule B3, votre plage doit commencer par la colonne B.
plage
Il s'agit de la plage dans laquelle :
  • la fonction recherche la clé de recherche spécifiée dans sa première colonne ;
  • RECHERCHEV renvoie la valeur de la colonne spécifiée par index. Vous pouvez également utiliser une plage nommée.
Pour renvoyer une valeur sans erreur, votre clé de recherche doit figurer dans la première colonne de la plage.
Par exemple, si la valeur de votre clé_recherche se trouve dans la cellule B3, votre plage doit commencer par la colonne B.
index
Également appelé "numéro de colonne", il s'agit de l'index de la colonne de la plage qui contient la valeur renvoyée.
  • Le plus petit index possible est 1.
  • Le plus grand index possible correspond au nombre maximal de colonnes dans la plage concernée.
Une fois la plage définie, RECHERCHEV ne prend en compte que la colonne de la clé de recherche (lorsque la valeur index est égale à 1) ou les colonnes situées plus à droite.
Remarque : Avec RECHERCHEV, imaginez que les colonnes de la plage sont numérotées de gauche à droite, en commençant par 1.
est_trié
Cette entrée est facultative. Vous pouvez lui attribuer deux valeurs uniquement : TRUE ou FALSE.
  • Si la valeur TRUE est attribuée à est_trié, RECHERCHEV utilise une correspondance proche.
    Important : Avant d'utiliser une correspondance proche, triez votre clé de recherche par ordre croissant. Dans le cas contraire, vous risquez d'obtenir une valeur renvoyée inattendue. Découvrez pourquoi vous pouvez rencontrer une valeur renvoyée incorrecte.
  • Si la valeur FALSE est attribuée à est_trié, RECHERCHEV utilise une correspondance exacte.

  • Si est_trié n'est pas spécifié, la valeur TRUE est attribuée par défaut.
Nous vous recommandons vivement de :
  • définir la valeur FALSE pour l'entrée est_trié, car son comportement restera cohérent, que la colonne spécifiée pour la clé de recherche soit triée ou non ;
  • toujours attribuer une valeur à est_trié pour une meilleure lisibilité, même si cette entrée est facultative.

 

Résultats Description
Valeur renvoyée
Il s'agit de la valeur renvoyée par RECHERCHEV en fonction des informations que vous avez saisies. Une seule valeur peut être renvoyée par fonction RECHERCHEV.
  • Si plusieurs valeurs correspondent à la clé de recherche, la valeur renvoyée est celle dont la clé de recherche associée apparaît en premier dans la colonne.
  • Si aucune valeur n'est trouvée, #N/A est renvoyé.
Si une valeur inattendue ou une erreur s'affiche (par exemple, #N/A ou #VALUE!), essayez de résoudre le problème. Si vous souhaitez remplacer #N/A par une autre valeur, découvrez comment fonctionne SI.NON.DISP() avec RECHERCHEV().

Exemples de formules basiques avec RECHERCHEV :

RECHERCHEV avec différentes clés de recherche

Vous pouvez rechercher le prix d'une orange et d'une pomme à l'aide de RECHERCHEV.

VLOOKUP on different search keys example
Explication :

Dans la formule RECHERCHEV, vous pouvez ajouter différentes clés de recherche telles que "pomme" et "orange".

Pour renvoyer une valeur sans erreur, ces clés de recherche doivent figurer dans la première colonne de la plage. Si vous ne souhaitez pas remplir de valeur pour les clés de recherche, vous pouvez également indiquer une référence de cellule, par exemple "G9".
clé_recherche correspond à "Orange"
=RECHERCHEV("Orange"; B4:D8; 3; FALSE)
Valeur renvoyée = 1,01 $
clé_recherche correspond à "Apple" (pomme)
=RECHERCHEV("Apple"; B4:D8; 3; FALSE)
Valeur renvoyée = 1,50 $
clé_recherche correspond à la référence de cellule "Apple" en G9
=RECHERCHEV(G9; B4:D8; 3; FALSE)
Valeur renvoyée = 1,50 $

RECHERCHEV avec différents index de colonne

Vous pouvez déterminer la quantité d'oranges dans la deuxième colonne d'index à l'aide de la formule RECHERCHEV.
VLOOKUP on different column indexes example
Explication :
Avec RECHERCHEV, imaginez que les colonnes de la plage sont numérotées de gauche à droite, en commençant par 1. Pour trouver l'information que vous désirez, vous devez spécifier son index de colonne. Par exemple, la colonne 2 pour la quantité.
Index = 2
Permet de trouver la quantité d'oranges, une information qui figure dans la deuxième colonne de la plage.
=RECHERCHEV(G3; B4:D8; 2; FALSE)
Valeur renvoyée = 5

RECHERCHEV avec une correspondance exacte ou proche

  • Trouvez un identifiant exact à l'aide de la formule RECHERCHEV avec une correspondance exacte.
  • Trouvez un identifiant proche à l'aide la formule RECHERCHEV avec une correspondance proche.
VLOOKUP exact match or approximate match example
Explication :
Utilisez une correspondance proche ou la valeur TRUE pour est_trié lorsque vous recherchez une correspondance optimale, mais pas exacte.
Si vous souhaitez rechercher l'identifiant 102, qui n'existe pas dans le tableau, une correspondance proche vous indiquera l'identifiant précédent, à savoir 101. En effet, dans la colonne de clé de recherche, 101 est la valeur inférieure la plus proche à 102.
Une correspondance proche recherche dans la colonne de clé de recherche la première valeur supérieure à votre clé de recherche. Elle s'arrête alors sur la ligne qui précède cette valeur plus élevée et renvoie dans la colonne dédiée la valeur indiquée sur cette ligne. Par conséquent, si la colonne de votre clé de recherche n'est pas triée par ordre croissant, vous obtiendrez probablement une valeur renvoyée incorrecte.
Important : Avant d'utiliser une correspondance proche, triez votre clé de recherche par ordre croissant pour obtenir la valeur correcte. Dans le cas contraire, vous risquez d'obtenir une valeur renvoyée inattendue.
Lorsque vous recherchez une correspondance exacte, avec la valeur FALSE attribuée à est_trié, une correspondance exacte est renvoyée. Par exemple, "banane" est le nom du fruit qui correspond à l'identifiant 103. En l'absence de correspondance exacte, vous obtenez une erreur #N/A. En raison de son comportement plus prévisible, nous vous recommandons d'utiliser la correspondance exacte.
Correspondance exacte
=RECHERCHEV(G6; A4:D8; 2; FALSE)
Valeur renvoyée = "Apple"
Correspondance proche
=RECHERCHEV(G3; A4:D8; 2; TRUE)
OU
=RECHERCHEV(G3; A4:D8; 2)
Valeur renvoyée = "Banana"

Utilisations courantes de RECHERCHEV

Remplacer la valeur d'erreur dans RECHERCHEV

Lorsque votre clé de recherche n'existe pas, vous pouvez remplacer la valeur d'erreur #N/A renvoyée par RECHERCHEV à l'aide des fonctions SI.NON.DISP(). En savoir plus
Replace error value from VLOOKUP example
La clé de recherche "Pencil" (crayon) n'existe pas dans la colonne "Fruit". RECHERCHEV renvoie donc la valeur #N/A à l'origine.
SI.NON.DISP() remplace l'erreur #N/A par la deuxième entrée spécifiée dans la fonction. Dans notre cas, il s'agit de "INTROUVABLE".
=SI.NON.DISP(RECHERCHEV(G3; B4:D8; 3; FALSE),"INTROUVABLE"
Valeur renvoyée = "INTROUVABLE"

Conseil : Si vous souhaitez remplacer d'autres erreurs telles que #REF!, cliquez ici pour en savoir plus sur la fonction SIERREUR().

RECHERCHEV avec plusieurs critères

RECHERCHEV ne peut pas être appliqué directement à plusieurs critères. Vous devez créer une colonne d'assistance qui rassemble plusieurs de vos colonnes existantes pour appliquer directement RECHERCHEV à plusieurs critères.
VLOOKUP with multiple criteria example
1. Vous pouvez créer une colonne d'assistance à l'aide de "&" pour combiner la colonne "Prénom" et la colonne "Nom de famille". =C4&D4, puis faites glisser le curseur de B4 vers B8 pour créer la colonne d'assistance.
2. Utilisez la référence de cellule B7, JohnLee, comme clé de recherche.
=RECHERCHEV(B7; B4:E8; 4; FALSE)
Valeur renvoyée = "Support" (Assistance)

RECHERCHEV avec des caractères génériques ou des correspondances partielles

La fonction RECHERCHEV peut également comprendre des caractères génériques ou des correspondances partielles. Les caractères génériques suivants sont acceptés :
  • Le point d'interrogation "?" remplace n'importe quel caractère.
  • L'astérisque "*" remplace n'importe quel groupe de caractères.
Pour utiliser des caractères génériques dans RECHERCHEV, la valeur FALSE doit être obligatoirement attribuée à est_trié pour une correspondance exacte.
VLOOKUP with wildcard example
"St*" remplace tous les éléments qui commencent par "St", quel que soit leur nombre de caractères, comme "Steve", "St1", "Stock" ou "Steeeeeeve".
=RECHERCHEV("St*"; B4:D8; 3; FALSE)
Valeur renvoyée = "Marketing"

Résolution des erreurs et bonnes pratiques

Valeur renvoyée incorrecte
  • Renvoie une valeur inattendue : si vous attribuez la valeur TRUE à est_trié, mais que la première colonne de la plage n'est pas triée par ordre numérique ou alphabétique, remplacez-la par FALSE.

  • RECHERCHEV renvoie la première correspondance : RECHERCHEV ne renvoie que la première correspondance. Si plusieurs clés de recherche correspondent, une valeur est renvoyée, mais pas nécessairement celle attendue.
  • Données incorrectes : les valeurs contenant des espaces superflues peuvent être traitées différemment par RECHERCHEV. Par exemple, les valeurs suivantes ne sont pas identiques pour RECHERCHEV :
    • " Pomme"
    • "Pomme "
    • "Pomme"
Pour des résultats optimisés, supprimez les espaces avant d'utiliser RECHERCHEV.
#N/A
  • Si vous utilisez une correspondance proche ou attribuez la valeur TRUE à est_trié et si la clé de recherche dans RECHERCHEV est inférieure à la plus petite valeur de la première colonne, alors RECHERCHEV renvoie une erreur #N/A.
  • Si vous utilisez une correspondance exacte ou attribuez la valeur FALSE à est_trié, alors la première colonne ne contient pas la correspondance exacte de la clé de recherche indiquée dans RECHERCHEV. Pour ne pas obtenir d'erreur #N/A lorsque la clé de recherche est introuvable dans la première colonne, vous pouvez utiliser la fonction SI.NON.DISP().
#REF!
Vous avez peut-être spécifié par erreur une plage avec un nombre de colonnes supérieur à celui que contient au maximum la plage en question. Pour éviter cela, assurez-vous de :
  • compter les colonnes de la plage sélectionnée, et non de l'ensemble du tableau ;
  • commencer à compter à partir de 1 au lieu de 0.
#VALUE!
L'erreur #VALUE! s'affiche dans les cas suivants :
  • Le texte ou le nom de la colonne saisis dans index contiennent une erreur.
  • Vous avez saisi un nombre inférieur à 1 pour index. L'index doit être au moins égal à 1 et inférieur au nombre maximal de colonnes que contient la plage. La fonction RECHERCHEV ne peut effectuer une recherche que dans la colonne de clé de recherche si la valeur index est égale à 1, ou que dans les colonnes situées plus à droite.

Important : index n'accepte que des chiffres.

#NAME?
  • Si votre clé_recherche contient du texte, vous avez peut-être oublié un guillemet.
Bonnes pratiques

 

À faire Motif
Utiliser des références absolues pour la plage
Vous devez utiliser :
  • une référence absolue pour la plage de la fonction RECHERCHEV
  • RECHERCHEV(G3; $B$3:$D$7; 3; FALSE)
Vous ne devez pas utiliser :
  • RECHERCHEV(G3; B3:D7; 3; FALSE)
Ceci afin d'éviter toute modification malencontreuse de la plage lorsque vous la copiez ou la faites glisser vers le bas.
Trier la première colonne par ordre croissant lorsque vous utilisez une correspondance proche, par exemple quand est_trié est défini sur TRUE. Si vous utilisez une correspondance proche ou attribuez la valeur TRUE à est_trié, vous devez trier la première colonne par ordre croissant. Dans le cas contraire, vous obtiendrez probablement une valeur renvoyée incorrecte. En savoir plus sur le tri des données
Nettoyer vos données avant d'utiliser RECHERCHEV
Avant d'utiliser RECHERCHEV, n'oubliez pas de nettoyer vos données. Dans le cas contraire, RECHERCHEV est susceptible de renvoyer une valeur imprévisible. Voici quelques exemples courants de données non nettoyées :
  • Espaces en début de mot : " pomme"
  • Espaces en fin de mot : "pomme "
  • Espaces ou valeurs vides : "" et " " ne sont pas équivalents
Pour supprimer les espaces vides au début ou en fin de mot, cliquez sur Données puis Nettoyage des données puis Supprimer les espaces vides.
Ne pas enregistrer les valeurs numériques ou les dates sous forme de texte
Assurez-vous que les valeurs numériques ou les dates figurant dans la première colonne de la plage de recherche RECHERCHEV, comme la colonne de clé de recherche, ne sont pas enregistrées sous forme de texte. Vous risqueriez d'obtenir une valeur renvoyée inattendue.
  1. En haut de votre feuille, sélectionnez la colonne de clé de recherche.
  2. Appuyez sur le menu Format puis Nombre.
  3. Choisissez une option en fonction du type de données souhaité :
    • Date
    • Nombre
true
Consulter le centre de formation

Vous utilisez des produits Google, comme Google Docs, dans votre entreprise ou votre établissement scolaire ? Essayez de suivre des astuces efficaces, ainsi que des didacticiels et des modèles puissants. Apprenez notamment à travailler sur des fichiers Office sans avoir à installer Office, créez des plans de projet et des calendriers d'équipe dynamiques, et organisez automatiquement votre boîte de réception.

Recherche
Effacer la recherche
Fermer le champ de recherche
Applications Google
Menu principal
257253598822416477
true
Rechercher dans le centre d'aide
true
true
true
true
true
35