VERT.ZOEKEN

 

Als er bekende gegevens in een spreadsheet staan, kun je VERT.ZOEKEN gebruiken om te zoeken naar gerelateerde informatie per rij. Als je bijvoorbeeld een sinaasappel wilt kopen, kun je zoeken naar de prijs met VERT.ZOEKEN.

VERT.ZOEKEN voor BigQuery

Verticaal zoeken. Retourneert de waarden in een gegevenskolom op de positie waar een overeenkomst is gevonden in de zoekkolom.

Gebruiksvoorbeelden

VERT.ZOEKEN("Appel",tabelnaam!fruit,tabelnaam!prijs)

Syntaxis

VERT.ZOEKEN(zoeksleutel, bereik,index, is_gesorteerd)

• zoeksleutel: De waarde waarnaar wordt gezocht in de zoekkolom.
• zoekkolom: De gegevenskolom die voor de zoekopdracht moet worden gebruikt.
• resultaatkolom: De gegevenskolom die voor het resultaat moet worden gebruikt.
• is_gesorteerd: [OPTIONEEL] De manier waarop er wordt gezocht naar een overeenkomst voor de zoeksleutel.
  • ONWAAR: Aangeraden voor een exacte overeenkomst.
  • WAAR: Voor een overeenkomst bij benadering is dit de standaardwaarde als je is_gesorteerd niet opgeeft.
    Tip: Sorteer de zoeksleutel in oplopende volgorde voordat je een overeenkomst bij benadering gebruikt. Anders krijg je waarschijnlijk een verkeerde retourwaarde. Ontdek waarom je een verkeerde retourwaarde kunt krijgen.

Tip: Gebruik XLOOKUP voor flexibelere databasequery's in BigQuery.

Syntaxis

=VERT.ZOEKEN(zoeksleutel, bereik, index, [is_gesorteerd])

Invoer

1. zoeksleutel: De waarde waarnaar wordt gezocht in de 1e kolom van het bereik.
2. bereik: De hoogste en laagste waarden die moeten worden meegenomen in de zoekopdracht.
3. index: De index van de kolom met de retourwaarde van het bereik. De index moet een positief geheel getal zijn.
4. is_gesorteerd: Optionele invoer. Kies een optie:
   • ONWAAR: Exacte overeenkomst. Dit wordt aangeraden.
   • TRUE: Overeenkomst bij benadering. Dit is de standaardinstelling als je is_gesorteerd niet opgeeft.
     Belangrijk: Sorteer de zoeksleutel in oplopende volgorde voordat je een overeenkomst bij benadering gebruikt. Anders krijg je waarschijnlijk een verkeerde retourwaarde. Ontdek waarom je een verkeerde retourwaarde kunt krijgen.

Retourwaarde

De 1e overeenkomende waarde uit het geselecteerde bereik.

Technische gegevens:

Voorbeeld:

=VERT.ZOEKEN(G9, B4:D8, 3, ONWAAR)

=VERT.ZOEKEN("Appel", B4:D8, 3, WAAR)

Invoer	Beschrijving
zoeksleutel	Dit is de waarde waarnaar wordt gezocht in de 1e kolom van het bereik. Als je een waarde wilt krijgen die geen fout is, moet de zoeksleutel in de 1e kolom van het bereik staan. Celverwijzing wordt ook ondersteund. Zo check je dit makkelijk: Als de zoeksleutel in B3 staat, moet het bereik beginnen met kolom B.
bereik	Dit is het bereik. Hiervoor geldt het volgende: De functie zoekt in de 1e kolom naar de opgegeven zoeksleutel. VERT.ZOEKEN retourneert de waarde uit de kolom die je hebt opgegeven bij index. Je kunt ook een benoemd bereik gebruiken. Als je een waarde wilt krijgen die geen fout is, moet de zoeksleutel in de 1e kolom van het bereik staan. Zo check je dit makkelijk: Als de zoeksleutel in B3 staat, moet het bereik beginnen met kolom B.
index	Ook wel Kolomnummer genoemd. Dit is de index van de kolom in het bereik die de retourwaarde bevat. De kleinst mogelijke index is 1. De grootst mogelijke index is het maximale aantal kolommen in dat bereik. Nadat je het bereik hebt ingesteld, kijkt VERT.ZOEKEN alleen naar de kolom met de zoeksleutel als index = 1, of een kolom die verder naar rechts staat. Tip: Als je VERT.ZOEKEN gebruikt, stel je je voor dat de kolommen van het bereik van links naar rechts zijn genummerd, beginnend met 1.
is_gesorteerd	Dit is een optionele invoer. De 2 beschikbare opties zijn WAAR en ONWAAR. Als is_gesorteerd gelijk is aan WAAR, gebruikt VERT.ZOEKEN een overeenkomst bij benadering. Belangrijk: Sorteer de zoeksleutel in oplopende volgorde voordat je een overeenkomst bij benadering gebruikt. Anders kun je een onverwachte retourwaarde krijgen. Ontdek waarom je een verkeerde retourwaarde kunt krijgen. Als is_gesorteerd gelijk is aan ONWAAR, gebruikt VERT.ZOEKEN een exacte overeenkomst. Als je is_gesorteerd niet opgeeft, wordt standaard WAAR gebruikt. We raden je sterk aan het volgende te doen: Gebruik ONWAAR voor is_gesorteerd, omdat je dan altijd dezelfde waarden krijgt, ook als de kolom met zoeksleutels niet is gesorteerd. Geef is_gesorteerd altijd op voor meer leesbaarheid, ook al is deze invoer optioneel.

 

