VLOOKUP

 

Om du har känd information i kalkylarket kan du använda LETARAD för att söka efter relaterad information rad för rad. Om du till exempel vill köpa en apelsin kan du använda LETARAD för att söka efter priset.

LETARAD för BigQuery

Vertikal sökning. Returnerar värdena i en datakolumn vid den position där en matchning hittades i sökkolumnen.

Användningsexempel

LETARAD("Apple",tabellnamn!frukt,tabellnamn!pris)

Syntax

LETARAD(söknyckel, intervall, index, är_sorterad)

• söknyckel: Värdet att söka efter i sökkolumnen.
• sökkolumn: Datakolumnen som ska sökas igenom.
• resultatkolumn: Datakolumnen som ska användas för resultatet.
• är_sorterad: [VALFRITT] Sättet att hitta en matchning för söknyckel.
  • FALSKT: Rekommenderas för exakt matchning.
  • SANT: För en ungefärlig matchning är detta standard om är_sorterad inte har angetts.
    Tips! Sortera söknyckeln i stigande ordning innan du använder en ungefärlig matchning. Annars får du sannolikt ett felaktigt returvärde. Läs mer om varför du kan få fel returvärde.

Tips! Om du vill ha mer flexibla databassökningar i BigQuery kan du använda du XLOOKUP.

Syntax

=LETARAD(söknyckel, intervall, index, [är_sorterad])

Ingångar

1. söknyckel: Värdet att söka efter i den första kolumnen i intervallet.
2. intervall: De övre och nedre värden som ska användas för sökningen.
3. index: Indexet för kolumnen med returvärdet för intervallet. Indexet måste vara ett positivt heltal.
4. är_sorterad: Valfri indata. Välj ett alternativ:
   • FALSKT = Exakt matchning. Detta rekommenderas.
   • SANT = Ungefärlig matchning. Detta är standardinställningen om är_sorterad är ospecificerat.
     Viktigt! Sortera söknyckeln i stigande ordning innan du använder en ungefärlig matchning. Annars får du sannolikt ett felaktigt returvärde. Läs mer om varför du kan få fel returvärde.

Returvärde

Det första matchade värdet från det valda intervallet.

Teknisk information:

Exempel:

=LETARAD(G9, B4:D8, 3, FALSKT)

=LETARAD("Apple", B4:D8, 3, SANT)

Indata	Beskrivning
söknyckel	Detta är det värde du söker efter den första kolumnen i intervallet. Om du förväntar dig ett värde som inte är ett fel måste söknyckeln finnas i den första kolumnen av intervallet. Cellreferens stöds också. Gör en enkel kontroll: Om din söknyckel finns i B3 ska intervallet börja med kolumn B.
intervall	Detta är intervallet där funktionen söker efter den angivna söknyckeln i den första kolumnen. LETARAD returnerar värdet från kolumnen som specificeras av indexet. Du kan även använda ett namngivet intervall. Om du vill returnera ett värde som inte är ett fel måste söknyckeln finnas i den första kolumnen av intervallet. Gör en enkel kontroll: Om din söknyckel finns i B3 ska intervallet börja med kolumn B.
index	Kallas även Kolumnnummer. Det här är indexet för kolumnen i det intervall som innehåller returvärdet. Minsta möjliga index är 1. Högsta möjliga index är det högsta antalet kolumner i intervallet. När du har ställt in intervallet använder LETARAD enbart kolumnen för söknyckel när index = 1 eller för kolumner som är längre åt höger. Tips! Tänk på att kolumnerna i intervallet är numrerade från vänster till höger och att de börjar med 1 när du använder LETARAD.
är_sorterad	Det här är valfri indata. De två tillgängliga alternativen är SANT och FALSKT. Om är_sorterad är SANT använder LETARAD ungefärlig matchning. Viktigt! Sortera söknyckeln i stigande ordning innan du använder en ungefärlig matchning. Annars kan du ett oväntat värde returneras. Läs mer om varför du kan få fel returvärde. Om är_sorterad är FALSKT använder LETARAD exakt matchning. Om är_sorterad inte anges används värdet SANT som standard. Vi rekommenderar starkt att du använder FALSKT för är_sorterad för dess konsekventa funktion oavsett om kolumnen för söknyckel är sorterad eller inte. alltid anger är_sorterad för bättre läsbarhet, även om indata är valfri.

 

Resultat

Beskrivning

Returvärde

Detta är det värde som LETARAD returnerar baserat på din indata. Det finns bara ett returvärde från varje LETRAD-funktion. Om det finns flera söknyckelvärden som matchar, returneras värdet i kolumnen för returvärde vars motsvarande söknyckel först matchas i söknyckelkolumnen. Om #N/A returneras hittades inget värde. Om du stöter på ett förväntat värde eller fel som #N/A eller #VALUE! kan du påbörja felsökningen. Om du vill ersätta #N/A med ett annat värde kan du läsa mer om att använda OMSAKNAS() på LETARAD().

