LET-Funktion

Diese Funktion weist einen Namen mit den Ergebnissen von Wertausdruck zu und gibt das Ergebnis von Formelausdruck zurück.

Verwendungsbeispiel

LET(avg, AVERAGE(B2:D2); IF(avg>=4; "Hervorragend"; IF(avg>3; "Gut"; "Schlecht"))): Einen Durchschnittswert kategorisieren.

LET(criteria; "Fred"; range, FILTER(A2:D8; A2:A8=criteria); ARRAYFORMULA(IF(ISBLANK(range); "-"; range))): Daten filtern und die leere Zelle durch einen Bindestrich ersetzen.

Syntax

LET(Name1; Wertausdruck1; [Name2; …]; [Wertausdruck2; …]; Formelausdruck)

Name1: Ein Name, der innerhalb der nächsten Wertausdrücke und dem Formelausdruck verwendet wird. Das muss eine Kennung sein (Details siehe unten). Bei der Verwendung wird nicht zwischen Groß- und Kleinschreibung unterschieden.
Wertausdruck1: Formel, auf deren Ergebnis später mit dem zuvor deklarierten Namen Bezug genommen werden kann. Dabei können die in den vorherigen Parametern deklarierten Namen verwendet werden.
- Beispiel: MITTELWERT(B2:D2).
Name2…: [OPTIONAL] Wiederholbare, weitere Namen, die zugewiesen werden sollen.
Wertausdruck2…: [OPTIONAL] Wiederholbarer, zusätzlicher Wertausdruck, der ausgewertet werden soll.
Formelausdruck: Zu berechnende Formel. Darin werden die Namen verwendet, die in der LET-Funktion angegeben wurden.

Tipp : Sie können Formelausdruck als Namen verwenden, die im Bereich der LET-Funktion definiert sind. Wertausdrücke werden in der LET-Funktion nur einmal ausgewertet, auch wenn die nächsten Wertausdrücke oder der Formelausdruck sie mehrmals verwenden.

Beispiele

Durchschnittlichen Wert von Produktbewertungen mit LET kategorisieren

Beispieldaten:

	A	B	C	D
1	Produkt	Bewertungen im Januar	Bewertungen im Februar	Bewertungen im März
2	Rotes T-Shirt	3,5	4	3
3	Schwarze Jeans	4,5	5	3,5
4	Schirmmütze	3	2,5	2

Mit LET: Geben Sie diese Formel in E2 ein und ziehen Sie den blauen Rahmen um die Zelle nach unten, um E3 und E4 zu füllen.

LET(avg, AVERAGE(B2:D2); IF(avg>=4; "Hervorragend"; IF(avg>3; "Gut"; "Schlecht")))

Ohne LET: Geben Sie die Formel in E2 ein und ziehen Sie den blauen Rahmen um die Zelle nach unten, um E3 und E4 zu füllen.

=IF(AVERAGE(B2:D2)>=4; "Hervorragend"; IF(AVERAGE(B2:D2)>=3, "Gut", "Schlecht"))

Ergebnis:

	A	B	C	D	E
1	Produkt	Bewertungen im Januar	Bewertungen im Februar	Bewertungen im März	Durchschnittliche Bewertungskategorie
2	Rotes T-Shirt	3,5	4	3	Gut
3	Schwarze Jeans	4,5	5	3,5	Hervorragend
4	Schirmmütze	3	2,5	2	Schlecht

Kopie erstellen

Mit LET Daten filtern und leere Zellen durch Bindestrich ersetzen

Alle Daten für „Fred“ zurückgeben und leere Zellen durch einen Bindestrich ersetzen.

Beispieldaten:

	A	B	C	D
1	Vertreter	Region	Produkt	Gewinn
2	Marie	Osten	Apfel	1,33 $
3	Fred	Süden	Banane	0,09 $
4	Marie	Westen	Mango	1,85 $
5	Fred	Norden		0,82 $
6	Fred	Westen	Banane	1,25 $
7	Marie	Osten	Apfel	0,72 $
8	Fred	Norden	Mango	0,54 $

Mit LET: Geben Sie diese Formel in E2 ein:

=LET(criteria, "Fred", range, FILTER(A2:D8, A2:A8=criteria), ARRAYFORMULA(IF(ISBLANK(range), "-", range)))

Ohne LET: Geben Sie die folgende Formel in E2 ein:

=ARRAYFORMULA(IF(ISBLANK(FILTER(A2:D8, A2:A8="Fred")), "-", FILTER(A2:D8, A2:A8="Fred")))

Ergebnis:

	E	F	G	H
1	Vertreter	Region	Produkt	Gewinn
2	Fred	Süden	Banane	0,09
3	Fred	Norden	-	0,82
4	Fred	Westen	Banane	1,25
5	Fred	Norden	Mango	0,54

Kopie erstellen

Häufig auftretende Fehler

Das Argument „Name“ ist keine Kennung

Beispiel: =LET(B2, AVERAGE(B2:D2), IF(B2>=4, "Hervorragend", IF(B2>=3, "Gut", "Schlecht")))

Wenn das Argument keine Kennung ist, tritt dieser Fehler auf:

Anforderungen an Kennungen:

Dürfen keine Bereiche wie „A1“ oder „A2“ sein.
Dürfen keine Leerzeichen oder Sonderzeichen enthalten.
Dürfen nicht mit Zahlen beginnen, z. B. „9hello“.

Rechtsläufiges Bereichsproblem

In einem Wertausdruck innerhalb der LET-Funktion können Sie mit dieser Syntax die benannten Argumente verwenden, die bereits zuvor deklariert wurden. Beispiel: „Links in der Funktion“.

Beispiel:

LET(x, 1, y, LET(z, 2, x+z), x+y)	RICHTIG: x wurde vor der Verwendung in der inneren LET-Funktion deklariert.
LET(y, LET(z, 2, x+y), x, 1, x+y)	FALSCH: mit x vor der Deklaration.

Wenn Sie ein Argument verwenden, bevor es deklariert wird, tritt dieser Fehler auf: