FINN.RAD (VLOOKUP)

 

Hvis du har kjent informasjon i regnearket, kan du bruke FINN.RAD til å søke etter relatert informasjon etter rad. Hvis du for eksempel vil kjøpe en appelsin, kan du bruke FINN.RAD til å søke etter prisen.

FINN.RAD for BigQuery

FINN.RAD er et vertikalt søk som leter etter samsvar i en søkekolonne, og returnerer verdiene i en datakolonne på samme sted som samsvaret ble funnet.

Eksempler på bruk

FINN.RAD("Eple";tabellnavn!frukt;tabellnavn!pris)

Syntaks

FINN.RAD(søkenøkkel; område; indeks; er_sortert)

• søkenøkkel: Verdien funksjonen skal søke etter i søkekolonnen.
• søkekolonne: Datakolonnen funksjonen skal søke i.
• resultatkolonne: Datakolonnen resultatet skal returneres i.
• er_sortert: [VALGFRITT] hvordan funksjonen skal lete etter samsvar, i henhold til søkenøkkel.
  • USANN: anbefales hvis du vil ha eksakt samsvar.
  • SANN: standardinnstilling for omtrentlig samsvar hvis er_sortert er uspesifisert.
    Tips: Før du bruker omtrentlig samsvar, må du sortere søkenøkkelen i stigende rekkefølge. Ellers kan det hende at du får feil returverdi. Finn ut hvorfor du kan få feil returverdi.

Tips: Bruk XLOOKUP for mer fleksible databasesøk i BigQuery.

Syntaks

=FINN.RAD(søkenøkkel; område; indeks; [er_sortert])

Inndata

1. søkenøkkel: verdien det skal søkes etter i den første kolonnen i området.
2. område: den høyeste og den laveste verdien som skal tas med i søket.
3. indeks: indeksen for kolonnen med returverdien for området. Indeksen må være et positivt heltall.
4. er_sortert: valgfri parameter. Velg et alternativ:
   • USANN = eksakt samsvar. Dette anbefales.
   • SANN = omtrentlig samsvar. Dette er standardinnstillingen hvis er_sortert er uspesifisert.
     Viktig: Før du bruker omtrentlig samsvar, må du sortere søkenøkkelen i stigende rekkefølge. Ellers kan det hende at du får feil returverdi. Finn ut hvorfor du kan få feil returverdi.

Returverdi

Den første samsvarende verdien fra det valgte området.

Tekniske detaljer

:

Eksempel:

=FINN.RAD(G9; B4:D8; 3; USANN)

=FINN.RAD("Eple"; B4:D8; 3; SANN)

Inndata	Beskrivelse
søkenøkkel	Dette er verdien du søker etter i den første kolonnen i et område. Hvis du forventer verdier som ikke er feil, må søkenøkkelen være i den første kolonnen i området. Cellereferanser støttes også. Slik sjekker du det: Hvis søkenøkkelen er plassert i B3, skal området starte med kolonne B.
område	Dette er området der funksjonen søker etter den angitte søkenøkkelen i den første kolonnen FINN.RAD returnerer verdien fra kolonnen som er angitt av indeks Du kan også bruke et navngitt område. For å returnere en verdi som ikke er feil, må søkenøkkelen være i den første kolonnen i området. Slik sjekker du det: Hvis søkenøkkelen er plassert i B3, skal området starte med kolonne B.
indeks	Dette kalles også «kolonnenummer». Dette er indeksen for kolonnen i området som inneholder returverdien. Den laveste mulige indeksen er 1. Den høyeste mulige indeksen er det maksimale antallet kolonner i det området. Når du har konfigurert området, ser FINN.RAD bare på søkenøkkelkolonnen, når indeks = 1, eller kolonner som ligger lenger til høyre. Tips: Når du bruker FINN.RAD, kan du se for deg at kolonnene i området er nummerert fra venstre til høyre, og at de begynner med 1.
er_sortert	Dette er valgfritt. De to tilgjengelige alternativene er SANN og USANN. Hvis er_sortert er SANN, bruker FINN.RAD omtrentlig samsvar. Viktig: Før du bruker omtrentlig samsvar, må du sortere søkenøkkelen i stigende rekkefølge. Hvis ikke kan du få en uventet returverdi. Finn ut hvorfor du kan få feil returverdi. Hvis er_sortert er USANN, bruker FINN.RAD eksakt samsvar. Hvis er_sortert ikke er angitt, er den SANN som standard. Vi anbefaler på det sterkeste at du bruker USANN for er_sortert fordi den har konsekvent atferd uansett om søkenøkkelkolonnen er sortert eller ikke alltid angir er_sortert for bedre lesbarhet, selv om det er valgfritt å bruke den

 

