傳回以列偏移和欄偏移方式指定的儲存格內容。
範例
賓客姓名 | 飲食限制 | 已傳送邀請 | 餐桌編號 |
---|---|---|---|
David | 素食 | 否 | 3 |
Bob | 無 | 否 | 5 |
david | 無 | 是 | 1 |
Nancy | 無 | 否 | 4 |
Mary | 素食 | 是 | 2 |
公式 | 公式輸出結果 |
---|---|
=INDEX(A2:D6, 2, 1) | Bob |
=INDEX(A2:D6, 4, 4) | 4 |
=INDEX(A2:D6,1,1) | David |
=INDEX(A1:D6, 6, 2) | 素食 |
公式 | 公式輸出結果 | |||
---|---|---|---|---|
=INDEX(A2:D6, 2, 0) | Bob | 無 | 否 | 5 |
公式 | 公式輸出結果 |
---|---|
=INDEX(A2:D6, 0, 4) | 3 |
5 | |
1 | |
4 | |
2 |
傳回參照範圍中依索引值指定的儲存格內容。
用法示範
INDEX(A1:C20, 5, 1)
語法
INDEX(reference, [row], [column])
-
reference
- 參照範圍,亦即傳回值所在的儲存格範圍。 -
row
- [選用 - 預設值是 0] - 要從參照的儲存格範圍中傳回的資料列索引。 -
column
- [選用 - 預設值是0
] - 要從參照的儲存格範圍中傳回的資料欄索引。
使用 INDEX 和 Match
你可以搭配使用 INDEX 和 MATCH 來執行更進階和動態的查詢作業。
賓客姓名 | 飲食限制 | 已傳送邀請 | 餐桌編號 |
---|---|---|---|
David | 素食 | 否 | 3 |
Bob | 無 | 否 | 5 |
david | 無 | 是 | 1 |
Nancy | 無 | 否 | 4 |
Mary | 素食 | 是 | 2 |
目標 | 公式 | 公式輸出結果 | 註解 |
---|---|---|---|
查看 Mary 的飲食限制 | =VLOOKUP("Mary", A1:D6, 2, false) | 素食 | 以硬式編碼方式指定搜尋詞和索引 |
查看 Mary 的飲食限制 | =INDEX(A1:D6, MATCH("Mary", A1:A6, 0), 2) | 素食 | 以動態方式指定列編號,以硬式編碼方式指定欄編號 |
查看 Mary 的飲食限制 | =INDEX(A1:D6, MATCH("Mary", A1:A6, 0), MATCH("飲食限制", A1:D1, 0)) | 素食 | 以動態方式指定列編號和欄編號 |
查看坐在餐桌編號 2 的賓客 | 無法使用 VLOOKUP 執行這項查詢 | 不適用 | 當查詢值位於要傳回的屬性左側時,才能使用 VLOOKUP |
查看坐在餐桌編號 2 的賓客 | =INDEX(A1:D6, MATCH(2, D1:D6, 0), MATCH("賓客姓名", A1:D1, 0)) | Mary | 無論查詢值和要傳回的屬性之相對位置為何,你都可以使用 INDEX 和 MATCH |
另請參閱
MATCH
:傳回與指定值相符的項目在範圍中的相對位置。
OFFSET
:傳回開首儲存格參照內的指定欄/列數之範圍參照。
附註
- 如果將列 (row) 或欄 (column) 設為 0,則
INDEX
會分別傳回一整欄或一整列的值陣列。