MIN()

リスト内の最小値を返します。リストが値のない空のリストの場合は 0 を返します。

使用例

MIN(商品[価格]) は、商品テーブルの価格列にあるすべての値の中から、最小の値を返します。これは MIN(SELECT(商品[価格], TRUE)) と同等です。関連情報: SELECT()

MIN([割引]) は、割引列の値に含まれる最小値のアイテムを返します。ここで、割引は List 型です。

MIN(LIST(1, 2, 3)) は、Number 値の 1 を返します。

選択値のうちの最小値

過去 6 か月以内の非従業員への最低販売価格:

MIN(
  SELECT(
    販売[販売価格],
    AND(
      ISNOTBLANK([販売価格]),
      NOT([顧客].[従業員か]),
      ([販売日] > (
        EOMONTH(TODAY(), -7) + DAY(TODAY())
      ))
    )
  )
)

1. SELECT(販売[販売価格], ...) は、販売テーブルの行から販売価格列に含まれる値のリストを返します。
2. AND(..., ..., ...) は、返される値を、指定されたすべての条件と一致する行の値のみに制限します。
3. ISNOTBLANK([販売価格]) は、販売価格列の値が空白ではない行のみを含めます。
4. NOT([顧客].[従業員か]) は、顧客列の値が、顧客が従業員であることを示している顧客レコードを参照している行を除外します。
5. [販売日] > ... は、販売日列の値が計算された日付より後になっている行のみを含めます。
6. EOMONTH(TODAY(), -7) + DAY(TODAY() は、今日から 6 か月前の日付を計算します。
7. MIN(...) は、販売価格の値の選択リスト内の最小値を返します。

関連情報: AND()、DAY()、EOMONTH()、ISNOTBLANK()、NOT()、SELECT()、TODAY()

一般的な問題

MIN(1, 2, 3): この例では引数がリスト形式になっていません。これを修正するには、MIN(LIST(1, 2, 3)) のように、引数を LIST() でラップしてリストを構成します。

構文

MIN(リスト)

• リスト - 任意の数値型または任意の時間型のリスト（両方を混在させることはできません）。

注意事項

AppSheet では、リストに含まれる値の型を判別するために、その内容が適切な型であることを示す十分なコンテキストが必要です。そのため、リストは、適切な値が含まれる List 型の列値、適切な型の列の列リスト（商品[価格] など）、（LIST() などで）構成された適切な型のリストのいずれかにする必要があります。

関連情報

AVERAGE()

COUNT()

MAX()

STDEVP()

SUM()