WYSZUKAJ.PIONOWO

 

Jeśli w arkuszu kalkulacyjnym masz znane informacje, możesz użyć funkcji WYSZUKAJ.PIONOWO, aby wyszukać powiązane informacje według wiersza. Jeśli na przykład chcesz kupić pomarańczę (ang. „Orange”), możesz wyszukać jej cenę (ang. „Price”) za pomocą funkcji WYSZUKAJ.PIONOWO.

WYSZUKAJ.PIONOWO dla BigQuery

Wyszukiwanie pionowe. Zwraca wartości w kolumnie danych w pozycji, w której znaleziono dopasowanie w kolumnie wyszukiwania.

Przykłady użycia

=WYSZUKAJ.PIONOWO("Orange"; nazwa_tabeli!Fruit; nazwa_tabeli!Price)

Składnia

WYSZUKAJ.PIONOWO(klucz_wyszukiwania; zakres; indeks; [posortowany])

• klucz_wyszukiwania: wartość do wyszukania w kolumnie wyszukiwania.
• kolumna_wyszukiwania: kolumna danych uwzględniana w wyszukiwaniu.
• kolumna_wyników: kolumna danych uwzględniana w wyniku.
• posortowany: [OPCJONALNIE] sposób wyszukiwania dopasowania dla argumentu klucz_wyszukiwania.
  • FAŁSZ: zalecane, pozwala na dopasowanie ścisłe.
  • PRAWDA: pozwala na dopasowanie przybliżone, ta wartość jest domyślna, jeśli argument [posortowany] nie jest określony.
    Wskazówka: zanim użyjesz dopasowania przybliżonego, posortuj kolumnę z kluczem wyszukiwania w kolejności rosnącej. W przeciwnym razie możesz otrzymać nieprawidłowy wynik. Dowiedz się, dlaczego wynik może być niepoprawny

Wskazówka: bardziej elastyczne zapytania do bazy danych w BigQuery uzyskasz dzięki funkcji XLOOKUP.

Składnia

WYSZUKAJ.PIONOWO(klucz_wyszukiwania; zakres; indeks; [posortowany])

Wejścia

1. klucz_wyszukiwania: wartość do wyszukania w pierwszej kolumnie zakresu.
2. zakres: wartości górna i dolna, które będą brane pod uwagę podczas wyszukiwania.
3. indeks: indeks kolumny z wartością zwracaną zakresu. Indeks musi być dodatnią liczbą całkowitą.
4. [posortowany]: argument opcjonalny. Wybierz odpowiednią opcję:
   • FAŁSZ = dopasowanie ścisłe. Zalecane.
   • PRAWDA = dopasowanie przybliżone. Ustawienie domyślne, jeśli argument [posortowany] nie jest określony.
     Ważne: zanim użyjesz dopasowania przybliżonego, posortuj kolumnę z kluczem wyszukiwania w kolejności rosnącej. W przeciwnym razie możesz otrzymać nieprawidłowy wynik. Dowiedz się, dlaczego wynik może być niepoprawny

Zwracana wartość

Jest to pierwsza pasująca wartość z wybranego zakresu.

Informacje techniczne

Przykład:

=WYSZUKAJ.PIONOWO(G9; B4:D8; 3; FAŁSZ)

=WYSZUKAJ.PIONOWO("Apple"; B4:D8; 3; PRAWDA)

