TOTALHOURS()

指定された期間の時間数（Decimal 値）を返します。

使用例

TOTALHOURS("000:00:18") は 0.005（18 秒を時間で表した数）を返します。

TOTALHOURS("000:15:00") は 0.25（15 分を時間で表した数）を返します。

TOTALHOURS("024:00:00") は 24 を返します。

TOTALHOURS("024:00:00" + "000:15:00" + "000:00:18") は 24.255 を返します。TOTALHOURS(SUM(LIST("024:00:00", "000:15:00", "000:00:18"))) に相当します。関連情報: LIST()、SUM()

TOTALHOURS(TIMENOW() - "00:00:00") は、今日の午前 0 時から現在までに経過した時間数を返します。TIMENOW() は現在の時間値を返します。1 つの Time 値（"00:00:00"）をもう 1 つの値から引くと、必要な Duration 値の引数が求められます。関連情報: TIMENOW()、日時式

今週の労働時間

TOTALHOURS(
  SUM(
    SELECT(
      タイムシート[時間],
      AND(
        ([従業員] = USEREMAIL()),
        ([勤務日] > (TODAY() - WEEKDAY(TODAY()))),
        ([勤務日] <= (TODAY() - WEEKDAY(TODAY())) + 7)
      )
    )
  )
)

1. SELECT(タイムシート[時間], ...) は、指定された条件（...、（2）を参照）に一致するタイムシート テーブルの行から時間列の Duration 型の値を収集します。関連情報: SELECT()

2. AND(..., ..., ...) は、指定された条件（（3）、（4）、（5）を参照）のすべてに一致する行のみを含めます。関連情報: AND()

3. ([従業員] = USEREMAIL()) は、現在のアプリユーザーのメールアドレスと従業員列の値が一致する行のみを含めます。関連情報: USEREMAIL()

4. ([勤務日] > (TODAY() - WEEKDAY(TODAY()))) は、勤務日が前週の最終日以降である行のみを含めます。関連情報: TODAY()、WEEKDAY()

5. ([勤務日] <= (TODAY() - WEEKDAY(TODAY())) + 7) は、勤務日が今週の最終日またはその日より前の行のみを含めます。

6. SUM(...) は、（1）で収集した毎日の Hours 値から Duration 値として合計時間を計算します。関連情報: SUM()

7. TOTALHOURS(...) は、（6）の Duration 値を Decimal 値に変換します。

構文

TOTALHOURS(期間)

• 期間 - Duration 値。

関連情報

日時式

HOUR()

MINUTE()

SECOND()

TOTALMINUTES()

TOTALSECONDS()