ANY()

次のように、リストから 1 個の項目を返します。

• リストが LIST() などで作成されている場合は、リストの最初の項目。
• リストが FILTER() または SELECT() などで生成されている場合は、任意の 1 項目。
• リストが空の場合は空白。

注: SORT() でラップしない限り、リスト内の順序は保証されません。

使用例

ANY(学生[名前]) は、学生テーブルの名前列から任意の値を返します。学生[名前] 列リスト内の値の順序は、SORT() でラップしない限り保証されないため、任意の値になります。これは ANY(SELECT(学生[名前], TRUE)) と同等です。関連情報: SELECT()

ANY(LIST(1, 2, 3)) は 1（数値）を返します。

ANY({"Red", "Yellow", "Green"}) は Red（テキスト）を返します。

列の値

任意の行セットから 1 つの列値:

ANY(SELECT(商品[価格], ([カラー] = "Orange")))

1. SELECT(商品[価格], ...) は、商品テーブルの行で選択条件に一致する価格列の値を返します。
2. [カラー] = "Orange" は、カラー列の値が Orange と完全に一致する行のみに選択範囲を限定します。
3. ANY(...) は、列値のリストから任意の値を返します。

同等: LOOKUP("Orange", "商品", "カラー", "価格")

関連情報: LOOKUP()、SELECT()

列内の最大値

最も高い商品価格:

ANY(TOP(SORT(商品[価格], TRUE), 1))

1. 商品[価格] は、商品テーブルの価格列からすべての値のリストを取得します。
2. SORT(..., TRUE) は、降順、つまり大きい値から小さい値の順（TRUE）で価格のリストを並べ替えます。
3. TOP(..., 1) は、並べ替えたリストの最初の価格を返します。
4. ANY(...) は、上位リストから残りの価格の 1 つを返します。
5. MAX(商品[価格]) と同等です。

MAX(商品[価格]) と同等です。

関連情報: MAX()、SORT()、TOP()

優先する値

空白でない携帯電話番号、勤務先電話番号、自宅電話番号から値を選択:

ANY(
  TOP(
    (
      LIST([携帯電話番号], [勤務先電話番号], [自宅電話番号])
      - LIST("")
    ),
    1
  )
)

1. LIST([携帯電話番号], [勤務先電話番号], [自宅電話番号]) は、3 つの番号のリストを作成します。
2. LIST(...) - LIST("") は、番号のリストから空白の項目を削除します。
3. TOP(..., 1) は、空白でない番号のリストから最初の項目を返します。
4. ANY(...) は、上位リストから空白でない残りの番号の 1 つを返します。

次と同等です。

INDEX(
  (
    LIST([携帯電話番号], [勤務先電話番号], [自宅電話番号])
    - LIST("")
  ),
  1
)

参考情報: LIST()、INDEX()、TOP()

列内の最大値を持つ行

Sandwich 先生のクラスで GPA が最も高い学生の行:

ANY(
  TOP(
    ORDERBY(
      FILTER("学生",
        AND(
          ISNOTBLANK([教師]),
          ([教師] = "Mr Sandwich")
        )
      ),
      [GPA], TRUE
    ),
    1
  )
)

1. FILTER("学生", ...) は、学生テーブルから、条件と一致するキー値のリストを返します。
2. AND(..., ...) は、指定されたサブ条件のすべてと一致する行のみにフィルタを制限します。
3. ISNOTBLANK([教師]) は、教師列の値が空白でないことを条件とします。
4. [教師] = "Mr Sandwich" は、教師列の値が Mr Sandwich であることを条件とします。
5. ORDERBY(..., [GPA], TRUE) は、フィルタされたキーを、対応する GPA 列の値を基準に降順、つまり大きい値から小さい値の順（TRUE）で並べ替えて、最も高い GPA を先頭に配置します。
6. TOP(..., 1) は、並べ替えたリストの最初の項目を返します（GPA の最も高い行のキーを取得します）。
7. ANY(...) は、上位リストの残りのエントリの 1 つを返します。これは、Sandwich 先生のクラスで GPA が最も高い学生の行のキーです。

次と同等です。

MAXROW(
  "学生", "GPA",
  AND(
    ISNOTBLANK([教師]),
    ([教師] = "Mr Sandwich")
  )
)

関連情報: AND()、FILTER()、ISNOTBLANK()、ORDERBY()、MAXROW()、TOP()

一般的な問題

ANY(1, 2, 3): 引数がリスト形式になっていません。これを修正するには、ANY(LIST(1, 2, 3)) のように、引数を LIST() でラップしてリストを構成します。

構文

ANY(リスト)

• リスト - 任意の型のリスト。

関連情報

INDEX()

TOP()