Uitvoer

Beschrijving

Retourwaarde

Dit is de waarde die VERT.ZOEKEN retourneert op basis van de invoer. Je krijgt maar één retourwaarde voor elke VERT.ZOEKEN-functie. Als er meerdere zoeksleutelwaarden overeenkomen, wordt de waarde uit de kolom met retourwaarden geretourneerd waarvan de gekoppelde zoeksleutel het eerst overeenkomt in de kolom met zoeksleutels. Als #N/A wordt geretourneerd, is er geen waarde gevonden. Als je een onverwachte waarde of fout tegenkomt, zoals #N/A of #VALUE!, begin je met de probleemoplossing. Als je #N/A wilt vervangen door een andere waarde, ontdek je hoe je ALS.NB() gebruikt in VERT.ZOEKEN().

Voorbeelden van basisopdrachten met VERT.ZOEKEN:

VERT.ZOEKEN voor verschillende zoeksleutels

Gebruik VERT.ZOEKEN om de prijs van een sinaasappel en een appel te vinden.

Probeer het nu

Uitleg:

Als je VERT.ZOEKEN gebruikt, kun je verschillende zoeksleutels gebruiken, zoals Appel en Sinaasappel.

Als je een waarde wilt krijgen die geen fout is, moet deze zoeksleutel in de 1e kolom van het bereik staan. Als je geen waarde wilt invoeren voor zoeksleutels, kun je ook een celverwijzing gebruiken, bijvoorbeeld G9.

zoeksleutel is Sinaasappel	=VERT.ZOEKEN("Sinaasappel", B4:D8, 3, ONWAAR) Retourwaarde = $ 1,01
zoeksleutel is Appel	=VERT.ZOEKEN("Appel", B4:D8, 3, ONWAAR) Retourwaarde = $ 1,50
zoeksleutel die de celverwijzing Appel gebruikt in G9	=VERT.ZOEKEN(G9, B4:D8, 3, ONWAAR) Retourwaarde = $ 1,50

VERT.ZOEKEN voor verschillende kolomindexen

Gebruik VERT.ZOEKEN om de hoeveelheid sinaasappels te vinden in de 2e indexkolom.

Probeer het nu

Uitleg:

Als je VERT.ZOEKEN gebruikt, stel je je voor dat de kolommen van het bereik van links naar rechts zijn genummerd, beginnend met 1. Je moet de kolomindex opgeven om de doelinformatie te vinden. Bijvoorbeeld kolom 2 voor het aantal.

Index = 2 Zoek de hoeveelheid sinaasappels, die staat in de 2e kolom van het bereik.

=VERT.ZOEKEN(G3, B4:D8, 2, ONWAAR) Retourwaarde = 5

Exacte overeenkomst of overeenkomst bij benadering met VERT.ZOEKEN

• Gebruik een exacte overeenkomst met VERT.ZOEKEN om een exacte ID te vinden.
• Gebruik een overeenkomst bij benadering met VERT.ZOEKEN om de ID bij benadering te vinden.

Probeer het nu

Uitleg:

Gebruik een overeenkomst bij benadering of is_gesorteerd = WAAR als je zoekt naar de beste overeenkomst, maar niet een exacte overeenkomst.

Als je wilt zoeken op ID = 102, die niet in de tabel voorkomt, ga je met een overeenkomst bij benadering een stap terug en krijg je ID = 101 als resultaat. Dit komt omdat in de zoeksleutelkolom 101 de waarde is die het dichtst bij 102 ligt en die kleiner is dan 102.

