SORTN

Restituisce i primi n elementi di un set di dati dopo aver eseguito un ordinamento.

Esempi di utilizzo

SORTN(A1:A10; 2)

SORTN(A2:C20; 2; 2; B2:B20; VERO)

SORTN(A2:C20; 2; 3; B2:B20; VERO; 3; FALSO)

Sintassi

SORTN(intervallo; [n]; [mostra_tutti_i_legami]; [ordina_colonna1; è_ascendente1], ...)

• Intervallo - I dati da ordinare per trovare i primi n elementi.
• n - [FACOLTATIVO - 1 per impostazione predefinita] Il numero di elementi da restituire. Deve essere maggiore di 0.
• modalità_visualizzazione_legami - [FACOLTATIVO - 0 per impostazione predefinita] Un numero che rappresenta il modo di visualizzare i legami.
  • 0: mostra al massimo le prime n righe dell'intervallo ordinato.
  • 1: mostra al massimo le prime n righe, più eventuali righe aggiuntive che sono identiche all'n-esima riga.
  • 2: mostra al massimo le prime n righe dopo la rimozione delle righe duplicate.
  • 3: mostra al massimo le prime n righe, ma mostra tutti i duplicati di queste righe.

• ordina_colonna - [FACOLTATIVO] - L'indice della colonna in intervallo o un intervallo fuori da intervallo contenente i valori in base ai quali ordinare. Un intervallo specificato come ordina_colonna1 deve essere una singola colonna con lo stesso numero di righe di intervallo.

• è_ascendente1 - [FACOLTATIVO] - VERO o FALSO indica come ordinare ordina_colonna1. VERO ordina in ordine crescente. FALSO ordina in ordine decrescente.
• ordina_colonna2; è_ascendente2; ... - [FACOLTATIVO] - Colonne aggiuntive e indicazioni della modalità di ordinamento utilizzati in caso di legame in ordine di precedenza.

Note

• intervallo viene ordinato solo dalle colonne specificate. Le altre colonne sono restituite nell'ordine in cui compaiono inizialmente.
• Se ordina_colonna1 ed è_ascendente1 non vengono inclusi, l'ordinamento viene eseguito in base alla colonna con indice più basso di intervallo, mentre le colonne successive vengono utilizzate per ordinare in caso di legami.

Argomenti correlati

• SORT: ordina le righe di una matrice o di un intervallo dato in base ai valori in una o più colonne.
• FILTER: restituisce una versione filtrata dell'intervallo di origine, restituendo solo le righe o le colonne che soddisfano le condizioni specificate.
• MAX: restituisce il valore massimo in un insieme di dati numerico.
• INDICE: restituisce il contenuto di una cella, specificato da uno spostamento di riga e colonna.
• GRANDE: restituisce l'n-esimo elemento più grande da un insieme di dati dove n è definito dall'utente.

Esempi

Questa tabella viene utilizzata per gli esempi seguenti.

	A	B	C
1	Studente	Punteggio test 1	Punteggio test 2
2	Alice	100	90
3	Bob	75	85
4	Carol	80	85
5	Devon	100	95
6	Eloise	80	90

 

Formula	Risultato
=SORTN(A2:C6)	Alice 100 90
=SORTN(A2:C6; 2)	Alice 100 90 Bob 75 85
=SORTN(A2:C6; 3; 0; B2:B6, FALSO)	Alice 100 90 Devon 100 95 Carol 80 85
=SORTN(A2:C6; 3; 1; B2:B6; FALSO)	Alice 100 90 Devon 100 95 Carol 80 85 Eloise 80 90
=SORTN(A2:C6; 3; 2; B2:B6; FALSO)	Alice 100 90 Carol 80 85 Bob 75 85
=SORTN(A2:C6; 3; 3; B2:B6; FALSO)	Alice 100 90 Devon 100 95 Carol 80 85 Eloise 80 90 Bob 75 85
=SORTN(A2:C6; 3; 3; 2; FALSO; 3; FALSO)	Devon 100 95 Alice 100 90 Eloise 80 90