행과 열 오프셋으로 지정된 셀의 콘텐츠를 반환합니다.
예
| 고객 이름 | 식단 제한사항 | 초대장 전송 여부 | 예약 테이블 번호 |
|---|---|---|---|
| 민수 | 채식주의자 | 아니요 | 3 |
| 영철 | 없음 | 아니요 | 5 |
| 다빈 | 없음 | 예 | 1 |
| 현주 | 없음 | 아니요 | 4 |
| 수정 | 채식주의자 | 예 | 2 |
| 수식 | 수식 출력 |
|---|---|
| =INDEX(A2:D6, 2, 1) | 영철 |
| =INDEX(A2:D6, 4, 4) | 4 |
| =INDEX(A2:D6,1,1) | 민수 |
| =INDEX(A1:D6, 6, 2) | 채식주의자 |
| 수식 | 수식 출력 | |||
|---|---|---|---|---|
| =INDEX(A2:D6, 2, 0) | 영철 | 없음 | 아니요 | 5 |
| 수식 | 수식 출력 |
|---|---|
| =INDEX(A2:D6, 0, 4) | 3 |
| 5 | |
| 1 | |
| 4 | |
| 2 |
색인 값으로 찾은 셀을 참조된 범위로 반환합니다.
사용 예
INDEX(A1:C20, 5, 1)
구문
INDEX(참조, [행], [열])
-
참조: 값이 반환되는 셀의 범위입니다. -
행: [선택사항 - 기본값은 0] 셀의 참조 범위 내에서 반환될 행의 색인입니다. -
열: [선택사항 - 기본값은0] 셀의 참조 범위 내에서 반환될 열의 색인입니다.
INDEX 및 MATCH 사용하기
INDEX 및 MATCH를 함께 사용하여 고급 동적 검색을 수행할 수 있습니다.
- 도움말: 조회 값이 반환하려는 속성 왼쪽에 있는 경우 VLOOKUP을 사용할 수 있습니다. INDEX 및 MATCH는 데이터 세트의 조회 값이 있는 위치와 관계없이 사용할 수 있습니다.
| 고객 이름 | 식단 제한사항 | 초대장 전송 여부 | 예약 테이블 번호 |
|---|---|---|---|
| 민수 | 채식주의자 | 아니요 | 3 |
| 영철 | 없음 | 아니요 | 5 |
| 다빈 | 없음 | 예 | 1 |
| 현주 | 없음 | 아니요 | 4 |
| 수정 | 채식주의자 | 예 | 2 |
| 목표 | 수식 | 수식 출력 | 비고 |
|---|---|---|---|
| 수정의 식단 제한사항 찾기 | =VLOOKUP("수정", A1:D6, 2, false) | 채식주의자 | 검색 키와 색인 모두 하드 코딩됨 |
| 수정의 식단 제한사항 찾기 | =INDEX(A1:D6, MATCH("수정", A1:A6, 0), 2) | 채식주의자 | 행 번호는 동적이며 열 번호는 하드 코딩됨 |
| 수정의 식단 제한사항 찾기 | =INDEX(A1:D6, MATCH("수정", A1:A6, 0), MATCH("식단 제한", A1:D1, 0)) | 채식주의자 | 행 번호와 열 번호 모두가 동적임 |
| 2번 테이블에 누가 있는지 확인 | VLOOKUP을 사용할 수 없음 | N/A | VLOOKUP은 조회 값이 반환하려는 속성의 왼쪽에 있는 경우에만 사용할 수 있음 |
| 2번 테이블에 누가 있는지 확인 | =INDEX(A1:D6, MATCH(2, D1:D6, 0), MATCH("고객 이름", A1:D1, 0)) | 수정 | INDEX 및 MATCH는 반환하려는 속성을 기준으로 한 조회 값의 위치와 관계없이 사용할 수 있음 |
참고 항목
MATCH: 범위에서 지정된 값과 일치하는 항목의 상대적 위치를 반환합니다.
OFFSET: 시작 셀 참조에서 지정된 수의 행과 열로 변환된 범위 참조를 반환합니다.
참고
- 행 또는 열을 0으로 설정하면
INDEX는 전체 열 또는 행의 값 배열을 각각 반환합니다.