COUNT()

リスト内の項目数を返します。

使用例

COUNT(商品[カラー]): 商品テーブルのカラー列の値の合計数（重複も含む）。これは COUNT(SELECT(商品[カラー], TRUE, FALSE)) と同等です。関連情報: SELECT()

COUNT(SELECT(商品[カラー], TRUE, TRUE)): 商品テーブルのカラー列の値の合計数（重複を除く）。

COUNT(SELECT(商品[カラー], IN([カラー], {"Red", "Orange"}))): 商品テーブルのカラー列で、カラー列の値が Red または Orange の値の合計数（重複を含む）。関連情報: IN()

COUNT(注文[_RowNumber]): 注文テーブルの行の合計数。これとは異なり、MAX(注文[_RowNumber]) は、空の行（削除された行など）やスプレッドシートのヘッダー行を考慮しません。関連情報: MAX()

COUNT([割引]) は、割引列値の項目数を返します。割引は List 型です。

COUNT(LIST("Red", "Yellow", "Green")) は 3 を返します。

COUNT(LIST()) は 0 を返します。

COUNT(LIST("")) は 1 を返します。

選択した行数をカウントする

レポート対象期間内に特別な配送指示のあった注文数をカウントする:

COUNT(
  FILTER(
    "注文",
    AND(
      ISNOTBLANK([特別な指示]),
      ([完了日] >= [_THISROW].[開始日]),
      ([完了日] < [_THISROW].[終了日])
    )
  )
)

• FILTER("注文", ...) は、注文の選択行の行参照（キー列の値）のリストを取得します。
• AND(..., ..., ...) は、結果をすべての条件と一致する行のみに限定します。
• ISNOTBLANK([特別な指示]) は、特別の配送指示を含む行のみがカウントされるようにします。
• ([完了日] >= [_THISROW].[開始日]) は、完了日列の値がレポートの開始日列の値よりも前になっていない行のみがカウントされるようにします。
• さらに、([完了日] < [_THISROW].[終了日]) は、レポートの終了日より前の日付になっている行のみがカウントされるようにします。
• COUNT(...) は、選択された項目の数を返します。

関連情報: AND()、FILTER()、ISNOTBLANK()

一般的な問題

COUNT(1, 2, 3) - この例では引数がリスト形式になっていません。これを修正するには、COUNT(LIST(1, 2, 3)) のように、引数を LIST() でラップしてリストを構成します。

構文

COUNT(リスト)

• リスト - 任意の型のリスト。

関連情報

AVERAGE()

MAX()

MIN()

STDEVP()

SUM()