SUM()

リスト内の値の合計を計算して返します。

使用例

SUM(クラス[席数]) は、クラステーブルの席数列にあるすべての値の合計を返します。SUM(SELECT(クラス[席数], TRUE)) に相当します。関連情報: SELECT()

SUM([割引]) は、割引列の値に入っているすべてのアイテムの合計を返します（割引は List または EnumList 型です）。

SUM(LIST(1, 2, 3)) は Number 値の 6 を返します。

選択した行の値を合計する

レポート対象期間に記録された配送料の合計を計算します。

 

SUM(
  SELECT(
    配達[配達費用],
    AND(
      ([完了日] >= [_THISROW].[開始日]),
      ([完了日] < [_THISROW].[終了日])
    )
  )
)

• SELECT(配達[配達費用], ...) は、配達テーブルの選択行から配送料のリストを取得します。
• AND(..., ...) は SELECT() の結果を、すべての条件に一致する行のみに限定します。
• ([完了日] >= [_THISROW].[開始日]) はカウント内容を、完了日がレポートの開始日以降である行のみに限定します。
• ([完了日] < [_THISROW].[終了日])はさらに、レポートの終了日より前の日付である行に限定します。
• SUM(...) は、SELECT() の結果として得られた値を合計します。

関連情報: AND()、SELECT()

一般的な問題

SUM(1, 2, 3): 引数がリスト形式になっていません。これを修正するには、引数を LIST() でラップしてリストを構築し、SUM(LIST(1, 2, 3)) とします。

構文

SUM(リスト)

• リスト - 任意の数値型のリスト。

注

AppSheet がリストに含まれる値の型を判別できるよう、内容が数値であることを示す十分なコンテキストが必要です。そのため、リストは次のいずれかである必要があります。数値が含まれる List 型の列値、数値型の列の列リスト（例: 製品[価格]）、数値型の構成されたリスト（例: LIST() を使用）。

関連情報

AVERAGE()

COUNT()

MAX()

MIN()

STDEVP()