Een overeenkomst bij benadering zoekt in de kolom met zoeksleutels totdat er een waarde wordt gevonden die groter is dan de zoeksleutel. De zoekopdracht stopt dan in de rij vóór die grotere waarde en retourneert de waarde uit de kolom met retourwaarden van die rij. Als je de kolom met zoeksleutels dus niet hebt gesorteerd in oplopende volgorde, krijg je waarschijnlijk een verkeerde retourwaarde.

Belangrijk: Sorteer de zoeksleutel in oplopende volgorde voordat je een overeenkomst bij benadering gebruikt, om de juiste waarde te krijgen. Anders kun je een onverwachte retourwaarde krijgen.

Als je zoekt naar een exacte overeenkomst, zoals is_gesorteerd = ONWAAR, wordt er een exacte overeenkomst geretourneerd. De fruitnaam van ID = 103 is bijvoorbeeld Banaan. Als er geen exacte overeenkomst is, krijg je de fout #N/A. We raden je aan exacte overeenkomsten te gebruiken, omdat je hierbij precies weet wat je kunt verwachten.

Exacte overeenkomst	=VERT.ZOEKEN(G6, A4:D8, 2, ONWAAR) Retourwaarde = Appel
Overeenkomst bij benadering	=VERT.ZOEKEN(G3, A4:D8, 2, WAAR) OF =VERT.ZOEKEN(G3, A4:D8, 2) Retourwaarde = Banaan

Veelgebruikte toepassingen voor VERT.ZOEKEN

Foutwaarde van VERT.ZOEKEN vervangen

Je kunt instellen dat een foutwaarde wordt vervangen als die wordt geretourneerd door VERT.ZOEKEN wanneer de zoeksleutel niet bestaat. Als je #N/A niet wilt gebruiken, kun je ALS.NB() gebruiken om #N/A te vervangen. Ontdek meer over ALS.NB().

Probeer het nu

Oorspronkelijk retourneert VERT.ZOEKEN #N/A, omdat de zoektoets Potlood niet in de kolom Fruit staat. ALS.NB() vervangt de #N/A-fout door de 2e invoer die je opgeeft in de functie. In dit geval is dat NIET GEVONDEN.

=ALS.NB(VERT.ZOEKEN(G3, B4:D8, 3, ONWAAR),"NIET GEVONDEN") Retourwaarde = NIET GEVONDEN

Tip: Als je andere fouten wilt vervangen, zoals #REF!, ontdek je meer informatie over ALS.FOUT().

VERT.ZOEKEN met meerdere criteria

Je kunt VERT.ZOEKEN niet rechtstreeks toepassen op meerdere criteria. Maak in plaats daarvan een nieuwe helperkolom om VERT.ZOEKEN direct toe te passen op meerdere criteria, om meerdere bestaande kolommen te combineren.

Probeer het nu

1. Je kunt een helperkolom maken door Voornaam en Achternaam te combineren met &.	Voer =C4&D4 in en sleep naar beneden van B4 naar B8 om de helperkolom te maken.
2. Gebruik celverwijzing B7, JohnLee als zoeksleutel.	=VERT.ZOEKEN(B7, B4:E8, 4, ONWAAR) Retourwaarde = Support

VERT.ZOEKEN met jokerteken of gedeeltelijke overeenkomsten

Je kunt met VERT.ZOEKEN ook jokertekens of gedeeltelijke overeenkomsten gebruiken. Je kunt deze jokertekens gebruiken:

• Een vraagteken ? komt overeen met elk individueel teken.
• Een sterretje * komt overeen met elke reeks tekens.

Als je jokertekens wilt gebruiken in VERT.ZOEKEN, moet je een exacte overeenkomst gebruiken: is_gesorteerd = ONWAAR.

Probeer het nu

Met St* vind je alles wat begint met St, ongeacht het aantal tekens. Dus Steve, St1, Straat of Steeeeeeve.

=VERT.ZOEKEN("St*", B4:D8, 3, ONWAAR) Retourwaarde = Marketing

Foutopsporing en best practices:

Verkeerde retourwaarde

• Er wordt een onverwachte waarde geretourneerd: Als je is_gesorteerd instelt op WAAR, maar de 1e kolom in het bereik niet numeriek of alfabetisch hebt gesorteerd in oplopende volgorde, moet je is_gesorteerd veranderen in ONWAAR.

