日付が認識される場合は曜日を Number
値(1
~7
、1
は日曜日)で返します。認識されない場合(入力が無効な場合)は 0
を返します。
使用例
WEEKDAY("1/1/2019")
: 3
INDEX(LIST("日曜日", "月曜日", "火曜日", "水曜日", "木曜日", "金曜日", "土曜日"), WEEKDAY("1/1/2019"))
は火曜日
(Text
)を返します。関連情報: INDEX()
、LIST()
WEEKDAY(TODAY())
は今日の曜日を数値で返します。関連情報: TODAY()
(TODAY() - WEEKDAY(TODAY()))
は先週の土曜日の日付を返します。
(TODAY() - WEEKDAY(TODAY()) + 6)
は今週の金曜日の日付を返します。
(TODAY() - WEEKDAY(TODAY()) + 7 + 4)
は来週の水曜日の日付を返します。
([曜日] - WEEKDAY(TODAY()))
は今日から今週の [曜日]
(1
は日曜日、...、7
は土曜日)のオフセットを返します(例: 0
は今日、-1
は昨日、1
は明日)。
(TODAY() + ([曜日] - WEEKDAY(TODAY())))
または(より直感的と思われる)(TODAY() - WEEKDAY(TODAY()) + [曜日])
は、現在の週の [曜日]
の日付を返します。
([日付] + ([曜日] - WEEKDAY([日付])))
または ([日付] - WEEKDAY([日付]) + [曜日])
は、[日付]
を含む週の [曜日]
の日付を返します。
MOD(([曜日] - WEEKDAY([日付]) + 7), 7)
は、[日付]
またはその日より後の [曜日]
のオフセットを返します。関連情報: MOD()
MOD(([曜日] - WEEKDAY([日付]) - 7), 7)
は、[日付]
またはその日より前の [曜日]
のオフセットを返します。
([日付] + MOD(([曜日] - WEEKDAY([日付]) + 7), 7))
は、[日付]
またはその日より後の最初の [曜日]
の日付を返します。
([日付] + MOD(([曜日] - WEEKDAY([日付]) - 7), 7))
は、[日付]
またはその日より前の最初の [曜日]
の日付を返します。
([日付] - DAY([日付]) + 1)
または (EOMONTH([日付], -1) + 1)
は、[日付]
を含む月の初日を返します。関連情報: DAY()
、EOMONTH()
(([日付] - DAY([日付]) + 1) + MOD(([曜日] - WEEKDAY([日付] - DAY([日付]) + 1) + 7), 7))
は、[日付]
を含む月の最初の [曜日]
の日付を返します。
(EOMONTH([日付], 0) + MOD(([曜日] - WEEKDAY(EOMONTH([日付], 0)) - 7), 7))
は、[日付]
を含む月の最後の [曜日]
の日付を返します。
((([日付] - DAY([日付]) + 1) + MOD(([曜日] - WEEKDAY([日付] - DAY([日付]) + 1) + 7), 7)) + (([序数] - 1) * 7))
は、[日付]
を含む月の [序数]
番目の [日付]
の日付を返します。
構文
WEEKDAY(日時)
日時
-Date
値またはDateTime
値。
注
AppSheet では、"MM/DD/YYYY"
などの一部の定数値は Date
値として評価されます。同様に、"000:00:00"
は Duration
値として評価されます。ただし、スプレッドシートのデータを同じ形式にする必要はありません。スプレッドシートの日付と時刻の形式は、ロケールと言語の設定によって決まります。Column は常に列型として評価されます。また、DATE()
、TIME()
、DATETIME()
などの関数を使用すると、データ、両方の列、文字列リテラルを特定の型に変換できます。