RIGHT()

テキスト値の末尾から指定された数の文字を返します。返される文字数がテキスト値より長い場合や 0 より少ない場合は、テキスト値をそのまま返します。

使用例

RIGHT("123 Maple Dr", 5) は le Dr を返します。

RIGHT("123 Maple Dr", 0) は空白を返します。

小数値の小数部分

結果列の Decimal 値の小数部分:

NUMBER(
  RIGHT(
    TEXT([結果]),
    (LEN(TEXT([結果]))
      - FIND(".", TEXT([結果])))
  )
)

• TEXT([結果]) は Decimal 値を Text 値に変換します。この例で使用されるテキスト関数は、テキスト以外の値を違う方法で解釈します。TEXT() を使用すると結果列の値が各関数で同じように解釈されます。
• FIND(".", ...) は値の小数点を探します。
• (LEN(...) - FIND(...)) は、全体の長さから小数ではない部分の長さを引いて小数部分の長さを計算します。
• RIGHT(..., ...) は小数部分を抜き出します。
• NUMBER(...) は抜き出したテキストを Number 値に変換します。

関連情報: FIND()、LEN()、NUMBER()、TEXT()

番地から町名を抜き出す

通常、番地の最初の単語以降はすべて町名を表します。

RIGHT([住所], (LEN([住所]) - FIND(" ", [住所])))

• FIND(" ", [住所]) は住所列の値の先頭 / 左端のスペースを探します。

• LEN([住所]) - FIND(...) は、全体の長さから最初のスペースの前にあるテキストの長さを引いて最初のスペース以降の住所列の値の長さを計算します。

• RIGHT([住所], ...) は、最初のスペース以降の右端のテキストを返します。

関連情報: FIND()、LEN()

構文

RIGHT(テキスト, 文字数)

• テキスト - 任意のテキスト型。
• 文字数  - 返すテキストの文字数（Number）。Number 値以外が受け入れられることもありますが、予期しない結果になる場合があります。

関連情報

INITIALS()

LEFT()

MID()

RIGHT()

SUBSTITUTE()

TRIM()