LOPSLAG

 

Hvis du har kendte oplysninger i dit regneark, kan du bruge LOPSLAG til at søge efter relaterede oplysninger efter række. Hvis du f.eks. vil købe en appelsin, kan du bruge LOPSLAG til at søge efter prisen.

LOPSLAG til BigQuery

Lodret opslag. Returnerer værdierne i en datakolonne på den placering, hvor der blev fundet et match i søgekolonnen.

Eksempel på brug

LOPSLAG("Apple",tabelnavn!frugt,tabelnavn!pris)

Syntaks

LOPSLAG(søgenøgle, område, indeks, er_sorteret)

• søgenøgle: den værdi, der skal søges efter i søgekolonnen.
• søgekolonne: den datakolonne, der skal søges i.
• resultatkolonne: den datakolonne, resultaterne skal findes i..
• er_sorteret: [VALGFRIT] Den måde, hvor der skal findes et match for søgenøgle.
  • FALSK: Vi anbefaler, at du bruger et eksakt match.
  • SAND: Hvis der er tale om et omtrentligt match, er dette standardværdien, hvis er_sorteret ikke er angivet.
    Tip! Inden du bruger et omtrentligt match, skal du sortere din søgenøgle i stigende rækkefølge. Ellers får du sandsynligvis en forkert returværdi. Få flere oplysninger om, hvorfor du muligvis ser en forkert returværdi.

Tip! Brug XLOOKUP for mere fleksible databaseforespørgsler i BigQuery.

Syntaks

=LOPSLAG(søgenøgle, område, indeks, [er_sorteret])

Input

1. søgenøgle: Den værdi, der skal søges efter i den første kolonne i området.
2. område: De øvre og nedre værdier, der skal tages i betragtning i søgningen.
3. indeks: Indekset for kolonnen med returværdien for området. Indekset skal være et positivt heltal.
4. er_sorteret: Valgfrit input. Vælg en af mulighederne:
   • FALSK = eksakt match. Dette er anbefalet.
   • SAND = omtrentlig match. Dette er standardværdien, hvis er_sorteret ikke er angivet.
     Vigtigt! Inden du bruger et omtrentligt match, skal du sortere din søgenøgle i stigende rækkefølge. Ellers får du sandsynligvis en forkert returværdi. Se, hvorfor du muligvis ser en forkert returværdi.

Returværdi

Den første matchede værdi fra det valgte område.

Tekniske oplysninger:

Eksempel:

=LOPSLAG(G9, B4:D8, 3, FALSK)

=LOPSLAG("Apple", B4:D8, 3, SAND)

Input	Beskrivelse
søgenøgle	Dette er den værdi, du søger efter i den første kolonne i området. Hvis du forventer en værdi, der ikke er en fejl, skal søgenøglen være i den første kolonne i området. Cellereference er også understøttet. Sådan foretager du en simpel kontrol: Hvis din søgenøgle findes i B3, skal dit område starte med kolonne B.
område	Dette er det område, hvor: Funktionen søger efter den angivne søgenøgle i den første kolonne. LOPSLAG returnerer værdien fra den kolonne, der er angivet af indeks. Du kan også bruge et navngivet område. Hvis du vil returnere en værdi, der ikke er en fejl, skal din søgenøgle være i den første kolonne i intervallet. Sådan foretager du en simpel kontrol: Hvis din søgenøgle findes i B3, skal dit område starte med kolonne B.
indeks	Kaldes også "Kolonnenummer". Dette er indekset for kolonnen i det område, der indeholder returværdien. Det mindst mulige indeks er 1. Det størst mulige indeks er det maksimale antal kolonner i det pågældende område. Når du har konfigureret området, leder LOPSLAG kun i kolonnen med søgenøglen, når indeks = 1, eller kolonner, der er længere til højre. Tip! Når du bruger LOPSLAG, skal du forestille dig, at kolonnerne i området er nummereret fra venstre mod højre og starter med 1.
er_sorteret	Dette er et valgfrit input. De to tilgængelige valg er SAND og FALSK. Hvis er_sorteret er SAND, bruger LOPSLAG omtrentligt match. Vigtigt! Inden du bruger et omtrentligt match, skal du sortere din søgenøgle i stigende rækkefølge. Ellers kan du få en uventet værdi returneret. Få flere oplysninger om, hvorfor du muligvis ser en forkert returværdi. Hvis er_sorteret er FALSK, bruger LOPSLAG eksakt match. Hvis er_sorteret ikke er angivet, bruges SAND som standard. Vi anbefaler, at du: Brug FALSK for er_sorteret på grund af dens konsekvente adfærd, uanset om kolonnen med søgenøglen er sorteret eller ej. Angiv altid er_sorteret for at øge læsevenligheden, selvom input er valgfrit.

 

Output

Beskrivelse

Returværdi

