Retorna o conteúdo de uma célula, especificado pelo deslocamento de linha e coluna.
Exemplos
Nome do hóspede | Restrição alimentar | Convite enviado | Número da tabela |
---|---|---|---|
David | Vegetariana | Não | 3 |
Beto | Nenhuma | Não | 5 |
David | Nenhuma | Sim | 1 |
Nancy | Nenhuma | Não | 4 |
Mary | Vegetariana | Sim | 2 |
Fórmula | Saída de fórmula |
---|---|
=ÍNDICE(A2:D6, 2, 1) | Beto |
=ÍNDICE(A2:D6, 4, 4) | 4 |
=ÍNDICE(A2:D6,1,1) | David |
=ÍNDICE(A1:D6, 6, 2) | Vegetariana |
Fórmula | Saída de fórmula | |||
---|---|---|---|---|
=ÍNDICE(A2:D6; 2; 0) | Beto | Nenhuma | Não | 5 |
Fórmula | Saída de fórmula |
---|---|
=ÍNDICE(A2:D6; 0, 4) | 3 |
5 | |
1 | |
4 | |
2 |
Retorna as células encontradas pelo valor do índice no intervalo referenciado.
Exemplo de uso
INDEX(A1:C20, 5, 1)
Sintaxe
ÍNDICE(referência, [linha], [coluna])
-
referência
: o intervalo de células a partir do qual os valores são retornados. -
linha
- [OPCIONAL - 0 por padrão]: o índice da linha a ser retornado no intervalo de referência das células. -
coluna
- [OPCIONAL -0
por padrão]: o índice da coluna a ser retornado no intervalo de referência das células.
Como usar ÍNDICE e CORRESP
As funções ÍNDICE e CORRESP podem ser usadas juntas para realizar pesquisas mais avançadas e dinâmicas.
- Dica: PROCV pode ser usada quando o valor da pesquisa aparece à esquerda do atributo que você quer retornar. É possível usar ÍNDICE e CORRESP independentemente de onde o valor da pesquisa está localizado no conjunto de dados.
Nome do hóspede | Restrição alimentar | Convite enviado | Número da tabela |
---|---|---|---|
David | Vegetariana | Não | 3 |
Beto | Nenhuma | Não | 5 |
David | Nenhuma | Sim | 1 |
Nancy | Nenhuma | Não | 4 |
Mary | Vegetariana | Sim | 2 |
Meta | Fórmula | Saída de fórmula | Comentário |
---|---|---|---|
Encontrar a restrição alimentar de Mary | =PROCV("Mary", A1:D6, 2, falso) | Vegetariana | A tecla de pesquisa e o índice são fixados no código |
Encontrar a restrição alimentar de Mary | =ÍNDICE(A1:D6, CORRESP("Mary"; A1:A6; 0); 2) | Vegetariana | O número da linha é dinâmico, e o número da coluna é fixado no código |
Encontrar a restrição alimentar de Mary | =ÍNDICE(A1:D6, CORRESP("Mary", A1:A6, 0), CORRESP("Restrição alimentar", A1:D1, 0)) | Vegetariana | Os números de linhas e colunas são dinâmicos. |
Encontrar quem está na tabela número 2 | Não é possível usar PROCV | N/A | PROCV só pode ser usada quando o valor de pesquisa aparece à esquerda do atributo que você quer retornar |
Encontrar quem está na tabela número 2 | =ÍNDICE(A1:D6, CORRESP(2, D1:D6, 0), CORRESP("Nome do hóspede", A1:D1, 0)) | Mary | ÍNDICE e CORRESP podem ser usadas independentemente do local em que o valor da pesquisa está localizado em relação ao atributo que você quer retornar |
Ver também
CORRESP
: Retorna a posição relativa de um item no intervalo que corresponde ao valor especificado.
DESLOC
: Retorna uma referência de intervalo deslocada a um número especificado de linhas e colunas de uma referência de célula inicial.
Observações
- Se você define uma linha ou coluna como 0,
ÍNDICE
retorna a matriz de valores para toda a coluna ou linha, respectivamente.