Utdata

Beskrivelse

Returverdi

Dette er verdien FINN.RAD returnerer basert på inndataene dine. Det er bare én returverdi fra hver FINN.RAD-funksjon. Hvis det finnes flere søkenøkkelverdier som samsvarer, returneres verdien i returverdikolonnen der den relaterte søkenøkkelen samsvarer først, i søkenøkkelkolonnen. Hvis #I/T returneres, er det ikke funnet noen verdi. Hvis du støter på en forventet verdi eller feil, for eksempel #I/T eller #VERDI!, kan du begynne å feilsøke. Hvis du vil bytte ut #I/T med en annen verdi, kan du finne ut mer om hvordan du bruker HVIS.IT() i FINN.RAD().

Grunnleggende eksempler på FINN.RAD:

FINN.RAD med forskjellige søkenøkler

Bruk FINN.RAD til å finne prisen på appelsiner eller epler.

Prøv nå

Forklaring:

Når du bruker FINN.RAD, kan du bruke forskjellige søkenøkler, for eksempel «Eple» eller «Appelsin».

For å returnere en verdi som ikke er feil, må disse søkenøklene være i den første kolonnen i området. Hvis du ikke vil fylle ut en verdi for søkenøkler, kan du bruke en cellereferanse i stedet, for eksempel «G9».

søkenøkkel er «Appelsin»	=FINN.RAD("Appelsin"; B4:D8; 3; USANN) Returverdi = $1.01
søkenøkkel er «Eple»	=FINN.RAD("Eple"; B4:D8; 3; USANN) Returverdi = $1.50
søkenøkkel som bruker cellereferansen til «Eple» i G9	=FINN.RAD(G9; B4:D8; 3; USANN) Returverdi = $1.50

FINN.RAD i ulike kolonneindekser

Bruk FINN.RAD til å finne antallet appelsiner i den andre indekskolonnen.

Prøv nå

Forklaring:

Når du bruker FINN.RAD, kan du se for deg at kolonnene i området er nummerert fra venstre til høyre, og at de begynner med 1. For å finne målinformasjonen må du angi kolonneindeksen. Eksempel: kolonne 2 for antall.

Indeks = 2 Finn antallet appelsiner, som er den andre kolonnen i området.

=FINN.RAD(G3; B4:D8; 2; USANN) Returverdi = 5

FINN.RAD – eksakt samsvar eller omtrentlig samsvar

• Bruk eksakt samsvar for FINN.RAD for å finne en eksakt ID.
• Bruk omtrentlig samsvar for FINN.RAD for å finne den omtrentlige ID-en.

Prøv nå

Forklaring:

Bruk et omtrentlig samsvar eller er_sortert = SANN når du søker etter beste samsvar, men ikke et eksakt samsvar.

Hvis du vil søke etter ID = 102, som ikke finnes i tabellen, går omtrentlig samsvar ett steg tilbake og returnerer ID = 101. Det er fordi 101 er den nærmeste verdien som også er lavere enn 102 i søkenøkkelkolonnen.