Dette er den værdi, som LOPSLAG returnerer baseret på dine input. Der er kun én returværdi fra hver funktion for LOPSLAG. Hvis der er flere søgenøgleværdier, der matcher, returneres værdien i den returværdiolonne, hvis tilknyttede søgenøgle først matches i søgenøglekolonnen. Hvis #N/A returneres, blev der ikke fundet en værdi. Hvis du ser en forventet værdi eller en forventet fejl, f.eks. #N/A eller #VALUE!, skal du finde og løse problemer. Hvis du vil erstatte #N/A med en anden værdi, kan du få flere oplysninger om, hvordan du bruger HVISIT() på LOPSLAG().

Grundlæggende eksempler på LOPSLAG:

LOPSLAG på forskellige søgenøgler

Brug LOPSLAG til at finde prisen på Orange og Apple.

Prøv det

Forklaring:

Når du bruger LOPSLAG, kan du bruge forskellige søgenøgler, f.eks. "Apple" og "Orange".

Hvis du vil returnere en værdi, der ikke er en fejl, skal disse søgenøgler være i den første kolonne i området. Hvis du ikke vil udfylde en værdi for søgenøgler, kan du også bruge en cellereference, f.eks. "G9".

søgenøgle er "Orange"	=LOPSLAG("Orange", B4:D8, 3, FALSK) Returværdi = $1.01
søgenøgle er "Apple"	=LOPSLAG("Apple", B4:D8, 3, FALSK) Returværdi = $1.50
søgenøgle, der bruger cellereference af "Apple" i G9	=LOPSLAG(G9, B4:D8, 3, FALSK) Returværdi = $1.50

LOPSLAG på forskellige kolonneindekser

Brug LOPSLAG til at finde antallet af appelsiner i den anden indekskolonne.

Prøv det

Forklaring:

Når du bruger LOPSLAG, kan du forestille dig, at kolonnerne i området er nummereret fra venstre mod højre og starter med 1. Du skal angive kolonneindekset for at finde måloplysningerne. Eksempel: Kolonne 2 for mængde.

Indeks = 2 Find mængden af appelsiner, som er den anden kolonne i området.

=LOPSLAG(G3, B4:D8, 2, FALSK) Returværdi = 5

Eksakt match eller omtrentligt match for LOPSLAG

• Brug eksakt match for LOPSLAG for at finde et eksakt id.
• Brug det omtrentlige match fra LOPSLAG til at finde det omtrentlige id.

Prøv det

Forklaring:

Brug et omtrentligt match eller er_sorteret = SAND, når du søger efter det bedste match, men ikke et eksakt match.

Hvis du vil søge efter id = 102, som ikke findes i tabellen, tager det omtrentlige match ét skridt tilbage for at give dig id = 101 som resultat. Dette skyldes, at 101 i kolonnen med søgenøglen er den nærmeste værdi, som også er mindre end 102.

Et omtrentligt match søger i kolonnen med søgenøglen, indtil den finder en værdi, der er større end din søgenøgle. Derefter stopper den på rækken før den større værdi og returnerer værdien fra returværdikolonnen på den pågældende række. Hvis din søgekolonne ikke er sorteret i stigende rækkefølge, betyder dette, at du sandsynligvis får en forkert returværdi.

Vigtigt! Inden du bruger et omtrentligt match, skal du sortere din søgenøgle i stigende rækkefølge for at returnere den korrekte værdi. Ellers kan du få en uventet værdi returneret.

Når du søger efter det eksakte match, f.eks. er_sorteret = FALSK, returneres der et eksakt match. F.eks. er frugtnavnet for id = 103 "Banana". Hvis der ikke er noget eksakt match, får du vist en #N/A-fejl. Vi anbefaler, at du bruger eksakt match, da det har en mere forudsigelig adfærd.

Eksakt match	=LOPSLAG(G6, A4:D8, 2, FALSK) Returværdi = "Banana"
Omtrentlig match	=LOPSLAG(G3, A4:D8, 2, SAND) ELLER =LOPSLAG(G3, A4:D8, 2) Returværdi = "Banana"

Almindelige LOPSLAG-apps

Erstat fejlværdi fra LOPSLAG

Det er en god idé at erstatte en fejlværdi, der returneres af LOPSLAG, når din søgenøgle ikke findes. Hvis du i dette tilfælde ikke vil have #N/A, kan du bruge funktionen HVISIT() til at erstatte #N/A. Få flere oplysninger om HVISIT().

Prøv det

Oprindeligt returneres #N/A af LOPSLAG, fordi søgenøgle "Pencil" ikke findes i kolonnen "Fruit". HVISIT() erstatter #N/A-fejl med det andet input, der er angivet i funktionen. I vores tilfælde er det "IKKE FUNDET".

=HVISIT(LOPSLAG(G3, B4:D8, 3, FALSK),"IKKE FUNDET") Returværdi = "IKKE FUNDET"

Tip! Hvis du vil erstatte andre fejl såsom #REF!, kan du få flere oplysninger om HVIS.FEJL().

LOPSLAG med flere kriterier

LOPSLAG kan ikke anvendes direkte på flere kriterier. Opret i stedet en ny kolonne med hjælpere, så du anvender LOPSLAG direkte på flere kriterier for at kombinere flere eksisterende kolonner.

Prøv det