Grundläggande exempel på LETARAD:

LETARAD med olika söknycklar

Använda LETRAD för att hitta priset på en apelsin och ett äpple.

Testa själv

Förklaring:

När du använder LETARAD kan du använda olika söknycklar, som Apple och Orange.

Om du vill returnera ett värde som inte är ett fel måste dessa söknycklar finnas i den första kolumnen av intervallet. Om du inte vill fylla i ett värde för söknycklar kan du även använda en cellreferens, till exempel G9.

söknyckel är Orange	=Letarad("Orange", B4:D8, 3, FALSKT) Returvärde = 1,01 USD
söknyckel är Apple	=LETARAD("Apple", B4:D8, 3, FALSKT) Returvärde = 1,50 USD
söknyckel som använder cellreferensen ”Apple” i G9	=LETARAD(G9, B4:D8, 3, FALSKT) Returvärde = 1,50 USD

LETARAD med olika kolumnindex

Använd LETARAD för att hitta antalet apelsiner i den andra indexkolumnen.

Testa själv

Förklaring:

När du använder LETARAD kan du tänka dig att kolumnerna i intervallet är numrerade från vänster till höger och börjar på 1. Du måste ange kolumnindex för att hitta målinformationen. Till exempel kolumn 2 för antal.

Index = 2 Antalet apelsiner är den andra kolumnen i intervallet.

=LETARAD(G3, B4:D8, 2, FALSKT) Returvärde = 5

Exakt matchning eller ungefärlig matchning med LETARAD

• Använd exakt matchning med LETARAD för att hitta ett exakt id.
• Använd ungefärlig matchning med LETARAD för att hitta ett ungefärligt id.

Testa själv

Förklaring:

Använd en ungefärlig matchning eller är_sorterad = SANT när du söker efter en bästa matchning, men inte en exakt matchning.

Om du vill söka efter ID = 102, som inte finns i tabellen, tar en ungefärlig matchning ett steg tillbaka för att ge dig ID = 101 som resultat. Det beror på att 101 i söknyckelkolumnen är det närmaste värde som också är mindre än 102.

En ungefärlig matchning söker i kolumnen söknyckel tills den hittar ett värde som är större än söknyckeln. Därefter stannar söknyckeln på raden före det större värdet och returnerar värdet från kolumnen för returvärde på den raden. Det innebär att du troligen får ett felaktigt returvärde om kolumnen för söknyckel inte är sorterad i stigande ordning.

Viktigt! Sortera söknyckeln i stigande ordning innan du använder en ungefärlig matchning för att returnera rätt värde. Annars kan du ett oväntat värde returneras.

När du söker efter den exakta matchningen, till exempel är_sorterad = FALSKT, returneras en exakt matchning. Fruktnamnet för ID = 103 är till exempel Banana. Om det inte finns någon exakt matchning visas felmeddelandet #N/A. På grund av den mer förutsägbara funktionen rekommenderar vi att du använder exakt matchning.

Exakt matchning	=LETARAD(G6, A4:D8, 2, FALSKT) Returvärde = ”Apple”
Ungefärlig matchning	=LETARAD(G3, A4:D8, 2, SANT) ELLER =LETARAD(G3, A4:D8, 2) Returvärde = Banana

Vanliga tillämpningar för LETARAD

Ersätt felvärde från LETARAD

Du kan ersätta ett felvärde som returneras av LETARAD när söknyckeln inte finns. Om du inte vill ha #N/A kan du använda funktionen OMSAKNAS() i stället för #N/A. Läs mer om OMSAKNAS().

Testa själv

Ursprungligen returnerar LETARAD #N/A eftersom söknyckeln Penna inte finns i kolumnen Frukt. OMSAKNAS() ersätter felet #N/A med den andra indata som anges i funktionen. I vårt fall är det HITTADES INTE.

=OMSAKNAS(LETARAD(G3, B4:D8, 3, FALSKT),"HITTADES INTE") Returvärde = HITTADES INTE

Tips! Om du vill ersätta andra fel, som #REF!, kan du läsa mer om OMFEL().

LETARAD med flera kriterier

LETARAD kan inte tillämpas direkt på flera kriterier. Skapa i stället en ny hjälpkolumn för att tillämpa LETARAD på flera kriterier direkt om du vill kombinera flera befintliga kolumner.

Testa själv

