この関数は、値式の結果に名前を割り当て、数式の結果を返します。
使用例
LET(avg, AVERAGE(B2:D2), IF(avg>=4, "非常に良い", IF(avg>=3, "良い", "悪い"))): 平均値を分類します。
LET(criteria, "フレッド", range, FILTER(A2:D8, A2:A8=criteria), ARRAYFORMULA(IF(ISBLANK(range), "-", range))): データをフィルタして、空白のセルをダッシュに置き換えます。
構文
LET(名前 1, 値式 1, [名前 2, ...], [値式 2, ...], 数式)
名前 1: それに続く別の値式と数式内で使用される名前。識別子である必要があります（詳細は後述）。大文字と小文字は区別されません。値式 1: 前に宣言した名前を使用して、結果を後で参照できる数式。前のパラメータで宣言した名前を使用できます。- 例:
AVERAGE(B2:D2)
- 例:
名前 2…: （省略可）割り当てられる追加の名前。繰り返し使用できます。値式 2…: （省略可）評価される追加の値式。繰り返し使用できます。数式: 計算される数式。LET関数で宣言された名前を使用します。
ヒント: LET 関数内で定義される名前として、数式を使用できます。値式は、それに続く別の値式や数式で複数回使用される場合でも、LET 関数内で 1 回だけ評価されます。
例
LET を使用して商品評価の平均値を分類する
サンプルデータ:
|
A |
B |
C |
D |
|
|---|---|---|---|---|
|
1 |
商品 |
1 月の評価 |
2 月の評価 |
3 月の評価 |
|
2 |
赤い T シャツ |
3.5 |
4 |
3 |
|
3 |
ブラック ジーンズ |
4.5 |
5 |
3.5 |
|
4 |
帽子 |
3 |
2.5 |
2 |
LET を使用する場合: E2 に次の数式を入力し、セルを囲む青いボックスを E3 と E4 までドラッグして入力します。
=LET(avg, AVERAGE(B2:D2), IF(avg>=4, "非常に良い", IF(avg>=3, "良い", "悪い")))
LET を使用しない場合: E2 に次の数式を入力し、セルを囲む青いボックスを E3 と E4 までドラッグして入力します。
=IF(AVERAGE(B2:D2)>=4, "非常に良い", IF(AVERAGE(B2:D2)>=3, "良い", "悪い"))
結果:
|
A |
B |
C |
D |
E |
|
|---|---|---|---|---|---|
|
1 |
商品 |
1 月の評価 |
2 月の評価 |
3 月の評価 |
平均評価の分類 |
|
2 |
赤い T シャツ |
3.5 |
4 |
3 |
良い |
|
3 |
ブラック ジーンズ |
4.5 |
5 |
3.5 |
非常に良い |
|
4 |
帽子 |
3 |
2.5 |
2 |
悪い |
LET を使用してデータをフィルタし、空白のセルをダッシュに置き換える
「フレッド」のすべてのデータを返し、空白のセルをダッシュに置き換えます。
サンプルデータ:
|
A |
B |
C |
D |
|
|---|---|---|---|---|
|
1 |
担当者 |
地域 |
商品 |
利益 |
|
2 |
エイミー |
東 |
リンゴ |
$1.33 |
|
3 |
フレッド |
南 |
バナナ |
$0.09 |
|
4 |
エイミー |
西 |
マンゴー |
$1.85 |
|
5 |
フレッド |
北 |
$0.82 |
|
|
6 |
フレッド |
西 |
バナナ |
$1.25 |
|
7 |
エイミー |
東 |
リンゴ |
$0.72 |
|
8 |
フレッド |
北 |
マンゴー |
$0.54 |
LET を使用する場合: E2 に次の数式を入力します。
=LET(criteria, "フレッド", range, FILTER(A2:D8, A2:A8=criteria), ARRAYFORMULA(IF(ISBLANK(range), "-", range)))
LET を使用しない場合: E2 に次の数式を入力します。
=ARRAYFORMULA(IF(ISBLANK(FILTER(A2:D8, A2:A8="フレッド")), "-", FILTER(A2:D8, A2:A8="フレッド")))
結果:
|
E |
F |
G |
H |
|
|---|---|---|---|---|
|
1 |
担当者 |
地域 |
商品 |
利益 |
|
2 |
フレッド |
南 |
バナナ |
0.09 |
|
3 |
フレッド |
北 |
- |
0.82 |
|
4 |
フレッド |
西 |
バナナ |
1.25 |
|
5 |
フレッド |
北 |
マンゴー |
0.54 |
一般的なエラー
名前引数が識別子になっていない例: =LET(B2, AVERAGE(B2:D2), IF(B2>=4, "非常に良い", IF(B2>=3, "良い", "悪い")))
引数が識別子でない場合、次のエラーが発生します。
識別子の要件:
- 「A1」や「A2」などの範囲は指定できません
- スペースや特殊文字を含めることはできません
- 先頭に数字（「9hello」など）を使用できません
LET 関数内の値式では、この構文（例:「関数内の左側」）に沿ってあらかじめ宣言されている名前付き引数を使用します。
例:
|
LET(x, 1, y, LET(z, 2, x+z), x+y) |
正しい - LET 関数内で使用する前に x が宣言されています。 |
|---|---|
|
LET(y, LET(z, 2, x+y), x, 1, x+y) |
誤り - 宣言する前に x を使用しています。 |
宣言前に引数を使用すると、次のエラーが発生します。
