# MIN()

Lowest item in list

Returns the lowest value in a list. If `list` is an empty list of values, returns 0.

## Sample usage

`MIN(Products[Price])` returns the lowest of all values in the `Price` column of the `Products` table. Equivalent to `MIN(SELECT(Products[Price], TRUE))`. See also: `SELECT()`

`MIN([Discounts])` returns the lowest of the items in the `Discounts` column value, where `Discounts` is of type `List`.

`MIN(LIST(1, 2, 3))` returns `Number`: `1`

### Lowest from Select Values

Lowest sale price to non-employees within the past six months:

``````MIN(
SELECT(
Sales[Sale Price],
AND(
ISNOTBLANK([Sale Price]),
NOT([Customer].[Is Employee?]),
([Sale Date] > (
EOMONTH(TODAY(), -7) + DAY(TODAY())
))
)
)
)``````
1. `SELECT(Sales[Sale Price], ...)` returns a list of values from the `Sale Price` column from rows of the `Sales` table.
2. `AND(..., ..., ...)` limits the values returned to only those from rows that match all of the given conditions.
3. `ISNOTBLANK([Sale Price])` includes only rows with a non-blank `Sale Price` column value.
4. `NOT([Customer].[Is Employee?])` excludes rows with a `Customer` column value that refers to a customer record that indicates the customer is also an employee.
5. `[Sale Date] > ...` includes only rows with a `Sale Date` column value later than the computed date.
6. `EOMONTH(TODAY(), -7) + DAY(TODAY()` computes the date for six month ago today.
7. `MIN(...)` returns the lowest value in the select list of `Sale Price` values.

See also: `AND()`, `DAY()`, `EOMONTH()`, `ISNOTBLANK()``NOT()`, `SELECT()`, `TODAY()`

### Common problems

`MIN(1, 2, 3)` In this example, the arguments are not in list form. To fix, wrap them in `LIST() `to construct a list: `MIN(LIST(1, 2, 3))`.

## Syntax

`MIN(list)`

• `list` - List of any numeric or any temporal type (but not a mix of both).

## Notes

AppSheet must be given enough context to determine what type of values `list` contains, that its contents are or will be a an appropriate type. To that end, `list` must be one of the following: a column value of type `List` that contains appropriate values; a column list (for example, `Products[Price]`) for a column of an appropriate type; or a constructed list (for example, with `LIST()`) of an appropriate type.

`AVERAGE()`

`COUNT()`

`MAX()`

`STDEVP()`

`SUM()`

How can we improve it?

Search
Clear search
Close search