BUSCARV (VLOOKUP)

 

Si tienes información conocida en tu hoja de cálculo, puedes usar BUSCARV para buscar información relacionada por fila. Por ejemplo, si quieres comprar una naranja, puedes usar la función BUSCARV para buscar el precio.

BUSCARV para BigQuery

Búsqueda vertical. Muestra los valores de una columna de datos en la posición en la que se encontró una concordancia en la columna de búsqueda.

Ejemplo de uso

BUSCARV("Manzana",nombre_tabla!fruta,nombre_tabla!precio)

Sintaxis

BUSCARV(valor_búsqueda, rango, índice, está_ordenada)

• valor_búsqueda: Es el valor que se va a buscar en la columna de búsqueda.
• columna_búsqueda: Es la columna que se considera para la búsqueda.
• columna_resultado: Es la columna de datos que se considera para el resultado.
• está_ordenada: Es la forma en que se encuentra una coincidencia para valor_búsqueda [OPCIONAL].
  • FALSO: Para una concordancia exacta, se recomienda esta opción.
  • VERDADERO: Para una concordancia aproximada, este es el valor predeterminado si no se especifica está_ordenada.
    Sugerencia: Antes de usar una concordancia aproximada, ordena el valor de búsqueda de forma ascendente. De lo contrario, es probable que el valor que se muestre sea incorrecto. Conoce los motivos por los que se puede obtener un valor incorrecto.

Sugerencia: Para realizar consultas de bases de datos más flexibles en BigQuery, usa XLOOKUP.

Sintaxis

=BUSCARV(valor_búsqueda, rango, índice, [está_ordenada])

Entradas

1. valor_búsqueda: Es el valor que se va a buscar en la primera columna del rango.
2. rango: Corresponde a los valores inferiores y superiores que se deben considerar para la búsqueda.
3. índice: Es el índice de la columna con el valor que se muestra del rango. Debe ser un número entero positivo.
4. está_ordenada: Es una entrada opcional. Elige una opción:
   • FALSO = Concordancia exacta. Esta es la opción recomendada.
   • VERDADERO = Concordancia aproximada. Esta es la opción predeterminada si no se especifica está_ordenada.
     Importante: Antes de usar una concordancia aproximada, ordena el valor de búsqueda de forma ascendente. De lo contrario, es probable que el valor que se muestre sea incorrecto. Conoce los motivos por los que se puede obtener un valor incorrecto.

Valor que se muestra

Es el primer valor coincidente del rango seleccionado.

Detalles técnicos:

Ejemplo:

=BUSCARV(G9, B4:D8, 3, FALSO)

=BUSCARV("Manzana", B4:D8, 3, VERDADERO)

Entradas	Descripción
valor_búsqueda	Este es el valor que buscas en la primera columna del rango. Si esperas obtener un valor sin error, el valor de búsqueda debe estar en la primera columna del rango. También se admite la referencia de celda. Comprobación simple: Si tu valor_búsqueda se encuentra en B3, entonces el rango debe comenzar con la columna B.
rango	Este es el rango, en el que ocurre lo siguiente: La función busca el valor de búsqueda especificado en su primera columna. BUSCARV muestra el valor de la columna especificada por índice. También puedes usar un rango con nombre. Para que se muestre un valor sin errores, el valor de búsqueda debe estar en la primera columna del rango. Comprobación simple: Si tu valor_búsqueda se encuentra en B3, entonces el rango debe comenzar con la columna B.
índice	También se denomina “Número de columna”. Este es el índice de la columna en el rango que contiene el valor que se muestra. El menor índice posible es 1. El mayor índice posible es la cantidad máxima de columnas en ese rango. Después de que configures el rango, BUSCARV solo buscará en la columna del valor de búsqueda, cuando el índice es igual a 1, o en las columnas que están más a la derecha. Sugerencia: Cuando uses BUSCARV, imagina que las columnas del rango están numeradas de izquierda a derecha y comienzan en 1.
está_ordenado	Esta es una entrada opcional. Las dos opciones disponibles son VERDADERO y FALSO. Si está_ordenada es VERDADERO, entonces BUSCARV utiliza una concordancia aproximada. Importante: Antes de usar una concordancia aproximada, ordena el valor de búsqueda de forma ascendente. De lo contrario, es posible que el valor que se muestra sea uno inesperado. Conoce los motivos por los que se puede obtener un valor incorrecto. Si está_ordenada es FALSO, entonces BUSCARV usa la concordancia exacta. Si no se especifica está_ordenada, se utiliza la opción VERDADERO de forma predeterminada. Te recomendamos lo siguiente: Usa FALSO para está_ordenada debido a su comportamiento constante, independientemente de si la columna de valor de búsqueda está ordenada. Siempre especifica está_ordenada para mejorar la legibilidad, aunque la entrada sea opcional.

 

Resultados

Descripción

Valor que se muestra