Omtrentlig samsvar søker nedover i søkenøkkelkolonnen til det finner en verdi som er større enn søkenøkkelen. Deretter stopper den på raden før den større verdien og returnerer verdien fra returverdikolonnen i den raden. Det betyr at hvis søkenøkkelkolonnen ikke er sortert i stigende rekkefølge, får du sannsynligvis feil returverdi.

Viktig: Før du bruker omtrentlig samsvar, må du sortere søkenøkkelen i stigende rekkefølge, slik at riktig verdi blir returnert. Hvis ikke kan du få en uventet returverdi.

Når du søker etter eksakt samsvar, for eksempel er_sortert = USANN, returneres et eksakt samsvar. Navnet på frukten med ID = 103 er for eksempel «Banan». Hvis det ikke finnes noe eksakt samsvar, får du en #I/T-feil. På grunn av den mer forutsigbare atferden, anbefaler vi at du bruker eksakt samsvar.

Eksakt samsvar	=FINN.RAD(G6; A4:D8; 2; USANN) Returverdi = «Eple»
Omtrentlig samsvar	=FINN.RAD(G3; A4:D8; 2; SANN) ELLER =FINN.RAD(G3; A4:D8; 2) Returverdi = «Banan»

Vanlig bruk av FINN.RAD

Erstatt feilverdien fra FINN.RAD

Det kan være lurt å erstatte en feilverdi som returneres av FINN.RAD, når søkenøkkelen ikke finnes. Hvis du ikke vil ha #I/T, kan du bruke HVIS.IT()-funksjonen til å erstatte #I/T. Finn ut mer om HVIS.IT().

Prøv nå

FINN.RAD returnerer opprinnelig #I/T fordi søkenøkkelen «Blyant» ikke finnes i «Frukt»-kolonnen. HVIS.RAD() erstatter #I/T-feil med de sekundære inndataene som er angitt i funksjonen. I vårt tilfelle er det «IKKE FUNNET».

=HVIS.IT(FINN.RAD(G3; B4:D8; 3; USANN);"IKKE FUNNET") Returverdi = «IKKE FUNNET»

Tips: Hvis du vil erstatte andre feil, for eksempel #REF!, kan du finne ut mer om HVISFEIL().

FINN.RAD med flere kriterier

FINN.RAD kan ikke brukes direkte på flere kriterier. I stedet kan du opprette en ny hjelpekolonne hvis du vil bruke FINN.RAD direkte på flere kriterier for å kombinere flere eksisterende kolonner.

Prøv nå

1. Du kan opprette en hjelpekolonne hvis du bruker «&» til å kombinere fornavn og etternavn.	=C4&D4 og dra ned fra B4 til B8 for å få frem hjelpekolonnen.
2. Bruk cellereferansen B7, JohnLee, som søkenøkkel.	=FINN.RAD(B7; B4:E8; 4; USANN) Returverdi = «Brukerstøtte»

FINN.RAD med jokertegn eller delvis samsvar

I FINN.RAD kan du også bruke jokertegn eller delvis samsvar. Du kan bruke disse jokertegnene:

• Et spørsmålstegn «?» samsvarer med et hvilket som helst enkelttegn.
• En stjerne «*» samsvarer med en hvilken som helst tegnsekvens.

For å bruke jokertegn i FINN.RAD må du bruke eksakt samsvar: «er_sortert = USANN».

Prøv nå

«St*» brukes til å finne alt som begynner med «St», uavhengig av antallet tegn, for eksempel «Steve», «St1», «Stokk» eller «Steeeeeeve».

=FINN.RAD("St*"; B4:D8; 3; USANN) Returverdi = «Markedsføring»

Feilsøk feil og anbefalte fremgangsmåter:

Feil returverdi

• Returnerer en uventet verdi: Hvis du angir er_sortert som SANN, men den første kolonnen i området ikke er sortert numerisk eller alfabetisk i stigende rekkefølge, må du endre er_sortert til USANT.

