INDEX

Gibt einen Zelleninhalt zurück, der durch einen Zeilen- und Spaltenversatz angegeben wird.

Beispiele

Name des Gastes	Ernährungseinschränkung	Einladung gesendet	Tischnummer
David	Vegetarisch	Nein	3
Boris	–	Nein	5
david	–	Ja	1
Sabine	–	Nein	4
Mary	Vegetarisch	Ja	2

Formel	Formelausgabe
=INDEX(A2:D6; 2; 1)	Boris
=INDEX(A2:D6; 4; 4)	4
=INDEX(A2:D6;1;1)	David
=INDEX(A1:D6; 6; 2)	Vegetarisch

Formel	Formelausgabe
=INDEX(A2:D6; 2; 0)	Boris	–	Nein	5

Formel	Formelausgabe
=INDEX(A2:D6; 0, 4)	3
	5
	1
	4
	2

Gibt die nach Indexwert gefundenen Zelle(n) in den Bereich zurück, auf den verwiesen wird.

Verwendungsbeispiel

INDEX(A1:C20; 5; 1)

Syntax

INDEX(Bezug, [Zeile], [Spalte])

Bezug – Zellenbereich, aus dem die Werte zurückgegeben werden
Zeile: [OPTIONAL – standardmäßig 0] – der Index der Zeile, die aus dem angegebenen Zellenbereich zurückgegeben werden soll.
Spalte – [OPTIONAL – standardmäßig 0] – der Index der Spalte, die aus dem angegebenen Zellenbereich zurückgegeben werden soll.

INDEX und VERGLEICH verwenden

INDEX und VERGLEICH können zusammen verwendet werden, um erweiterte und dynamische Lookups durchzuführen.

Tipp: SVERWEIS kann verwendet werden, wenn der gesuchte Wert links neben dem gewünschten Attribut steht, das zurückgegeben werden soll. INDEX und VERGLEICH können unabhängig davon verwendet werden, wo sich der Suchwert im Dataset befindet.

Name des Gastes	Ernährungseinschränkung	Einladung gesendet	Tischnummer
David	Vegetarisch	Nein	3
Boris	–	Nein	5
david	–	Ja	1
Sabine	–	Nein	4
Mary	Vegetarisch	Ja	2

Ziel	Formel	Formelausgabe	Kommentar
Marys Ernährungsbeschränkung finden	=SVERWEIS("Mary", A1:D6; 2; falsch)	Vegetarisch	Sowohl der Suchschlüssel als auch der Index sind hartcodiert
Marys Ernährungsbeschränkung finden	=INDEX(A1:D6; VERGLEICH("Mary"; A1:A6; 0); 2)	Vegetarisch	Die Zeilennummer ist dynamisch und die Spaltennummer ist hartcodiert
Marys Ernährungsbeschränkung finden	=INDEX(A1:D6; VERGLEICH("Mary"; A1:A6; 0); VERGLEICH("Ernährungseinschränkung"; A1:D1; 0))	Vegetarisch	Sowohl die Zeilennummer als auch die Spaltennummer sind dynamisch
Wer ist an Tisch Nummer 2?	In SVERWEIS ist dies nicht möglich.	–	SVERWEIS kann nur verwendet werden, wenn der Suchwert links vom gewünschten zurückzugebenden Attribut liegt
Wer ist an Tisch Nummer 2?	=INDEX(A1:D6; VERGLEICH(2; D1:D6; 0); VERGLEICH("Name des Gastes", A1:D1; 0))	Mary	INDEX und VERGLEICH können verwendet werden, unabhängig davon, wo sich der gesuchte Wert relativ zum gewünschten Attribut befindet, das zurückgegeben werden soll.

Siehe auch

VERGLEICH: Gibt die relative Position eines Elements in einem Bereich zurück, das einem angegebenen Wert in einer angegebenen Reihenfolge entspricht.

BEREICH.VERSCHIEBEN: Gibt einen Bereichsbezug zurück, der gegenüber einem Ausgangszellbezug um eine bestimmte Anzahl von Zeilen und Spalten versetzt ist.

Hinweise

Wenn Sie die Zeile oder Spalte auf 0 setzen, gibt INDEX das Array von Werten für die gesamte Spalte bzw. Zeile zurück.