Wejścia	Opis
szukany_klucz	To wartość, której szukasz w pierwszej kolumnie zakresu. Jeśli oczekiwana jest wartość inna niż błąd, klucz wyszukiwania musi znajdować się w pierwszej kolumnie zakresu. Można stosować także odwołania do komórek. Aby to sprawdzić: jeśli klucz_wyszukiwania znajduje się w komórce B3, wtedy zakres powinien zaczynać się od kolumny B.
zakres	To zakres, dla którego: funkcja wyszukuje określony klucz wyszukiwania w pierwszej kolumnie; WYSZUKAJ.PIONOWO zwraca wartość z kolumny określonej przez indeks. Możesz też użyć zakresu nazwanego. Jeśli oczekiwana jest wartość inna niż błąd, klucz wyszukiwania musi znajdować się w pierwszej kolumnie zakresu. Aby to sprawdzić: jeśli klucz_wyszukiwania znajduje się w komórce B3, wtedy zakres powinien zaczynać się od kolumny B.
indeks	Inaczej „Numer kolumny”. Jest to indeks kolumny zakresu, która zawiera wartość zwracaną. Najmniejszy możliwy indeks to 1. Największy możliwy indeks to maksymalna liczba kolumn w wybranym zakresie. Po ustaleniu zakresu funkcja WYSZUKAJ.PIONOWO przeszukuje tylko kolumnę, w której znajduje się klucz wyszukiwania, gdy indeks = 1. Gdy indeks wynosi 2 albo 3, albo 4 itd., funkcja przeszukuje drugą albo trzecią, albo czwartą kolumnę itd., licząc od maksymalnie lewej kolumny. Wskazówka: korzystając z WYSZUKAJ.PIONOWO, wyobraź sobie, że kolumny zakresu są numerowane od lewej do prawej i zaczynają się od 1.
posortowany	To pole jest opcjonalne. Dostępne są 2 opcje: PRAWDA i FAŁSZ. Jeśli argument posortowany ma wartość PRAWDA, funkcja WYSZUKAJ.PIONOWO używa dopasowania przybliżonego. Ważne: zanim użyjesz dopasowania przybliżonego, posortuj kolumnę z kluczem wyszukiwania w kolejności rosnącej. W przeciwnym razie może zostać zwrócona nieoczekiwana wartość. Dowiedz się, dlaczego wynik może być niepoprawny Jeśli argument posortowany ma wartość FAŁSZ, funkcja WYSZUKAJ.PIONOWO używa dopasowania ścisłego. Jeśli argument posortowany nie jest określony, ma domyślnie wartość PRAWDA. Zdecydowanie zalecamy wykonanie tych czynności: Dla argumentu posortowany użyj wartości FAŁSZ ze względu na spójne zasady działania niezależnie od tego, czy kolumna z kluczem wyszukiwania jest posortowana. Zawsze ustawiaj argument posortowany, aby zwiększyć czytelność, nawet jeśli jest on opcjonalny.

 

Wyniki

Opis

Zwracana wartość

To wartość, którą funkcja WYSZUKAJ.PIONOWO zwraca na podstawie podanych przez Ciebie danych. Każda funkcja WYSZUKAJ.PIONOWO zwraca tylko jedną wartość. Jeśli istnieje wiele pasujących wartości klucza wyszukiwania, zwracana jest wartość z kolumny wartości zwróconej, której powiązany klucz wyszukiwania został po raz pierwszy dopasowany w kolumnie klucza wyszukiwania. Zwracana jest wartość błędu #N/A, jeśli nie udało się znaleźć wartości. Jeśli napotkasz nieoczekiwaną wartość lub błąd, np. #N/A bądź #VALUE!, rozwiąż problemy. Jeśli chcesz zastąpić #N/A inną wartością, dowiedz się, jak używać funkcji JEŻELI.ND wewnątrz funkcji WYSZUKAJ.PIONOWO.

Podstawowe przykłady działania funkcji WYSZUKAJ.PIONOWO:

WYSZUKAJ.PIONOWO z różnymi kluczami wyszukiwania

Użyj funkcji WYSZUKAJ.PIONOWO, aby sprawdzić cenę (ang. „Price”) pomarańczy (ang. „Orange”) i jabłek (ang. „Apple”).

Wypróbuj

Wyjaśnienie:

WYSZUKAJ.PIONOWO pozwala na różne klucze wyszukiwania, takie jak „Apple” czy „Orange”.

Jeśli oczekiwana jest wartość inna niż błąd, klucze wyszukiwania muszą znajdować się w pierwszej kolumnie zakresu. Jeśli nie chcesz wpisywać wartości kluczy wyszukiwania, możesz użyć odwołania do komórki, np. „G9”.

klucz_wyszukiwania to „Orange”	=WYSZUKAJ.PIONOWO("Orange"; B4:D8; 3; FAŁSZ) Zwracana wartość = $1.01
klucz_wyszukiwania to „Apple”	=WYSZUKAJ.PIONOWO("Apple"; B4:D8; 3; FAŁSZ) Zwracana wartość = $1.50
klucz_wyszukiwania zawierający odwołanie do komórki „Apple” w G9	=WYSZUKAJ.PIONOWO(G9; B4:D8; 3; FAŁSZ) Zwracana wartość = $1.50