1. Du kan skapa en hjälpkolumn om du använder & för att kombinera förnamn och efternamn.	=C4&D4 och dra den nedåt från B4 till B8 för att få hjälpkolumnen.
2. Använd cellreferens B7, JohnLee, som söknyckel.	=LETARAD(B7, B4:E8, 4, FALSKT) Returvärde = Support

LETARAD med jokertecken eller partiella matchningar

I LETARAD kan du även använda jokertecken eller partiella matchningar. Du kan använda följande jokertecken:

• Ett frågetecken ? matchar ett valfritt tecken.
• En asterisk * matchar en valfri följd av tecken.

Om du vill använda jokertecken i LETARAD måste du använda en exakt matchning: är_sorterad = FALSKT.

Testa själv

St* används för att matcha allt som börjar med ”St” oavsett antal tecken. Exempelvis Steve, St1, Stock eller Steeeeeeve.

=LETARAD("St*", B4:D8, 3, FALSKT) Returvärde = Marknadsföring

Felsökning och rekommenderade metoder:

Fel returvärde

• Returnerar ett oväntat värde: Om du ställer in är_sorterad på SANT, men den första kolumnen i intervallet inte är numrerad i stigande numerisk eller alfabetisk ordning, ändras är_sorterad till FALSKT.

• LETARAD ger den första matchningen: LETARAD returnerar enbart den första matchningen. Om du har flera matchade söknycklar returneras ett värde, men det är kanske inte det förväntade värdet.
• Korrekt data: Ibland kan värden med inledande och efterföljande blanksteg likna varandra, men de behandlas på olika sätt av LETARAD. Följande behandlas till exempel på olika sätt av LETARAD:
  • ” Äpple”
  • ”Äpple ”
  • ”Äpple”

Ta bort blanksteg innan du använder LETARAD så att du får de förväntade resultaten.

Mer information finns i avsnittet med metodtips.

#N/A

• Om ungefärlig eller är_sorterad = SANT används och om söknyckeln i VLOOKUP är mindre än det minsta värdet i den första kolumnen returnerar LETARAD #N/A.
• Om exakt matchning eller är_sorterad används = FALSKT hittas inte den exakta matchningen av söknyckeln i LETARAD i den första kolumnen. Om du inte vill att #N/A ska visas när söknyckeln inte hittas i den första kolumnen kan du använda funktionen OMSAKNAS().

#REF!

Du kan av misstag ange ett intervall med ett tal som är större än det högsta antalet kolumner i intervallet. Undvik detta genom att göra följande:

• Räkna kolumnerna i det valda intervallet, inte hela tabellen.
• Börja räkna från 1 i stället för 0.

#VALUE!

Om du får felet #VALUE! kan det bero på något av följande:

• Felaktigt angiven text eller felaktigt kolumnnamn för indexet.
• Ett värde som är mindre än 1 har angetts för indexet. Indexet måste vara minst 1 och mindre än det högsta antalet kolumner i intervallet. LETARAD kan bara söka i kolumnen för söknyckel när index = 1 eller för kolumner som är längre åt höger.

Viktigt! Det går bara att använda tal för index.

#NAME?

• Du kanske har missat ett citattecken i söknyckeln när söknyckel är textdata.

Bästa metoder

 

Att göra	Orsak
Använd absoluta referenser för intervall	Du bör använda absolut referens för LETARAD-intervall LETARAD(G3, $B$3:$D$7, 3, FALSKT) Du bör inte använda LETARAD(G3, B3:D7, 3, FALSKT) Detta förhindrar oförutsägbara ändringar i intervallet när det kopieras eller dras ned.
Sortera den första kolumnen i stigande ordning när du använder en ungefärlig matchning, till exempel är_sorterad = SANT.	Om du använder en ungefärlig matchning eller är_sorterad = SANT måste du sortera den första kolumnen i stigande ordning. Annars får du troligen ett felaktigt returvärde. Läs mer om hur du sorterar.
Rensa din data innan du använder LETARAD	Kom ihåg att rensa data innan du använder LETARAD. Felaktig data kan leda till att LETARAD returnerar ett oförutsägbart värde. Här är några vanliga fällor med inkorrekt data: Inledande blanksteg: ” äpple” Avslutande blanksteg: ”äpple ” Data saknas eller blanksteg: ”” och ” ” är inte likvärdiga Om du vill trimma inledande och avslutande blanksteg kan du använda Data Datarensning Trimma blanksteg.
Lagra inte tal- eller datumvärden som text	Datum- och talvärdena i den första kolumnen i LETARAD-intervallet, till exempel kolumnen för söknyckel, lagras inte som textvärden. Du kan få ett oväntat returvärde. Välj kolumnen för söknyckeln högst upp i Kalkylark. Tryck på Format-meny Tal. Välj alternativ beroende på vilken datatyp du vill ha: Datum Tal