INDEX

Satır ve sütun uzaklığıyla belirtilen bir hücrenin içeriğini döndürür.

Örnekler

Kopyasını oluştur

Konuk Adı	Beslenme Sınırlaması	Davetiye Gönderildi	Masa Numarası
Davut	Vejetaryen	Hayır	3
Burak	Yok	Hayır	5
Okan	Yok	Evet	1
Nalan	Yok	Hayır	4
Meryem	Vejetaryen	Evet	2

 

Formül	Formül Sonucu
=INDEX(A2:D6, 2, 1)	Burak
=INDEX(A2:D6, 4, 4)	4
=INDEX(A2:D6,1,1)	Davut
=INDEX(A1:D6, 6, 2)	Vejetaryen

 

Formül	Formül Sonucu
=INDEX(A2:D6, 2, 0)	Burak	Yok	Hayır	5

 

Formül	Formül Sonucu
=INDEX(A2:D6, 0, 4)	3
	5
	1
	4
	2

Dizin değerine göre bulunan hücreleri referans alınan aralıkta döndürür.

Örnek Kullanım

INDEX(A1:C20; 5; 1)

Söz Dizimi

INDEX(reference, [row], [column])

• reference - Değerlerin döndürüldüğü hücre aralığı.

• row - [İSTEĞE BAĞLI - varsayılan olarak 0] - Hücre aralığı referans alınarak döndürülecek satırın dizini.

• column - [İSTEĞE BAĞLI - varsayılan olarak 0] - Hücre aralığı referans alınarak döndürülecek sütunun dizini.

INDEX ve Match'i kullanma

INDEX ve MATCH, daha gelişmiş ve dinamik aramalar yapmak için birlikte kullanılabilir.

• İpucu: VLOOKUP arama değeri döndürülecek özelliğin solunda olduğunda kullanılabilir. Arama değerinin veri kümesinde bulunduğu yerden bağımsız olarak INDEX ve MATCH kullanılabilir.

Konuk Adı	Beslenme Sınırlaması	Davetiye Gönderildi	Masa Numarası
Davut	Vejetaryen	Hayır	3
Burak	Yok	Hayır	5
Okan	Yok	Evet	1
Nalan	Yok	Hayır	4
Meryem	Vejetaryen	Evet	2

 

Hedef	Formül	Formül Sonucu	Yorum
Meryem'in Beslenme Sınırlamasını Bulma	=VLOOKUP("Meryem", A1:D6, 2, false)	Vejetaryen	Arama anahtarı ve dizinin ikisi de gömülü kodludur
Meryem'in Beslenme Sınırlamasını Bulma	=INDEX(A1:D6, MATCH("Meryem", A1:A6, 0), 2)	Vejetaryen	Satır numarası dinamik ve sütun numarası gömülü kodludur
Meryem'in Beslenme Sınırlamasını Bulma	=INDEX(A1:D6, MATCH("Meryem", A1:A6, 0), MATCH("Beslenme Sınırlaması", A1:D1, 0))	Vejetaryen	Satır numarası ve sütun numarasının ikisi de dinamiktir
2 Numaralı Masada Kimlerin Bulunduğunu Öğrenme	VLOOKUP kullanıldığında bu mümkün olmazdı	Yok	VLOOKUP yalnızca arama değeri döndürülecek özelliğin solunda olduğunda kullanılabilir
2 Numaralı Masada Kimlerin Bulunduğunu Öğrenme	=INDEX(A1:D6, MATCH(2, D1:D6, 0), MATCH("Konuk Adı", A1:D1, 0))	Meryem	INDEX ve MATCH, arama değerinin döndürülecek özelliğe göre nerede olduğundan bağımsız olarak kullanılabilir.

İlgili Konular

MATCH: Belirtilen değerle eşleşen bir öğenin aralıktaki göreli konumunu döndürür.

OFFSET: Bir başlangıç hücre başvurusundan belirtilen satır ve sütun uzaklıktaki aralık başvurusunu döndürür.

Notlar

• Satır veya sütunu 0 olarak ayarlarsanız INDEX, sırasıyla tüm sütun veya satıra ilişkin değer dizisini döndürür.