Date
または DateTime
値から月の最終日の日付を返します。
使用例
EOMONTH("3/15/2020", 3)
は 6/30/2020
を返します。
EOMONTH("2/1/2020", 0)
は 2/29/2020
を返します。
EOMONTH(TODAY(), 0)
または EOMONTH(NOW(), 0)
は現在の月の最終日を返します。
EOMONTH(TODAY(), 1)
は翌月の最終日を返します。
EOMONTH(TODAY(), -1)
は前月の最終日を返します。これは (TODAY() - DAY(TODAY()))
と同等です。
EOMONTH(TODAY(), 0) + 1
は、翌月の初日の日付を返します。
EOMONTH(TODAY(), -1) + 1
は、今月の初日の日付を返します。これは (TODAY() - DAY(TODAY()) + 1)
と同等です。
EOMONTH(TODAY(), -2) + 1
は、先月の初日の日付を返します。
EOMONTH(TODAY(), 0) + DAY(TODAY())
は、今日から 1 か月後の日付を返します。
EOMONTH(TODAY(), -1) + DAY(TODAY())
は今日の日付を返します。これは TODAY()
と同等です。
EOMONTH(TODAY(), -2) + DAY(TODAY())
は、今日から 1 か月前の日付を返します。
(DAY(EOMONTH(("2/1/" & (YEAR(TODAY()) + 1)), 0)) > 28)
(Yes / No
を返す)は、翌年がうるう年の場合に TRUE
を返します。
構文
EOMONTH(日時, オフセット月数)
日時
-Date
値またはDateTime
値。オフセット月数
(Number
): 月の最終日を計算する前に、日時
に加算または減算する月数。たとえば、0
は、日時
に指定された月の最終日を取得します。1
は、日時
の 1 か月後の最終日を取得します。-1
は、日時
の 1 か月前の最終日を取得します。
注
AppSheet では、"MM/DD/YYYY"
などの一部の定数値は Date
値として評価されます。同様に、"000:00:00"
は Duration
値として評価されます。ただし、スプレッドシートのデータを同じ形式にする必要はありません。スプレッドシートの日付と時刻の形式は、ロケールと言語の設定によって決まります。Column は常に列型として評価されます。また、DATE()
、TIME()
、DATETIME()
などの関数を使用すると、データ、両方の列、文字列リテラルを特定の型に変換できます。