Este es el valor que BUSCARV muestra según tus entradas. Solo hay un valor para mostrar de cada función BUSCARV. Si hay múltiples valores de búsqueda que coinciden, se mostrará el valor de la columna de valor que se muestra cuyo valor de búsqueda asociado coincida primero en la columna de valor de búsqueda. Si se muestra #N/A, no se encontró ningún valor. Si encuentras un error o un valor inesperado, como #N/A o #VALUE!, intenta solucionar el problema. Si quieres reemplazar #N/A por otro valor, obtén más información para usar SI.ND() en BUSCARV().

Ejemplos básicos de BUSCARV:

BUSCARV en diferentes valores de búsqueda

Usa BUSCARV para buscar el precio de una naranja (“Orange”) y una manzana (“Apple”).

Probar

Explicación:

Cuando usas BUSCARV, puedes utilizar diferentes valores de búsqueda, como “Manzana” (“Apple”) y “Naranja” (“Orange”).

Para que se muestre un valor sin errores, estos valores de búsqueda deben estar en la primera columna del rango. Si no quieres completar un valor para los valores de búsqueda, también puedes usar una referencia de celda, por ejemplo, “G9”.

valor_búsqueda es “Naranja” (“Orange”)	=BUSCARV("Naranja", B4:D8, 3, FALSO) Valor que se muestra = $1.01
valor_búsqueda es “Manzana” (“Apple”)	=BUSCARV("Manzana", B4:D8, 3, FALSO) Valor que se muestra = $1.50
valor_búsqueda que usa la referencia de celda de “Manzana” (“Apple”) en G9	=BUSCARV(G9, B4:D8, 3, FALSO) Valor que se muestra = $1.50

BUSCARV en diferentes índices de columna

Usa BUSCARV para buscar la cantidad de naranjas en la segunda columna de índice.

Probar

Explicación:

Cuando uses BUSCARV, imagina que las columnas del rango están numeradas de izquierda a derecha y comienzan en 1. Para encontrar la información objetivo, debes especificar su índice de columna. Por ejemplo, la columna 2 para cantidad.

Índice = 2 Busca la cantidad de naranjas, que corresponde a la segunda columna del rango.

=BUSCARV(G3, B4:D8, 2, FALSO) Valor que se muestra = 5

Concordancia exacta o concordancia aproximada de BUSCARV

• Usa la concordancia exacta de BUSCARV para encontrar un ID exacto.
• Usa la concordancia aproximada de BUSCARV para encontrar el ID aproximado.

Probar

Explicación:

Usa una concordancia aproximada o está_ordenada = VERDADERO cuando buscas la mejor coincidencia, pero no una exacta.

Si quieres buscar ID = 102, que no existe en la tabla, una coincidencia aproximada usa el valor inmediatamente menor, lo que da como resultado ID = 101. Esto se debe a que, en la columna de valor de búsqueda, 101 es el valor más cercano que, además, es inferior a 102.

Una coincidencia aproximada realiza una búsqueda descendente en la columna de valor de búsqueda hasta encontrar un valor mayor que el de tu valor de búsqueda. Luego, se detiene en la fila anterior al valor más alto y muestra el de la columna de valor en esa fila. Esto significa que si la columna de valor de búsqueda no está ordenada de forma ascendente, es probable que obtengas un valor incorrecto.

Importante: Antes de usar una concordancia aproximada, ordena el valor de búsqueda de forma ascendente para obtener el valor correcto. De lo contrario, es posible que el valor que se muestra sea uno inesperado.

Cuando buscas la concordancia exacta, como está_ordenada = FALSO, eso es lo que se muestra. Por ejemplo, el nombre de fruta para ID = 103 es “Banana”. Si no hay una coincidencia exacta, aparece un error #N/A. Debido a su comportamiento más predecible, te recomendamos que utilices la concordancia exacta.

Concordancia exacta	=BUSCARV(G6, A4:D8, 2, FALSO) Valor que se muestra = “Manzana” (“Apple”)
Concordancia aproximada	=BUSCARV(G3, A4:D8, 2, VERDADERO) O =BUSCARV(G3, A4:D8, 2) Valor que se muestra = “Banana”

Aplicaciones comunes de BUSCARV

Cómo reemplazar el valor de error de BUSCARV

Te recomendamos reemplazar el valor de error que muestra VLOOKUP cuando tu valor de búsqueda no existe. En este caso, si no quieres que aparezca #N/A, puedes reemplazarlo usando las funciones SI.ND(). Obtén más información sobre SI.ND().

Probar

Originalmente, BUSCARV muestra #N/A porque el valor de búsqueda “Lápiz” (“Pencil”) no existe en la columna “Fruta” (“Fruit”). SI.ND() reemplaza el error #N/A por la segunda entrada especificada en la función. En nuestro caso, es “NO ENCONTRADO” (“NOT FOUND”).

=SI.ND(BUSCARV(G3, B4:D8, 3, FALSO),"NO ENCONTRADO") Valor que se muestra = “NOT FOUND” (“NO ENCONTRADO”)

Sugerencia: Si quieres reemplazar otros errores, como #REF!, obtén más información sobre SI.ERROR().

BUSCARV con varios criterios

BUSCARV no se puede aplicar directamente en varios criterios. En su lugar, crea una nueva columna de ayuda para aplicar BUSCARV directamente en varios criterios para combinar varias columnas existentes.

Probar

