SORTN

並べ替えたデータセット内の最初の n 個の項目を返します。

使用例

SORTN(A1:A10, 2)

SORTN(A2:C20, 2, 2, B2:B20, TRUE)

SORTN(A2:C20, 2, 3, B2:B20, TRUE, 3, FALSE)

構文

SORTN(範囲, [n], [同等項目の表示モード], [並べ替え基準列1, 昇順1], ...)

  • 範囲 - このデータ範囲を並べ替えて最初の n 個の項目を探します。
  • n - [省略可 - 既定値は 1] 返す項目の数です。0 より大きな値を指定してください。
  • 同等項目の表示モード - [省略可 - 既定値は 0] 同等項目をどのように表示するかを示す数字です。
    • 0: 範囲内を並び替えて最初の n 行(n 行に満たない場合はすべての行)を表示します。
    • 1: 最初の n 行(n 行に満たない場合はすべての行)を表示し、さらに n 行目と同じ値の行があれば追加で表示します。
    • 2: 重複する行を削除したうえで、最初の n 行(n 行に満たない場合はすべての行)を表示します。
    • 3: 最初の一意の n 行(n 行に満たない場合はすべての行)と、それぞれの重複行を表示します。
  • 並べ替え基準列1 - [省略可] - 並べ替え基準の値を含む範囲内の列の番号または範囲外の範囲を指定します。並べ替え基準列1として指定する範囲は、範囲と同じ行数を含む単一の列とする必要があります。

  • 昇順1 - [省略可] - 並べ替え基準列1 で並べ替える際の方法を TRUE または FALSE で指定します。TRUE を指定すると昇順で並べ替えられます。FALSE を指定すると降順で並べ替えられます。
  • 並べ替え基準列2, 昇順2, ... - [省略可] - 同等項目があった際に順序の特定に使用する、追加の列と並べ替え順のフラグです。

メモ

  • range は、指定された列によってのみ並び替えられます。他の列は元から表示されていた順序で返されます。
  • 並べ替え基準列1昇順1 を指定しない場合、range 内で最も小さなインデックス列に基づいて並べ替えられます。後続の列が、同等項目があった場合の並べ替えに使用されます。

関連項目

  • SORT: 指定された配列または範囲の列を 1 つまたは複数の列の値によって並び替えます。
  • FILTER: 元の範囲にフィルタを設定した結果を返します。指定された条件に一致した行や列のみが返されます。
  • MAX: 数値データセットの最大値を返します。
  • INDEX: 行や列のオフセットで指定されたセルの内容を返します。
  • LARGE: データセット内で n 番目に大きな要素を返します。n はユーザーが定義します。

次の表を使用した場合、下記の例のようになります。

  A B C
1 生徒 テスト 1 得点 テスト 2 得点
2 アリス 100 90
3 ボブ 75 85
4 キャロル 80 85
5 デボン 100 95
6 エロイーズ 80 90

 

数式 結果
=SORTN(A2:C6)

アリス 100 90

=SORTN(A2:C6, 2)

アリス 100 90
エロイーズ 80 90

=SORTN(A2:C6, 3, 0, B2:B6, FALSE)

アリス 100 90
デボン 100 95
キャロル 80 85

=SORTN(A2:C6, 3, 1, B2:B6, FALSE)

アリス 100 90
デボン 100 95
キャロル 80 85
エロイーズ 80 90

=SORTN(A2:C6, 3, 2, B2:B6, FALSE)

アリス 100 90
キャロル 80 85
ボブ 75 85

=SORTN(A2:C6, 3, 3, B2:B6, FALSE)

アリス 100 90
デボン 100 95
キャロル 80 85
エロイーズ 80 90
ボブ 75 85

=SORTN(A2:C6, 3, 3, 2, FALSE, 3, FALSE)

デボン 100 95
アリス 100 90
エロイーズ 80 90

この情報は役に立ちましたか?
改善できる点がありましたらお聞かせください。