WYSZUKAJ.PIONOWO z różnymi indeksowanymi kolumnami

Użyj funkcji WYSZUKAJ.PIONOWO, aby znaleźć liczbę (ang. „Quantity”) pomarańczy (ang. „Orange”) w drugiej indeksowanej kolumnie.

Wypróbuj

Wyjaśnienie:

Gdy używasz funkcji WYSZUKAJ.PIONOWO, wyobraź sobie, że kolumny zakresu są numerowane (indeksowane) od lewej do prawej i zaczynają się od 1. Aby znaleźć żądaną informację, musisz podać indeks kolumny, w której ta informacja się znajduje. Na przykład: indeks 2 oznacza kolumnę drugą, czyli liczbę owoców („Quantity”).

Indeks = 2 Przeszukuje liczbę owoców dla pomarańczy, czyli drugą od lewej kolumnę zakresu.

=WYSZUKAJ.PIONOWO(G3; B4:D8; 2; FAŁSZ) Zwracana wartość = 5

Dopasowanie ścisłe lub przybliżone w funkcji WYSZUKAJ.PIONOWO

• Aby znaleźć identyfikator (ID) dokładny, użyj funkcji WYSZUKAJ.PIONOWO z dopasowaniem ścisłym.
• Aby znaleźć identyfikator (ID) przybliżony, użyj funkcji WYSZUKAJ.PIONOWO z dopasowaniem przybliżonym.

Wypróbuj

Wyjaśnienie:

Użyj dopasowania przybliżonego lub argumentu posortowany = PRAWDA, aby znaleźć najlepsze dopasowanie, ale nie ścisłe.

Jeśli chcesz wyszukać ID = 102, którego nie ma w tabeli, dopasowanie przybliżone cofnie się i da wynik ID = 101. Dzieje się tak, ponieważ w kolumnie klucza wyszukiwania 101 to wartość najbliższa wartości 102 (i jednocześnie nieprzekraczająca 102).

Dopasowanie przybliżone przeszukuje kolumnę klucza wyszukiwania z góry na dół, aż znajdzie wartość większą niż Twój klucz wyszukiwania. Następnie zatrzymuje się na wierszu przed większą wartością i zwraca wartość z kolumny wartości zwracanej dla wiersza, na którym się zatrzymało. Oznacza to, że jeśli kolumna klucza wyszukiwania nie jest posortowana w kolejności rosnącej, najprawdopodobniej zwracana jest nieprawidłowa wartość.

Ważne: zanim użyjesz dopasowania przybliżonego, posortuj kolumnę klucza wyszukiwania w kolejności rosnącej, aby zwracana była prawidłowa wartość. W przeciwnym razie może zostać zwrócona nieoczekiwana wartość.

Gdy szukasz dopasowania ścisłego, np. posortowany = FAŁSZ, zwracane jest dopasowanie ścisłe. Na przykład nazwa owocu dla ID = 103 to „Banana” (pol. „Banan”). Jeśli nie można znaleźć dopasowania ścisłego, pojawia się błąd #N/A. Ponieważ jest ono bardziej przewidywalne, zalecamy stosowanie dopasowania ścisłego.

Dopasowanie ścisłe	=WYSZUKAJ.PIONOWO(G6; A4:D8; 2; FAŁSZ) Zwracana wartość = Banana
Dopasowanie przybliżone	=WYSZUKAJ.PIONOWO(G3; A4:D8; 2; PRAWDA) LUB =WYSZUKAJ.PIONOWO(G3; A4:D8; 2) Zwracana wartość = Apple

Typowe zastosowania dla WYSZUKAJ.PIONOWO

Zastępowanie błędu z funkcji WYSZUKAJ.PIONOWO inną wartością

Jeśli klucz wyszukiwania nie istnieje, możesz zastąpić wartość błędu zwracanego przez funkcję WYSZUKAJ.PONOWNIE inną wartością. W takim przypadku, jeśli nie chcesz otrzymać #N/A, możesz użyć funkcji JEŻELI.ND, aby zastąpić #N/A inną wartością określoną w JEŻELI.ND. Więcej informacji o JEŻELI.ND

