SORTN

Retorna os primeiros n itens em um conjunto de dados após a classificação.

Exemplo de uso

SORTN(A1:A10, 2)

SORTN(A2:C20, 2, 2, B2:B20, VERDADEIRO)

SORTN(A2:C20, 2, 3, B2:B20, VERDADEIRO, 3, FALSO)

Sintaxe

SORTN(intervalo, [n], [mostrar_todos_os_empates], [classificar_coluna1, é_crescente1], ...)

• intervalo: os dados a serem classificados para encontrar os primeiros n itens.
• n [OPCIONAL, 1 por padrão]: o número de itens a serem retornados. Deve ser maior que 0.
• modo_de_exibição_de_empates [OPCIONAL, 0 por padrão]: um número que representa a forma de exibir empates.
  • 0: mostra no máximo as primeiras n linhas no intervalo classificado.
  • 1: mostra no máximo as primeiras n linhas, além de linhas adicionais idênticas à enésima linha.
  • 2: mostra no máximo as primeiras n linhas após remover linhas duplicadas.
  • 3: mostra no máximo as primeiras n linhas exclusivas, mas mostra todas as linhas que são duplicatas dessas linhas.

• classificar_coluna1 [OPCIONAL]: o índice da coluna em intervalo ou um intervalo fora de INTERVALO contendo os valores a serem usados na classificação. Um intervalo especificado como classificar_coluna1 precisa ser uma só coluna com o mesmo número de linhas que intervalo.

• é_crescente1 [OPCIONAL] VERDADEIRO ou FALSO: indica como classificar "classificar_coluna1". VERDADEIRO classifica em ordem crescente. FALSO faz com que a classificação seja decrescente.
• classificar_coluna2, é_crescente2, ... [OPCIONAL]: Colunas adicionais e sinalizações de ordem de classificação usadas se ocorrer um empate, em ordem de prioridade.

Observações

• intervalo é classificado apenas pelas colunas especificadas. Outras colunas são retornadas na ordem em que aparecem originalmente.
• Se os argumentos classificar_coluna1 e é_crescente1 não estiverem incluídos, a classificação será feita na coluna do índice mais baixo em intervalo, com as colunas subsequentes usadas na classificação se houver empates.

Consulte também

• SORT: classifica as linhas de determinada matriz ou intervalo pelos valores em uma ou mais colunas.
• FILTER: retorna uma versão filtrada do intervalo de origem, apresentando somente as linhas ou colunas que satisfaçam às condições especificadas.
• MÁXIMO: retorna o valor máximo em um conjunto de dados numéricos.
• ÍNDICE: retorna o conteúdo de uma célula especificada pelo deslocamento de linha e coluna.
• MAIOR: retorna o enésimo maior elemento de um conjunto de dados, onde n é definido pelo usuário.

Exemplos

A tabela a seguir é usada para os exemplos abaixo.

	A	B	C
1	Aluno	Pontuação do teste 1	Pontuação do teste 2
2	Alice	100	90
3	Beto	75	85
4	Carol	80	85
5	Daniel	100	95
6	Heloísa	80	90

 

Fórmula	Resultado
=SORTN(A2:C6)	Alice 100 90
=SORTN(A2:C6, 2)	Alice 100 90 Beto 75 85
=SORTN(A2:C6, 3, 0, B2:B6, FALSO)	Alice 100 90 Daniel 100 95 Carol 80 85
=SORTN(A2:C6, 3, 1, B2:B6, FALSO)	Alice 100 90 Daniel 100 95 Carol 80 85 Heloísa 80 90
=SORTN(A2:C6, 3, 2, B2:B6, FALSO)	Alice 100 90 Carol 80 85 Beto 75 85
=SORTN(A2:C6, 3, 3, B2:B6, FALSO)	Alice 100 90 Daniel 100 95 Carol 80 85 Heloísa 80 90 Beto 75 85
=SORTN(A2:C6, 3, 3, 2, FALSO, 3, FALSO)	Daniel 100 95 Alice 100 90 Heloísa 80 90