• VERT.ZOEKEN geeft de 1e overeenkomst: VERT.ZOEKEN retourneert alleen de 1e overeenkomst. Als er meerdere overeenkomende zoeksleutels zijn, wordt er een waarde geretourneerd, maar is dit misschien niet de verwachte waarde.
• Gecorrumpeerde gegevens: Soms zien waarden met spaties aan het begin of einde er hetzelfde uit, maar deze worden anders behandeld door VERT.ZOEKEN. De volgende waarden zijn bijvoorbeeld niet hetzelfde voor VERT.ZOEKEN:
  • " Appel"
  • "Appel "
  • "Appel"

Verwijder spaties voordat je VERT.ZOEKEN gebruikt om de verwachte resultaten te krijgen.

Ga naar het gedeelte met best practices voor meer informatie.

#N/A

• Als je een overeenkomst bij benadering of is_gesorteerd = WAAR gebruikt en als de zoeksleutel in VERT.ZOEKEN kleiner is dan de kleinste waarde in de 1e kolom, retourneert VERT.ZOEKEN de waarde #N/A.
• Als je een exacte overeenkomst of is_gesorteerd = ONWAAR gebruikt, wordt de exacte overeenkomst van de zoeksleutel in VERT.ZOEKEN niet gevonden in de 1e kolom. Als je niet wilt dat #N/A wordt getoond wanneer de zoeksleutel niet worden gevonden in de 1e kolom, kun je ALS.NB() gebruiken.

#REF!

Je hebt misschien per ongeluk een bereik opgeven met een getal dat groter is dan het maximale aantal kolommen van het bereik. Doe het volgende om dit te voorkomen:

• Gebruik het aantal de kolommen in het geselecteerde bereik, niet de hele tabel.
• Tel vanaf 1 in plaats van 0.

#VALUE!

Als je de fout #VALUE! krijgt, kan dit de volgende redenen hebben:

• Je hebt niet de juiste tekst of kolomnaam voor de index opgegeven.
• Je hebt een getal kleiner dan 1 opgegeven voor de index. De index moet minstens gelijk zijn aan 1 en kleiner zijn dan het maximale aantal kolommen in het bereik. VERT.ZOEKEN kan alleen zoeken in de kolom met zoeksleutels als index = 1 of een kolom die verder naar rechts staat.

Belangrijk: Je kunt alleen getallen invoeren bij index.

#NAME?

• Als zoeksleutel bestaat uit tekstgegevens, ontbreekt er misschien een aanhalingsteken.

Best practices

 

Doen	Reden
Gebruik absolute verwijzingen voor bereik	Gebruik het volgende: Absolute verwijzing voor VERT.ZOEKEN-bereik VERT.ZOEKEN(G3, $B$3:$D$7, 3, ONWAAR) Gebruik niet het volgende: VERT.ZOEKEN(G3, B3:D7, 3, ONWAAR) Zo voorkom je onvoorspelbare wijzigingen in het bereik als je het kopieert of versleept.
Sorteer de 1e kolom in oplopende volgorde als je een overeenkomst bij benadering gebruikt, dus is_gesorteerd = WAAR.	Als je een overeenkomst bij benadering of is_gesorteerd = WAAR gebruikt, moet je de 1e kolom sorteren in oplopende volgorde. Anders krijg je waarschijnlijk een verkeerde retourwaarde. Ontdek hoe je kolommen sorteert.
Schoon de gegevens op voordat je VERT.ZOEKEN gebruikt	Vergeet niet de gegevens op te schonen voordat je VERT.ZOEKEN gebruikt. Als gegevens gecorrumpeerd zijn, kan VERT.ZOEKEN onvoorspelbare waarden retourneren. Dit zijn enkele voorbeelden: Spaties aan het begin: " appel" Spaties aan het einde: "appel " Witruimtes of spaties: "" is niet hetzelfde als " " Als je spaties aan het begin of einde wilt verwijderen, kun je Gegevens Gegevensopschoning Witruimte bijsnijden gebruiken.
Sla getal- of datumwaarden niet op als tekst	Zorg dat de datum- of getalwaarden in de 1e kolom van het VERT.ZOEKEN-bereik, zoals de kolom met zoeksleutels, niet zijn opgeslagen als tekstwaarden. Anders kun je een onverwachte retourwaarde krijgen. Selecteer bovenin Spreadsheets de kolom met zoeksleutels. Tik op het menu Opmaak Getal. Kies de juiste optie: Datum Getal