HYPERLINK

データからテキストまたは画像のリンクを作成します。

HYPERLINK 関数では、データソースに Hyperlink フィールドと Image Link フィールドが作成されます。Hyperlink フィールドでは表内にテキストリンクを表示し、Image Link フィールドでは表内にクリック可能な画像を表示します。

この記事の内容:

構文

HYPERLINK(URL, Link Label)

 

パラメータ:

  • URL - URL として評価されるフィールドまたは式。
  • Link Label - Text または Image として評価されるフィールドまたは式。

HYPERLINK 関数の仕組み

HYPERLINK 関数では、まず URL とリンクラベルの 2 つのパラメータを受け取ります。どちらのパラメータも必須です。

URL パラメータは、データソースの既存の URL フィールドから取得するか、他のフィールドや関数から URL を作成する式を指定します。

Link Label パラメータでは、表内に表示するテキストまたは画像を指定します。Hyperlink フィールドの作成に必要な Link Label パラメータでは、データソースの Text ディメンションから値を取得するか、Text として評価される式を指定します。Image Link フィールドの作成に必要な Link Label パラメータでは、データソースの Image ディメンションから値を取得するか、Image として評価される式を指定します。Image フィールドは、IMAGE 関数を使って作成します。

HYPERLINK 関数では次のプロトコルを使用できます。

  • http:
  • https:
  • mailto:
  • ftp:

サポートされていないプロトコルを指定した場合は、リンクで空白のページが表示されます。プロトコルが指定されていない場合は、URL の先頭に http: が想定されて追加されます。

Hyperlink フィールドと Image Link フィールドでは、[タイプ] プルダウン メニューが無効になっています。

リンクとして完全な URL を表示するには、URL フィールド タイプを使用します。

HYPERLINK の例

URL フィールドと Text フィールドからリンクを作成する

次のフィールドを含むデータセットがある場合を考えてみましょう。

  • Product Page Path: 商品説明ページの完全な URL
  • SKU: 商品の ID
  • Pageviews: 各ページのトラフィック

例:

Product Page Path SKU Pageviews
http://my.company.com/productpages/product123.html 123 100
http://my.company.com/productpages/product456.html 456 400
http://my.company.com/productpages/product789.html 789 700

 

この例からデータソースを作成すると、各フィールドは次のように表されます。

フィールド タイプ
Product Page Path URL
SKU Text
Pageviews Number

 

商品説明ページのリンクを表示するには、次の式の SKU Link 計算フィールドを作成します。

HYPERLINK(Product Page Path, SKU )

この場合、データソースは次のようになります。

フィールド タイプ
SKU Link Hyperlink
Product Page Path URL
SKU Text
Pageviews Number

 

SKU Link フィールドを使用するレポートの表には、次のデータがクリック可能なリンクとして表示されます。

SKU Link Pageviews
123 100
456 400
789 700

CONCAT を使用して URL を作成する

フィールドにデータの一部のみを表示する場合や、リンクの一部をオーバーライドする場合は、CONCAT 関数を使って URL を作成すると便利です。

次の例では、CONCAT を使って、YouTube アナリティクス データソースから完全な URL(動画の URL ではなく、動画の ID とタイトルを含む URL)を作成します。

HYPERLINK(CONCAT('https://www.youtube.com/watch?v=', External Video Id), Video Title)

個々の動画のリンクを作成するには、この式を使ってリテラル URL(元のテキスト)と External Video Id フィールドを組み合わせます。動画タイトルはクリック可能なリンクとなります。

HYPERLINK を使ったレポートの例

クリック可能な画像を作成する

Image Link フィールドを作成するには、1 つ目のパラメータとして URL を 指定し、2 つ目の HYPERLINK パラメータとして、Image フィールドまたは画像の有効なリンクを含む IMAGE 関数を指定します。

たとえば、YouTube のサムネイルを表内にクリック可能なリンクとして表示する方法は次のとおりです。

  1. YouTube アナリティクスのデータソースを編集します
  2. 新しい計算フィールド(Video URL など)を作成します
  3. 次の式を使って URL フィールドを作成します
CONCAT('https://www.youtube.com/watch?v=', External Video Id)
  1. 新しい計算フィールド(Video Thumbnail など)を作成します
  2. 次の式を使って Image フィールドを作成します
IMAGE(CONCAT('https://i.ytimg.com/vi/', External Video Id, '/hqdefault.jpg'), Video Title)
  1. 新しい計算フィールド(Clickable Thumbnail など)を作成します
  2. 次の式を使って Image Link フィールドを作成します
HYPERLINK(Video URL, Video Thumbnail)
  1. 以下の例のように、表内で Clickable Thumbnail フィールドを使ってクリック可能なリンクを表示します。

Image Link を使ったレポートの例

この情報は役に立ちましたか?
改善できる点がありましたらお聞かせください。