Wypróbuj

Początkowo funkcja WYSZUKAJ.PIONOWO zwraca #N/A, ponieważ w kolumnie „Fruit” (pol. „Owoc”) nie ma klucza wyszukiwania „Pencil” (pol. „Ołówek”). Funkcja JEŻELI.ND zastępuje błąd #N/A drugim argumentem podanym w funkcji. W naszym przypadku jest to „NOT FOUND” (pol. „NIE ZNALEZIONO”).

=JEŻELI.ND(WYSZUKAJ.PIONOWO(G3; B4:D8; 3; FAŁSZ); "NOT FOUND") Zwracana wartość = NOT FOUND

Wskazówka: jeśli chcesz zastąpić inne błędy, takie jak #REF!, dowiedz się więcej o funkcji JEŻELI.BŁĄD.

WYSZUKAJ.PIONOWO z wieloma oddzielnymi kluczami wyszukiwania

Funkcji WYSZUKAJ.PIONOWO nie można stosować dla więcej niż jednego klucza wyszukiwania jednocześnie. Zamiast tego utwórz nową kolumnę pomocniczą będącą połączeniem innych kolumn, aby klucz wyszukiwania funkcji WYSZUKAJ.PIONOWO odwoływał się bezpośrednio do jednej komórki tej kolumny pomocniczej.

Wypróbuj

1. Jeśli za pomocą znaku „&” połączysz imię z nazwiskiem, utworzysz kolumnę pomocniczą.	Zastosuj formułę =C4&D4 w komórce B4 i przeciągnij ją z komórki B4 do B8, aby utworzyć kolumnę pomocniczą.
2. Jeśli chcesz, aby kluczem wyszukiwania była wartość „JohnLee”, użyj odwołania do komórki B7.	=WYSZUKAJ.PIONOWO(B7; B4:E8; 4; FAŁSZ) Zwracana wartość = Support

WYSZUKAJ.PIONOWO z symbolami wieloznacznymi lub dopasowaniami częściowymi

W funkcji WYSZUKAJ.PIONOWO możesz też używać symboli wieloznacznych lub dopasowań częściowych. Możesz zastosować te symbole wieloznaczne:

• Znak zapytania „?” odpowiada dowolnemu pojedynczemu znakowi.
• Gwiazdka „*” odpowiada dowolnej sekwencji znaków.

Aby użyć symboli wieloznacznych w funkcji WYSZUKAJ.PIONOWO, musisz skorzystać z dopasowania ścisłego: posortowany = FAŁSZ.

Wypróbuj

Wartość „St*” pozwala dopasować każdy ciąg znaków zaczynający się od „St” (niezależnie od ostatecznej liczby znaków), np. „Steve”, „St1”, „Stock” czy „Steeeeeeve”.

=WYSZUKAJ.PIONOWO("St*"; B4:D8; 3; FAŁSZ) Zwracana wartość = Marketing

Rozwiązywanie problemów i sprawdzone metody:

Nieprawidłowa zwracana wartość

• Funkcja zwraca nieoczekiwaną wartość: jeśli ustawisz argument posortowany jako PRAWDA, ale pierwsza kolumna w zakresie nie jest posortowana rosnąco alfabetycznie bądź numerycznie, zmień ten argument na FAŁSZ.

• Funkcja WYSZUKAJ.PIONOWO zwraca pierwsze dopasowanie: WYSZUKAJ.PIONOWO zwraca tylko pierwsze dopasowanie. Jeśli masz wiele pasujących kluczy wyszukiwania, zwracana jest wartość, lecz może ona nie być oczekiwana.
• Nieoczyszczone dane: czasami wartości ze spacjami na początku i na końcu mogą wydawać się podobne do wartości bez spacji, ale WYSZUKAJ.PIONOWO traktuje je inaczej. Funkcja WYSZUKAJ.PIONOWO będzie inaczej rozpoznawać te wartości:
  • „ Apple”
  • „Apple ”
  • „Apple”

Aby uzyskać oczekiwane wyniki, usuń niepotrzebne spacje przed użyciem funkcji WYSZUKAJ.PIONOWO.