1. Du kan oprette en kolonne med hjælpere, hvis du bruger "&" til at kombinere fornavn og efternavn.	=C4&D4, og træk den ned fra B4 til B8 for at få vist kolonnen Helper.
2. Brug cellereference B7, JohnLee, som søgenøgle.	=LOPSLAG(B7, B4:E8, 4, FALSK) Returværdi = "Support"

LOPSLAG med jokertegn eller delvise match

I LOPSLAG kan du også bruge jokertegn eller delvise match. Du kan bruge disse jokertegn:

• Et spørgsmålstegn "?" matcher alle enkeltstående tegn.
• En stjerne "*" matcher alle sekvenser af tegn.

Hvis du vil bruge jokertegn i LOPSLAG, skal du bruge et eksakt match: "er_sorteret = FALSK".

Prøv det

"St*" bruges til at matche alt, der starter med "St" uanset antallet af tegn, f.eks. "Steve", "St1", "Stok" eller "Steeeeeeve".

=LOPSLAG("St*", B4:D8, 3, FALSK) Returværdi = "Marketing"

Find og ret fejl samt bedste fremgangsmåder:

Forkert returværdi

• Returnerer en uventet værdi: Hvis du angiver er_sorteret som SAND, men din første kolonne i området ikke sorteres numerisk eller alfabetisk i stigende rækkefølge, ændrer du derefter er_sorteret til FALSK.

• LOPSLAG giver det første match: LOPSLAG returnerer kun det første match. Hvis du har flere matchende søgenøgler, returneres en værdi, men det er muligvis ikke den forventede værdi.
• Ikke-opryddede data: Nogle gange kan værdier med foran- eller bagvedstående mellemrum virke ens, men LOPSLAG behandler dem forskelligt. Følgende er f.eks. anderledes end LOPSLAG:
  • " Apple"
  • "Apple "
  • "Apple"

For at få de forventede resultater skal du fjerne mellemrum, før du bruger LOPSLAG.

Du kan få flere oplysninger i sektionen med de bedste fremgangsmåder.

#N/A

• Hvis omtrentlig eller er_sorteret = SAND anvendes, og hvis søgenøglen i LOPSLAG er mindre end den mindste værdi i den første kolonne, så returneres #N/A af LOPSLAG.
• Hvis eksakt match eller er_sorteret = FALSK bruges, findes det eksakte match af søgenøglen i LOPSLAG ikke i den første kolonne. Hvis du ikke vil have #N/A, når søgenøglen ikke findes i den første kolonne, kan du bruge funktionen HVISIT().

#REF!

Du kan fejlagtigt angive et område med et tal, der er større end det maksimale antal kolonner i området. Du kan undgå dette ved at sørge for følgende:

• Tæl kolonnerne fra det valgte område, ikke hele tabellen.
• Tæl fra 1 i stedet for 0.

#VALUE!

Hvis du får #VALUE!, kan du have:

• Indtastet teksten eller kolonnenavnet for indekset forkert.
• Angivet et tal, der er mindre end 1, for indekset. Indekset skal være mindst 1 og mindre end det maksimale antal kolonner i området. LOPSLAG kan kun søge i kolonnen med søgenøglen, når indeks = 1, eller kolonner, der er længere til højre.

Vigtigt! Indeks accepterer kun et tal.

#NAME?

• Du kan have overset et citat i søgenøglen, når din søgenøgle er tekstdata.

Bedste fremgangsmåder

 

Opgaver	Årsag
Brug absolutte referencer for område	Du skal bruge: Absolut reference for områder LOPSLAG. LOPSLAG(G3, $B$3:$D$7, 3, FALSK) Du bør ikke bruge: LOPSLAG(G3, B3:D7, 3, FALSK) Dette forhindrer uforudsigelige ændringer i området, når det kopieres eller trækkes ned.
Sortér den første kolonne i stigende rækkefølge, når du bruger et omtrentligt match, f.eks. er_sorteret = SAND.	Hvis du bruger et omtrentligt match eller er_sorteret = SAND, skal du sortere den første kolonne i stigende rækkefølge. Ellers får du sandsynligvis en forkert returværdi. Få flere oplysninger om, hvordan du sorterer.
Ryd op i dine data, inden du bruger LOPSLAG	Husk at rydde op i dine data, før du bruger LOPSLAG. Ikke-opryddede data kan medføre, at LOPSLAG returnerer en uforudsigelig værdi. Her er nogle almindelige faldgruber i forbindelse med rene data: Foranstående mellemrum: " apple" Bagvedstående mellemrum: "apple " Tommer felter eller mellemrum: "" og " " er ikke ækvivalente Hvis du vil fjerne foran- eller bagvedstående blanktegn, kan du bruge Data Dataoprydning Fjern blanktegn.
Gem ikke tal- eller datoværdier som tekst	Sørg for, at dato- eller talværdierne i den første kolonne i dit LOPSLAG-område, f.eks. søgenøglen, ikke gemmes som tekstværdier. Du kan modtage en uventet returværdi. Vælg kolonnen med din søgenøgle øverst i Sheets. Tryk på menuen Format Tal. Vælg en af mulighederne afhængigt af den ønskede datatype: Dato Tal