BYROW-Funktion

Diese Funktion gruppiert ein Array nach Zeilen. Dazu wird eine LAMBDA-Funktion auf jede Zeile angewendet.

Verwendungsbeispiel

BYROW(A1:C3;LAMBDA(Zeile;MAX(Zeile)))

BYROW(A1:C3;LAMBDA(Zeile;SUMME(Zeile)))

Syntax

BYROW(Array_oder_Bereich;LAMBDA)

• Array_oder_Bereich: Ein Array oder Bereich, das bzw. der nach Zeilen gruppiert werden soll.
• LAMBDA: Eine LAMBDA-Funktion, die auf jede Zeile im gegebenen Array oder Bereich angewendet wird, um den gruppierten Wert zu erhalten.
  • Syntax: LAMBDA(Name;Formelausdruck)
  • Voraussetzungen:
    • Die LAMBDA-Funktion muss genau ein Name-Argument sowie einen Formelausdruck enthalten, der dieses Name-Argument verwendet. Der Name wird in die aktuelle Zeile aufgelöst, die beim Anwenden der LAMBDA-Funktion gruppiert wird.

Hinweise

• Die übergebene LAMBDA-Funktion sollte genau ein Name-Argument akzeptieren. Andernfalls wird ein #N/A-Fehler zurückgegeben. Dieses Argument entspricht einer Zeile im Eingabearray.
• Jede Zeile sollte zu einem einzigen Wert gruppiert werden. Array-Ergebnisse für gruppierte Werte werden nicht unterstützt.

• Für den LAMBDA-Parameter kann eine benannte Funktion übergeben werden, die sich in diesem Fall wie eine LAMBDA-Funktion verhält. Weitere Informationen
  • Es muss genau ein Argumentplatzhalter definiert sein.
  • Nach der benannten Funktion sollte keine Klammer folgen.

Beispiele

Zeilenweise Summe

Beispieldaten:

	A	B	C
1	3	5	7
2	4	3	5
3	1	2	4

Beispiel: =BYROW(A1:C3;LAMBDA(Zeile;SUMME(Zeile)))

Ergebnis:

15

12

7

Jahre filtern, in denen ein Quartalsumsatz von 1.300 überschritten wurde

Beispieldaten:

	A	B	C	D	E
1		Q1	Q2	Q3	Q4
2	2019	1.060	295	1.425	280
3	2020	270	585	675	170
4	2021	285	1.200	780	1.235
5	2022	1.440	1.390	45	650

Beispiel:=FILTER(A2:A5;BYROW(B2:E5;LAMBDA(Zeile;MAX(Zeile)>1300)))

Ergebnis:

2019

2022

Ein 3 × 1-Array mit der Differenz zwischen dem Höchst- und dem Mindestwert jeder Zeile zurückgeben, wobei eine benannte Funktion als LAMBDA verwendet wird

Kopie erstellen

Beispieldaten:

	A	B	C
1	3	5	7
2	4	3	5
3	1	2	4

Beispiel: =BYROW(A1:C3;MAX_MIN_DIFF)

Benannte Funktion: MAX_MIN_DIFF ist eine benannte Funktion, die die Differenz zwischen dem Höchstwert und dem Mindestwert ausgibt.

Formeldefinition: =MAX(Zeile)-MIN(Zeile), wobei Zeile ein Argumentplatzhalter für MAX_MIN_DIFF ist.

Ergebnis:

4

2

3

Häufig auftretende Fehler

Die übergebene LAMBDA-Funktion hat nicht genau ein Namensargument

Wenn die übergebene LAMBDA-Funktion nicht genau ein Name-Argument und einen Formelausdruck als Argument enthält, tritt dieser Fehler auf:

„Falsche Anzahl von Argumenten für die LAMBDA-Funktion. Ein Argument wurde erwartet, aber 2 wurden übergeben.“

Beispiel: =BYROW(C1:C4;LAMBDA(a;b;a+b))

In diesem Beispiel wurden 2 Name-Argumente an LAMBDA übergeben, aber nur ein Argument ist erforderlich.

Der letzte Parameter von BYROW war kein LAMBDA

Wenn der letzte Parameter von BYROW kein LAMBDA war, tritt dieser Fehler auf:

„Argument muss LAMBDA sein.“

Beispiel: =BYROW(C1:C4;4)

Die an BYROW übergebene LAMBDA-Funktion war falsch

Wenn ein Name-Argument ungültig ist, tritt dieser Fehler auf:

„Das Argument X der Funktion LAMBDA ist kein gültiger Name.“

Beispiel: =BYROW(C1:C4;LAMBDA(C1; C1+1))

In diesem Beispiel ist C1 ein ungültiger Name, da er mit einem Bereich in Konflikt steht.

Die Anwendung von LAMBDA auf das Eingabearray gruppiert nicht jede Zeile zu einem einzelnen Wert

Wenn die Anwendung von LAMBDA auf das Eingabearray nicht jede Zeile zu einem einzelnen Wert gruppiert, tritt dieser Fehler auf:

„Einzelner Wert erwartet. Ergebnisse mit geschachtelten Arrays werden nicht unterstützt.“

Beispiel: =BYROW(C1:E1;LAMBDA(Zeile;Zeile))

Ähnliche Funktionen

• LAMBDA-Funktion: Mit dieser Funktion können Sie eine benutzerdefinierte Funktion mit einer Reihe von Name-Argumenten und einem Formelausdruck, der sie verwendet, erstellen und zurückgeben.
• MAP-Funktion: Diese Funktion ordnet jeden Wert in den gegebenen Arrays einem neuen Wert zu.
• REDUCE-Funktion: Diese Funktion reduziert ein Array auf ein kumuliertes Ergebnis.
• BYCOL-Funktion: Diese Funktion gruppiert ein Array nach Spalten.
• SCAN-Funktion: Diese Funktion durchsucht ein Array und generiert Zwischenwerte.
• MAKEARRAY-Funktion: Diese Funktion erstellt ein berechnetes Array mit angegebenen Dimensionen.
• Benannte Funktionen erstellen und verwenden: Mit dieser Funktion können Nutzer benutzerdefinierte Funktionen, ähnlich wie LAMBDA, erstellen und speichern.