先頭にあるリストアイテム
リストの先頭にある指定した数のアイテムを含むリストを返します。指定された数がリストの長さより大きい場合はリスト全体を返します。指定された数が 1 未満の場合は空のリストを返します。
使用例
TOP(LIST("赤", "黄色", "緑"), 2)
は、2 つのアイテム(赤
と黄色
)を含むリストを返します。
TOP({"赤", "黄色", "緑"}, 4)
は、3 つのアイテム(赤
、黄色
、緑
)を含むリストを返します。
ある月に含まれる日
各月の違いを考慮に入れ、ある月に含まれる日のリストを取得するには、次のようにします。
TOP(
{
1, 2, 3, 4, 5, 6, 7, 8, 9,
10, 11, 12, 13, 14, 15, 16, 17, 18, 19,
20, 21, 22, 23, 24, 25, 26, 27, 28, 29,
30, 31
},
EOMONTH([日付], 0)
)
{1, 2, 3, ..., 31}
は、月に含まれる可能性のあるすべての日を含むリストを構築します。EOMONTH([日付], 0)
は、日付
列内のDate
(またはDateTime
)値によって指定された月の最後の日の番号を識別します。TOP(..., ...)
は、指定された月の 1 日から最後の日までの日番号のみを含むリストを返します。
関連情報: EOMONTH()
下位の値
従業員の雇用日のうち、早いほうから数えた 5 つの日付を含むリストを取得するには、次のようにします。
TOP(SORT(従業員[雇用日]), 5)
従業員[雇用日]
は、従業員
テーブルの雇用日
列にあるすべての値を含むリストを取得します。SORT(...)
は、リスト内の日付を時系列で昇順(小さい値から大きい値の順)(デフォルトの並べ替え順)に並べ替え、早いほうの日付が先頭に来るようにします。TOP(..., 5)
は、並べ替えられたリストの最初の 5 つの値(従業員の雇用日のうち早いほうから数えた 5 つの日付)を返します。
関連情報: SORT()
上位の値が含まれる行
大谷先生のクラスで GPA が上位 3 位だった生徒の行を含むリストを取得するには、次のようにします。
TOP(
ORDERBY(
FILTER("生徒",
AND(
ISNOTBLANK([先生]),
([先生] = "大谷先生")
)
),
[GPA], TRUE
),
3
)
FILTER("生徒", ...)
は、生徒
テーブルから、条件と一致するキー値のリストを返します。AND(..., ...)
は、指定されたサブ条件のすべてと一致する行のみにフィルタを制限します。ISNOTBLANK([先生])
は、先生
列の値が空白でないことを条件とします。[先生] = "大谷先生"
は、先生
列の値が大谷先生
であることを条件とします。ORDERBY(..., [GPA], TRUE)
は、フィルタされたキーを、対応するGPA
列の値を基準に降順(大きい値から小さい値の順)(TRUE
)で並べ替えて、最も高い GPA を先頭に配置します。TOP(..., 3)
は、並べ替えられたリストの最初の 3 つのアイテム(上位 3 位までの GPA が含まれる行のキー)を返します。
関連情報: AND()
、FILTER()
、ISNOTBLANK()
、ORDERBY()
構文
TOP(リスト, 数)
リスト
- 任意の型のリスト。数
-リスト
に含まれるアイテム値のうち、返されるものの数を指定するNumber
値。