Devolve o conteúdo de uma célula, especificado pelo desvio de linha e de coluna.
Exemplos
Nome do hóspede | Restrição alimentar | Convite enviado | Número da mesa |
---|---|---|---|
David | Vegetariana | Não | 3 |
Bernardo | Nenhuma | Não | 5 |
david | Nenhuma | Sim | 1 |
Nádia | Nenhuma | Não | 4 |
Maria | Vegetariana | Sim | 2 |
Fórmula | Resultado da fórmula |
---|---|
=ÍNDICE(A2:D6; 2; 1) | Bernardo |
=ÍNDICE(A2:D6; 4; 4) | 4 |
=ÍNDICE(A2:D6;1;1) | David |
=ÍNDICE(A1:D6; 6; 2) | Vegetariana |
Fórmula | Resultado da fórmula | |||
---|---|---|---|---|
=ÍNDICE(A2:D6; 2; 0) | Bernardo | Nenhuma | Não | 5 |
Fórmula | Resultado da fórmula |
---|---|
=ÍNDICE(A2:D6; 0; 4) | 3 |
5 | |
1 | |
4 | |
2 |
Devolve a(s) célula(s) encontrada(s) por valor do índice no intervalo referenciado.
Exemplos de utilização
ÍNDICE(A1:C20; 5; 1)
Sintaxe
ÍNDICE(referência; [linha]; [coluna])
-
referência
– o intervalo de células a partir do qual os valores são devolvidos. -
linha
– [OPCIONAL – 0 por predefinição] – o índice da linha a ser devolvido a partir do intervalo de células de referência. -
coluna
– [OPCIONAL –0
por predefinição] – o índice da coluna a ser devolvido a partir do intervalo de referência das células.
Utilizar ÍNDICE e CORRESP
Pode utilizar ÍNDICE e CORRESP em conjunto para efetuar pesquisas mais avançadas e dinâmicas.
- Sugestão: pode utilizar PROCV quando o valor de pesquisa estiver à esquerda do atributo que pretende devolver. Pode utilizar ÍNDICE e CORRESP independentemente da localização do valor de pesquisa no conjunto de dados.
Nome do hóspede | Restrição alimentar | Convite enviado | Número da mesa |
---|---|---|---|
David | Vegetariana | Não | 3 |
Bernardo | Nenhuma | Não | 5 |
David | Nenhuma | Sim | 1 |
Nádia | Nenhuma | Não | 4 |
Maria | Vegetariana | Sim | 2 |
Objetivo | Fórmula | Resultado da fórmula | Comentário |
---|---|---|---|
Encontrar a restrição alimentar da Maria | =PROCV("Maria"; A1:D6; 2; falso) | Vegetariana | Tanto a tecla de pesquisa como o índice estão codificados |
Encontrar a restrição alimentar da Maria | =ÍNDICE(A1:D6; CORRESP("Maria"; A1:A6; 0); 2) | Vegetariana | O número da linha é dinâmico e o número da coluna está codificado |
Encontrar a restrição alimentar da Maria | =ÍNDICE(A1:D6; CORRESP("Maria"; A1:A6; 0); CORRESP("Restrição alimentar"; A1:D1; 0)) | Vegetariana | Tanto o número da linha como o número da coluna são dinâmicos |
Encontrar quem está na mesa 2 | Com a função PROCV, isto não seria possível | N/D | A função PROCV só pode ser utilizada quando o valor de pesquisa estiver à esquerda do atributo que pretende devolver |
Encontrar quem está na mesa 2 | =ÍNDICE(A1:D6; CORRESP(2; D1:D6; 0); CORRESP("Nome do hóspede"; A1:D1; 0)) | Maria | Pode utilizar ÍNDICE e CORRESP independentemente da localização do valor de pesquisa em relação ao atributo que pretende devolver |
Veja também
CORRESP
: Devolve a posição relativa de um item num intervalo que corresponde a um valor especificado.
DESLOCAMENTO
: Devolve uma referência de um intervalo movido como um número específico de linhas e colunas desde uma referência de célula inicial.
Notas
- Se definir a linha ou a coluna para 0, a função
ÍNDICE
devolve a matriz de valores de toda a coluna ou linha, respetivamente.