SORTN

정렬을 수행한 후 데이터 집합에서 첫 n개의 항목을 반환합니다.

사용 예

SORTN(A1:A10, 2)

SORTN(A2:C20, 2, 2, B2:B20, TRUE)

SORTN(A2:C20, 2, 3, B2:B20, TRUE, 3, FALSE)

구문

SORTN(범위, [n], [모든_동점_표시], [열_정렬1, 오름차순1], ...)

  • 범위 - 첫 n개의 항목을 찾기 위해 정렬할 데이터입니다.
  • n - [선택사항 - 기본값은 1] 반환할 항목의 개수입니다. 0보다 커야 합니다.
  • 동점_표시_모드 - [선택사항 - 기본값은 0] 동점을 표시할 방법을 나타내는 숫자입니다.
    • 0: 정렬된 범위 내에서 첫 번째 행부터 최대 n개의 행을 표시합니다.
    • 1: 첫 번째 행부터 최대 n개의 행을 표시하는 동시에 n번째 행과 내용이 동일한 다른 행도 표시합니다.
    • 2: 중복 행을 삭제한 후에 첫 번째 행부터 최대 n개의 행을 표시합니다.
    • 3: 첫 번째 행부터 최대 n개의 서로 다른 행을 표시하지만 내용이 동일한 행까지 포함됩니다.
  • 열_정렬1 - [선택사항] - 정렬의 기준이 될 값을 포함하는 범위 내 또는 범위 밖에 있는 열의 색인입니다. 열_정렬1로 지정된 범위는 범위와 동일한 수의 행을 갖는 한 개의 열이어야 합니다.

  • 오름차순1 - [선택사항] - TRUE 또는 FALSE로 열_정렬1을 어떻게 정렬할지 지정합니다. TRUE는 오름차순으로 정렬하며 FALSE는 내림차순으로 정렬합니다.
  • 열_정렬2, 오름차순2, ... - [선택사항] - 동점이 발생 시 사용할 수 있는 추가 열 및 정렬 순서 기준이며, 함수에 나열된 순서대로 정렬에 영향을 줍니다.

참고

  • 범위는 지정된 열을 기준으로 정렬됩니다. 다른 열은 원래 표시되는 순서로 반환됩니다.
  • 열_정렬1오름차순1이 포함되어 있지 않은 경우 범위 내에 있는 가장 낮은 색인 열을 기준으로 정렬되며 동점이 있는 경우 다음 열이 사용됩니다.

더보기

  • SORT: 지정된 배열 또는 범위의 행을 하나 이상의 열의 값을 기준으로 정렬합니다.
  • FILTER: 지정된 조건을 충족하는 열 또는 행만 반환하여 원본 범위를 필터링한 버전을 반환합니다.
  • MAX: 숫자 데이터 세트의 최대값을 반환합니다.
  • INDEX: 행과 열 오프셋으로 지정된 셀의 콘텐츠를 반환합니다.
  • LARGE: 데이터 세트에서 n번째로 큰 요소를 반환합니다(n은 사용자가 지정하는 수).

다음 표는 아래 예에 사용됩니다.

  A B C
1 학생 테스트 1 점수 테스트 2 점수
2 지현 100 90
3 영철 75 85
4 초희 80 85
5 경호 100 95
6 수영 80 90

 

수식 결과
=SORTN(A2:C6)

지현 100 90

=SORTN(A2:C6, 2)

지현 100 90
영철 75 85

=SORTN(A2:C6, 3, 0, B2:B6, FALSE)

지현 100 90
경호 100 95
초희 80 85

=SORTN(A2:C6, 3, 1, B2:B6, FALSE)

지현 100 90
경호 100 95
초희 80 85
수영 80 90

=SORTN(A2:C6, 3, 2, B2:B6, FALSE)

지현 100 90
초희 80 85
영철 75 85

=SORTN(A2:C6, 3, 3, B2:B6, FALSE)

지현 100 90
경호 100 95
초희 80 85
수영 80 90
영철 75 85

=SORTN(A2:C6, 3, 3, 2, FALSE, 3, FALSE)

경호 100 95
지현 100 90
수영 80 90

도움이 되었나요?
어떻게 하면 개선할 수 있을까요?