SORTN

排序後傳回資料集中前 n 個項目。

用法示範

SORTN(A1:A10, 2)

SORTN(A2:C20, 2, 2, B2:B20, TRUE)

SORTN(A2:C20, 2, 3, B2:B20, TRUE, 3, FALSE)

語法

SORTN(範圍, [n], [顯示所有和局], [排序欄_1, 遞增_1], ...)

• 範圍 - 要以排序方式找出前 n 個項目所用的資料。
• n - [選擇性 - 預設為 1] 傳回的項目數 (必須大於 0)。
• 顯示和局模式 - [選擇性 - 預設為 0] 顯示和局方式的代表數字。
  • 0：顯示排序範圍中的前 n 列。
  • 1：顯示前 n 列，以及與第 n 列相同的任何其他列。
  • 2：顯示移除重複列後的前 n 列。
  • 3：顯示不重複的前 n 列，以及與這些列重複的列。

• 排序欄_1 - [選擇性] - 範圍內的資料欄索引，或是在指定範圍以外需要排序的值。指定為排序欄_1的範圍須為單一欄，且與範圍的列數相同。

• 遞增_1 - [選擇性] - TRUE 或 FALSE 代表排序欄_1 的排序方式。設為 TRUE 代表以遞增方式排序；設為 FALSE 表示以遞減方式排序。
• 排序欄_2, 遞增_2, ... - [選擇性] - 如果發生和局，以優先順序為依據的其他欄及排序順序標記。

說明

• 範圍「只會」對指定資料欄進行排序，其他欄則是按原有順序傳回。
• 如果不附上排序欄_1 和 遞增_1，系統會根據範圍內的最低序位欄進行排序，但如果和局則會使用後面的欄來排序。

另請參閱

• SORT：以一欄或多欄中的值為依據，排列指定陣列或範圍內的資料列順序。
• FILTER：傳回來源範圍的篩選後版本，只傳回符合指定條件的資料列或資料欄。
• MAX：傳回數字資料集中的最大值。
• INDEX：傳回以列偏移與欄偏移方式指定的儲存格包含內容。
• LARGE：傳回資料集中第 n 大的項目，n 為使用者自行設定的變數。

範例

下方範例是根據下表製作而成。

	A	B	C
1	學生	測驗 1 分數	測驗 2 分數
2	麗麗	100	90
3	巴伯	75	85
4	凱凱	80	85
5	迪迪	100	95
6	艾羅	80	90

 

公式	結果
=SORTN(A2:C6)	麗麗 100 90
=SORTN(A2:C6, 2)	麗麗 100 90 巴伯 75 85
=SORTN(A2:C6, 3, 0, B2:B6, FALSE)	麗麗 100 90 迪迪 100 95 凱凱 80 85
=SORTN(A2:C6, 3, 1, B2:B6, FALSE)	麗麗 100 90 迪迪 100 95 凱凱 80 85 艾羅 80 90
=SORTN(A2:C6, 3, 2, B2:B6, FALSE)	麗麗 100 90 凱凱 80 85 巴伯 75 85
=SORTN(A2:C6, 3, 3, B2:B6, FALSE)	麗麗 100 90 迪迪 100 95 凱凱 80 85 艾羅 80 90 巴伯 75 85
=SORTN(A2:C6, 3, 3, 2, FALSE, 3, FALSE)	迪迪 100 95 麗麗 100 90 艾羅 80 90