SORTN

Affiche les n premiers éléments d'un ensemble de données après un tri.

Exemple d'utilisation

SORTN(A1:A10; 2)

SORTN(A2:C20; 2; 2; B2:B20; VRAI)

SORTN(A2:C20; 2; 3; B2:B20; VRAI; 3; FAUX)

Syntaxe

SORTN(plage; [n]; [afficher_tous_cas_d'égalité]; [colonne_tri1; ordre_croissant1]; …)

  • plage : données à trier pour identifier les n premiers éléments.
  • n [FACULTATIF, 1 par défaut] : nombre d'éléments à afficher. Cette valeur doit être supérieure à 0.
  • mode_affichage_cas_égalité [FACULTATIF, 0 par défaut] : numéro représentant le mode d'affichage des cas d'égalité.
    • 0 : afficher au maximum les n premières lignes de la plage triée.
    • 1 : afficher au maximum les n premières lignes, plus les autres lignes éventuelles identiques à la énième ligne.
    • 2 : afficher au maximum les n premières lignes après suppression des lignes en double.
    • 3 : afficher au maximum les n premières lignes uniques, mais afficher tous les doublons de ces lignes.
  • colonne_tri1 [FACULTATIF] : index de la colonne au sein de plage ou à l'extérieur de plage contenant les valeurs à utiliser comme référence de tri. La plage désignée comme colonne_tri1 doit correspondre à une colonne unique contenant le même nombre de lignes que plage.

  • ordre_croissant1 [FACULTATIF] : ordre de tri de "colonne_tri1", défini à l'aide de VRAI ou FAUX. Si la valeur est VRAI, les données sont triées dans l'ordre croissant. Si la valeur est FAUX, les données sont triées dans l'ordre décroissant.
  • colonne_tri2; ordre_croissant2; … [FACULTATIF] : autres colonnes et indicateurs d'ordre de tri à utiliser en cas d'égalité, par ordre de priorité.

Remarques

  • Le tri de plage s'effectue exclusivement sur la base des colonnes spécifiées. Les autres colonnes conservent leur ordre d'origine.
  • Si les valeurs colonne_tri1 et ordre_croissant1 ne sont pas précisées, le tri est effectué sur la base des colonnes ayant l'index le plus faible au sein de plage. En cas d'égalité, les colonnes suivantes sont utilisées pour trier les données.

Voir également

  • SORT : trie les lignes d'une plage ou d'un tableau donné en fonction des valeurs d'une ou de plusieurs colonnes.
  • FILTER : affiche une version filtrée de la plage source, qui ne prend en compte que les lignes ou colonnes répondant aux conditions spécifiées.
  • MAX : affiche la valeur maximale d'un ensemble de données numériques.
  • INDEX : affiche le contenu d'une cellule définie par un décalage de ligne et de colonne.
  • GRANDE.VALEUR : affiche le énième plus grand élément d'un ensemble de données, où "n" est défini par l'utilisateur.

Exemples

Le tableau ci-dessous présente quelques exemples.

  A B C
1 Élève Note au test 1 Note au test 2
2 Alice 100 90
3 Bob 75 85
4 Carol 80 85
5 Devon 100 95
6 Eloise 80 90

 

Formule Résultat
=SORTN(A2:C6)

Alice 100 90

=SORTN(A2:C6; 2)

Alice 100 90
Bob 75 85

=SORTN(A2:C6; 3; 0; B2:B6; FAUX)

Alice 100 90
Devon 100 95
Carol 80 85

=SORTN(A2:C6; 3; 1; B2:B6; FAUX)

Alice 100 90
Devon 100 95
Carol 80 85
Eloise 80 90

=SORTN(A2:C6; 3; 2; B2:B6; FAUX)

Alice 100 90
Carol 80 85
Bob 75 85

=SORTN(A2:C6; 3; 3; B2:B6; FAUX)

Alice 100 90
Devon 100 95
Carol 80 85
Eloise 80 90
Bob 75 85

=SORTN(A2:C6; 3; 3; 2; FAUX; 3; FAUX)

Devon 100 95
Alice 100 90
Eloise 80 90

Ces informations vous-ont elles été utiles ?
Comment pouvons-nous l'améliorer ?