Więcej informacji znajdziesz w sekcji sprawdzonych metod.

#N/A

• Jeśli używane jest dopasowanie przybliżone lub argument posortowany = PRAWDA, a klucz wyszukiwania w funkcji WYSZUKAJ.PIONOWO jest mniejszy niż najmniejsza wartość w pierwszej kolumnie, to WYSZUKAJ.PIONOWO zwraca #N/D.
• Jeśli używane jest dopasowanie ścisłe lub posortowane = FAŁSZ, a w pierwszej kolumnie nie znaleziono dokładnego dopasowania klucza wyszukiwania funkcji WYSZUKAJ.PIONOWO. Jeśli nie chcesz wyniku #N/A, gdy w pierwszej kolumnie nie ma klucza wyszukiwania, możesz użyć funkcji JEŻELI.ND.

#REF!

Być może błędnie podano indeks większy niż maksymalna liczba kolumn zakresu. Aby tego uniknąć:

• Licz kolumny wybranego zakresu, a nie całej tabeli.
• Liczenie kolumn zacznij od 1 zamiast od 0.

#VALUE!

Jeśli wartością zwracaną jest #VALUE:

• Dla argumentu indeks niepoprawnie wpisano tekst lub nazwę kolumny.
• Argument indeks to liczba mniejsza niż 1. Wartość indeksu musi wynosić co najmniej 1 i być mniejsza bądź równa maksymalnej liczbie kolumn zakresu. Gdy argument indeks = 1, funkcja WYSZUKAJ.PIONOWO może przeszukiwać tylko kolumnę klucza wyszukiwania. Gdy wartość tego argumentu jest większa, funkcja będzie przeszukiwać odpowiednio kolejną (licząc od lewej do prawej) kolumnę.

Ważne: argument indeks może być tylko liczbą.

#NAME?

• Być może zabrakło cudzysłowów w argumencie klucz_wyszukiwania, jeśli klucz wyszukiwania jest typu tekstowego.

Sprawdzone metody

 

Co zrobić	Uzasadnienie
Używaj odwołań bezwzględnych dla zakresu.	Należy stosować: odwołania bezwzględne dla zakresu funkcji WYSZUKAJ.PIONOWO; WYSZUKAJ.PIONOWO(G3; $B$3:$D$7; 3; FAŁSZ). Nie należy stosować: WYSZUKAJ.PIONOWO(G3; B3:D7; 3; FAŁSZ). Zapobiega to nieprzewidzianym zmianom w zakresie, gdy zostanie on skopiowany lub przeciągnięty w dół.
Sortuj pierwszą kolumnę w kolejności rosnącej, gdy używasz dopasowania przybliżonego, np. posortowany = PRAWDA.	Jeśli używasz dopasowania przybliżonego lub argumentu posortowany = PRAWDA, musisz posortować pierwszą kolumnę w kolejności rosnącej. W przeciwnym razie najprawdopodobniej otrzymasz nieprawidłowy wynik. Więcej informacji o sortowaniu
Oczyść dane przed użyciem funkcji WYSZUKAJ.PIONOWO.	Zanim użyjesz funkcji WYSZUKAJ.PIONOWO, oczyść dane. Dane z niepożądanymi elementami mogą skutkować nieprzewidzianym wynikiem funkcji WYSZUKAJ.PIONOWO. Oto niektóre z najczęstszych problemów z nieoczyszczonymi danymi: spacje na początku: „ jabłko”, spacje na końcu: „jabłko ”, puste dane lub same spacje: „” i „ ” nie są interpretowane tak samo. Aby usunąć odstępy na początku lub na końcu, można kliknąć Dane Czyszczenie danych Usuń spacje.
Nie przechowuj wartości liczbowych ani daty w formie tekstu.	Upewnij się, że wartości daty i liczb w pierwszej kolumnie zakresu użytego w funkcji WYSZUKAJ.PIONOWO, takie jak kolumna klucza wyszukiwania, nie są przechowywane jako wartości tekstowe. W przeciwnym razie możesz otrzymać nieoczekiwany wynik. U góry Arkuszy wybierz kolumnę klucza wyszukiwania. Kliknij Menu Formatuj Liczba. Wybierz opcję odpowiednią dla wybranego typu danych: Data Liczba