IN()

Is item in list?

Returns a Yes/No expression, as follows:

  • TRUE if the search target matches at least one item in the search value.
  • FALSE if the search target matches does not match an item in the search value.

Note: The match is case-insensitive: upper- and lower-case letters are equivalent.

Sample usage

IN("a", {"a", "b", "c"}) returns TRUE

IN("bc", {"a", "b", "c"}) returns FALSE

IN("d", {"a", "b", "c"}) returns FALSE

IN("Red", {"I'm bored!"}) returns FALSE

IN("@", LIST([Email])) answers the question: is the value of the Email column exactly @ and nothing else? Equivalent to ([Email] = "@"). See also: LIST()

IN(LEFT([Sentence], 1), {".", "?", "!"}) answers the question: is the left-most character of the value of the Sentence (LEFT([Sentence], 1)) a period (.), question mark (?), or exclamation mark (!)? Equivalent to CONTAINS(".?!", LEFT([Sentence], 1)). See also: CONTAINS(), LEFT()

IN(USEREMAIL(), AppUsers[Email]) answers the question: is the current app user's email address (USEREMAIl()) found in the list of Email addresses in the AppUsers table (AppUsers[Email])? See also: USEREMAIL()

IN(CONTEXT("ViewType"), {"Deck", "Gallery", "Table"}) answers the question: is the currently-displayed view's type Deck, Gallery, or Table? Equivalent to OR((CONTEXT("ViewType") = "Deck"), (CONTEXT("ViewType") = "Gallery"), (CONTEXT("ViewType") = "Table")). See also: CONTEXT(), OR()

Syntax

IN(needle, haystack)

  • needle - Any value to be found. The value's type must be compatible with that of the items of the search list (haystack).
  • haystack - A list of items (EnumList or List) to be searched. The type of items must be compatible with that of the search target (needle).

See also

CONTAINS()

FIND()

INTERSECT()

LIST()

SPLIT()

Was this helpful?
How can we improve it?
Search
Clear search
Close search
Google apps
Main menu
Search Help Center
false
false
false
false