• FINN.RAD returnerer første treff: FINN.RAD returnerer bare det første treffet. Hvis du har flere søkenøkler som samsvarer, returneres en verdi som kanskje ikke er den du forventer.
• Uriktige data: Noen ganger kan verdier som har mellomrom før eller etter, se ut til å være like, men FINN.RAD behandler dem ulikt. For eksempel er disse eksemplene ulike for FINN.RAD:
  • « Eple»
  • «Eple »
  • «Eple»

For å få de resultatene du forventer, må du fjerne mellomrom før du bruker FINN.RAD.

Finn ut mer om dette i delen om anbefalte fremgangsmåter.

#I/T

• Hvis omtrentlig eller er_sortert = SANN brukes, og hvis søkenøkkelen i FINN.RAD er mindre enn den laveste verdien i den første kolonnen, returnerer FINN.RAD #I/T.
• Hvis eksakt samsvar eller er_sortert = USANNbrukes, blir ikke det eksakte samsvaret for søkenøkkelen i FINN.RAD funnet i den første kolonnen. Hvis du ikke vil at #I/T skal returneres når søkenøkkelen ikke blir funnet i den første kolonnen, kan du bruke HVIS.IT()-funksjonen.

#REF!

Det kan hende du feilaktig angir et område med et større tall enn det maksimale antallet kolonner i området. For å unngå dette må du gjøre følgende:

• Tell kolonnene fra det valgte området – ikke hele tabellen.
• Begynn å telle fra 1 i stedet for 0.

#VERDI!

Hvis du får feilen #VERDI!, kan det hende du har

• skrevet feil i teksten eller kolonnenavnet for indeksen
• angitt et tall som er mindre enn 1, for indeksen. Indeksen må være minst 1 og mindre enn det maksimale antallet kolonner i området. FINN.RAD kan bare søke i søkenøkkelkolonnen når indeks = 1, eller i kolonner som ligger lengre til høyre.

Viktig: Indeksen godtar bare tall.

#NAVN?

• Du kan ha glemt et anførselstegn i søkenøkkelen når søkenøkkelen er tekstdata.

Anbefalte fremgangsmåter

 

Gjøremål	Årsak
Bruk absolutte referanser for område.	Du bør bruke absolutte referanser for FINN.RAD-området FINN.RAD(G3; $B$3:$D$7; 3; USANN) Du bør ikke bruke FINN.RAD(G3; B3:D7; 3; USANN) Dette hindrer uforutsigbare endringer i området når det kopieres eller dras ned.
Sorter den første kolonnen i stigende rekkefølge når du bruker omtrentlig samsvar, for eksempel er_sortert = SANN.	Hvis du bruker omtrentlig samsvar eller er_sortert = SANN, må du sortere den første kolonnen i stigende rekkefølge. Ellers får du mest sannsynlig en feil returverdi. Finn ut mer om hvordan du sorterer.
Rydd opp i dataene dine før du bruker FINN.RAD.	Før du bruker FINN.RAD, må du huske å rydde opp i dataene dine. Uriktige data kan føre til at FINN.RAD returnerer en uforutsigbar verdi. Her er noen vanlige fallgruver med uriktige data: Mellomrom før: « eple» Mellomrom etter: «eple » Tomme verdier eller mellomrom: «» og « » er ikke like Hvis du vil fjerne mellomrom før eller etter, kan du bruke Data Dataopprydding Fjern mellomrom.
Ikke lagre tall- eller datoverdier som tekst.	Sørg for at dato- og tallverdiene i den første kolonnen i FINN.RAD-området, for eksempel søkenøkkelkolonnen, ikke lagres som tekstverdier. Det kan hende du får en uventet returverdi. Velg søkenøkkelkolonnen øverst i Regneark. Trykk på Format-meny Tall. Velg et alternativ avhengig av datatypen du ønsker: Dato Tall