Fonction LET

Cette fonction attribue un nom avec les résultats des expressions_de_valeur et renvoie le résultat de l'expression_de_formule.

Exemple d'utilisation

LET(moyenne; MOYENNE(B2:D2); SI(moyenne>=4; "Excellent"; SI(moyenne>=3; "Bon"; "Médiocre"))) : catégorisez une valeur moyenne.

LET(critères; "Fred"; plage; FILTRER(A2:D8; A2:A8=critères); ARRAYFORMULA(SI(ESTVIDE(plage); "-"; plage))) : filtrez les données et remplacez la cellule vide par un tiret.

Syntaxe

LET(nom1; expression_de_valeur1; [nom2; ...]; [expression_de_valeur2; ...]; expression_de_formule)

nom1 : nom utilisé dans les expressions_de_valeur suivantes et dans l'expression_de_formule. Il doit s'agir d'un identifiant (voir détails ci-dessous). Il n'est pas sensible à la casse.
expression_de_valeur1 : formule dont le résultat peut être désigné plus tard avec le nom déclaré précédemment. Elle peut utiliser des noms déclarés dans les paramètres précédents.
- Par exemple, MOYENNE(B2:D2).
nom2… : [FACULTATIF] Autres noms répétables à attribuer.
expression_de_valeur2… : [FACULTATIF] Autres expressions_de_valeur répétables à évaluer.
expression_de_formule : formule à calculer. Elle utilise les noms déclarés dans la fonction LET.

Conseil : Vous pouvez utiliser l'expression_de_formule pour les noms définis dans le champ d'application de la fonction LET. Les expressions_de_valeur ne sont évaluées qu'une seule fois dans la fonction LET, même si les expressions_de_valeur suivantes ou l'expression_de_formule les utilisent plusieurs fois.

Exemples

Catégoriser la valeur moyenne des avis sur les produits avec LET

Exemples de données :

	A	B	C	D
1	Produit	Avis de janvier	Avis de février	Avis de mars
2	T-shirt rouge	3,5	4	3
3	Jean noir	4,5	5	3,5
4	Chapeau	3	2,5	2

Avec LET : saisissez cette formule dans E2 et faites glisser le cadre bleu entourant la cellule vers le bas pour remplir E3 et E4.

=LET(moyenne; MOYENNE(B2:D2); SI(moyenne>=4; "Excellent"; SI(moyenne>=3; "Bon"; "Médiocre")))

Sans LET : saisissez cette formule dans E2 et faites glisser le cadre bleu entourant la cellule vers le bas pour remplir E3 et E4.

=SI(MOYENNE(B2:D2)>=4; "Excellent"; SI(MOYENNE(B2:D2)>=3; "Bon"; "Médiocre"))

Résultat :

	A	B	C	D	E
1	Produit	Avis de janvier	Avis de février	Avis de mars	Catégorie d'évaluation moyenne
2	T-shirt rouge	3,5	4	3	Bon
3	Jean noir	4,5	5	3,5	Excellent
4	Chapeau	3	2,5	2	Médiocre

Créer une copie

Filtrer les données et remplacer les cellules vides par un tiret à l'aide de LET

Renvoyez toutes les données correspondant à "Fred" et remplacez les cellules vides par un tiret.

Exemples de données :

	A	B	C	D
1	Représentant	Région	Produit	Bénéfice
2	Amélie	Est	Pomme	1,33 €
3	Fred	Sud	Banane	0,09 €
4	Amélie	Ouest	Mangue	1,85 €
5	Fred	Nord		0,82 €
6	Fred	Ouest	Banane	1,25 €
7	Amélie	Est	Pomme	0,72 €
8	Fred	Nord	Mangue	0,54 €

Avec LET : saisissez cette formule dans E2 :

=LET(critères; "Fred"; plage; FILTRER(A2:D8; A2:A8=critères); ARRAYFORMULA(SI(ESTVIDE(plage); "-"; plage)))

Sans LET : saisissez cette formule dans E2 :

=ARRAYFORMULA(SI(ESTVIDE(FILTRER(A2:D8; A2:A8="Fred")); "-"; FILTRER(A2:D8; A2:A8="Fred")))

Résultat :

	E	F	G	H
1	Représentant	Région	Produit	Bénéfice
2	Fred	Sud	Banane	0,09
3	Fred	Nord	-	0,82
4	Fred	Ouest	Banane	1,25
5	Fred	Nord	Mangue	0,54

Créer une copie

Erreurs courantes

L'argument "nom" n'est pas un identifiant

Exemple : =LET(B2; MOYENNE(B2:D2); SI(B2>=4; "Excellent"; SI(B2>=3; "Bon"; "Médiocre")))

Si l'argument n'est pas un identifiant, l'erreur suivante se produit :

Exigences concernant les identifiants :

Il ne peut pas s'agir de plages ("A1" ou "A2", par exemple).
Ils ne peuvent pas contenir d'espaces ni de caractères spéciaux.
Ils ne peuvent pas commencer par des chiffres, comme dans "9hello".

Problème de champ d'application de gauche à droite

Dans une expression_de_valeur au sein de la fonction LET, cette syntaxe vous permet d'utiliser les arguments nommés qui ont déjà été déclarés précédemment. Par exemple, "à gauche dans la fonction".

Exemple :

LET(x; 1; y; LET(z; 2; x+z); x+y)	CORRECT : déclaration de x avant son utilisation dans la fonction LET interne.
LET(y; LET(z; 2; x+y); x; 1; x+y)	INCORRECT : utilisation de x avant sa déclaration.

Si vous utilisez un argument avant sa déclaration, l'erreur suivante se produit :

Fonction associée

LAMBDA