1. Puedes crear una columna de ayuda si usas “&” para combinar nombre y apellido.	=C4&D4 y, si lo arrastras de B4 a B8, obtendrás la columna de ayuda.
2. Usa la referencia de celda B7, JohnLee, como la tecla de búsqueda.	=BUSCARV(B7, B4:E8, 4, FALSO) Valor que se muestra = “Asistencia” (“Support”)

BUSCARV con comodines o concordancias parciales

En BUSCARV, también puedes usar comodines o concordancias parciales. Puedes usar estos caracteres comodín:

• Un signo de interrogación (“?”) coincide con cualquier carácter.
• Un asterisco (“*”) coincide con cualquier secuencia de caracteres.

Para usar comodines en BUSCARV, debes usar una concordancia exacta: “está_ordenada = FALSO”.

Probar

“St*” se usa para buscar cualquier coincidencia que comience con “St”, sin importar la cantidad de caracteres, como “Steve”, “St1”, “Stock” o “Steeeeeeve”.

=BUSCARV("St*", B4:D8, 3, FALSO) Valor que se muestra = “Marketing”

Solución de problemas y prácticas recomendadas:

Valor que se muestra incorrecto

• Se muestra un valor inesperado: Si estableces está_ordenada como VERDADERO, pero la primera columna del rango no está ordenada numérica o alfabéticamente, cambia el valor a FALSO.

• BUSCARV muestra la primera coincidencia: BUSCARV solo muestra la primera coincidencia. Si tienes varios valores de búsqueda coincidentes, se mostrará uno, pero tal vez no sea el esperado.
• Datos no limpios: A veces, los valores con espacios al principio y al final pueden parecer similares, pero BUSCARV los trata de manera distinta. Por ejemplo, las siguientes opciones son diferentes para BUSCARV:
  • " Manzana"
  • "Manzana "
  • "Manzana"

Para obtener los resultados esperados, quita los espacios antes de usar la función BUSCARV.

Para obtener más información, consulta nuestra sección de prácticas recomendadas.

#N/A

• Si se usa una aproximación o está_ordenada = VERDADERO y si el valor de búsqueda en BUSCARV es menor que el valor más pequeño de la primera columna, entonces VLOOKUP muestra #N/A.
• Si se utiliza la concordancia exacta o está_ordenada = FALSO, no se encontrará la concordancia exacta del valor de búsqueda de BUSCARV en la primera columna. Si no quieres que aparezca #N/A cuando no se encuentra el valor de búsqueda en la primera columna, puedes usar la función SI.ND().

#REF!

Puedes especificar por error un rango con un número superior a la cantidad máxima de columnas del rango. Para evitar esto, asegúrate de hacer lo siguiente:

• Cuenta las columnas del rango seleccionado, no de toda la tabla.
• Comienza a contar desde 1 en lugar de 0.

#VALUE!

Si obtienes el error #VALUE!, es posible que haya ocurrido lo siguiente:

• Ingresaste incorrectamente el texto o el nombre de la columna para el índice.
• Ingresaste un número menor que 1 para el índice. El índice debe ser al menos igual a 1 y menor que la cantidad máxima de columnas del rango. BUSCARV solo puede buscar en la columna de valor de búsqueda, cuando índice = 1, o en columnas que están más a la derecha.

Importante: El índice solo acepta un número.

#¿NOMBRE?

• Es posible que hayas omitido unas comillas en valor_búsqueda cuando corresponde a datos de texto.

Prácticas recomendadas

 

Pendientes	Motivo
Usa referencias absolutas para rango.	Debes usar lo siguiente: Referencia absoluta para BUSCARV rango BUSCARV(G3, $B$3:$D$7, 3, FALSO) No debes usar lo siguiente: BUSCARV(G3, B3:D7, 3, FALSO) Así, se evitan cambios impredecibles en el rango cuando se copia o se arrastra.
Ordena la primera columna de forma ascendente cuando uses una concordancia aproximada, como está_ordenada = VERDADERO.	Si utilizas una concordancia aproximada o está_ordenada = VERDADERO, debes ordenar la primera columna de forma ascendente. De lo contrario, es probable que el valor que se muestra sea incorrecto. Obtén más información para ordenar.
Limpia tus datos antes de usar BUSCARV.	Antes de usar BUSCARV, recuerda limpiar tus datos. Los datos no limpios pueden hacer que BUSCARV muestre un valor impredecible. Estos son algunos de los errores más comunes de los datos no limpios: Espacios al principio: " manzana" Espacios al final: "manzana " Comillas vacías o en blanco: "" y " " no son equivalentes Para eliminar los espacios en blanco al principio y al final, puedes usar Datos Limpieza de datos Cortar espacios en blanco.
No almacenes valores numéricos o de fecha como texto	Asegúrate de que los valores numéricos o de fecha de la primera columna del rango de BUSCARV, como la columna de valor de búsqueda, no se almacenen como valores de texto. De lo contrario, es posible que se muestre un valor inesperado. En la parte superior de Hojas de cálculo, selecciona la columna de valor de búsqueda. Presiona Menú de formato Número. Elige una opción según el tipo de datos que desees: Fecha Número