真の場合 / 偽の場合の条件評価の結果を返します。最初の引数が TRUE
として評価された場合は 2 番目の引数を評価した結果を返し、そうでない場合は 3 番目の引数を評価した結果を返します。
使用例
IF(TRUE, "はい", "いいえ")
は、はい
を返します。
IF(FALSE, "はい", "いいえ")
は、いいえ
を返します。
IF((1 > 0), "はい", "いいえ")
は、はい
を返します。
IF((1 < 0), "はい", "いいえ")
は、いいえ
を返します。
IF(ISBLANK(""), "はい", "いいえ")
は、はい
を返します。関連情報: ISBLANK()
IF(NOT(ISBLANK("")), "はい", "いいえ")
は、いいえ
を返します。これは IF(ISNOTBLANK(""), "はい", "いいえ")
と同等です。関連情報: ISNOTBLANK()
、NOT()
IF(([カウント] < 0), 0, [カウント])
は、カウント
列の値がゼロより小さい場合は 0
を返し、ゼロ以上の場合はその値を返します。MAX(LIST(0, [カウント]))
と同等です。関連情報: LIST()
、MAX()
IF(([日付] = TODAY()), TRUE, FALSE)
は、日付
列の値が今日の日付と一致する場合は TRUE
を返し、一致しない場合は FALSE
を返します。これは ([日付] = TODAY())
と同等です。関連情報: TODAY()
IF(USERSETTINGS("大文字の名前か"), UPPER([名前]), [名前])
は、大文字の名前か
のユーザー設定の値が TRUE
の場合はすべて大文字の名前
列の値を返し、そうでない場合は名前
列の値をそのままの状態で返します。関連情報: UPPER()
、USERSETTINGS()
IF(ISNOTBLANK([電話番号]), [電話番号], "(電話番号なし)")
は、電話番号
列の値が空白でない場合はその値を返し、空白の場合はテキスト(電話番号なし)
を返します。
IF(ISNOTBLANK([顧客].[割引率]), ([価格] * [顧客].[割引率]), [価格])
は、顧客に割引が適用される場合は割引後の価格を返し、割引が適用されない場合は元の価格を返します。
うるう年かどうか
IF(
(
MONTH(
DATE(
"2/28/"
& YEAR(TODAY())
)
+ 1
)
= 2
),
"うるう年",
"うるう年でない"
)
TODAY()
は、今日の日付を返します。YEAR(...)
は、返された日付の年を返します。"2/28/" & ...
は、今年の 2 月 28 日を表す、MM/DD/YYYY
日付形式のText
値を構成します。DATE(...)
は、構成されたText
値をDate
値として宣言します。DATE(...) + 1
は、返された日付に 1 日を追加します。MONTH(...)
は、算出された日付の月番号として1
~12
のいずれかを返します。ここで、1
は 1 月、12
は 12 月です。((...) = 2)
は、月番号が2
(2 月)であるかどうかを判別します。IF(..., "うるう年", "うるう年でない")
は、今年の 2 月 28 日の翌日が 2 月である場合はうるう年
を返し、そうでない場合はうるう年でない
を返します。
関連情報: DATE()
、MONTH()
、TODAY()
、YEAR()
平日か週末か
IF(
IN(
WEEKDAY(TODAY()),
LIST(1, 7)
),
"週末",
"平日"
)
TODAY()
は、今日の日付を返します。WEEKDAY(...)
は、返された日付の曜日番号として1
~7 のいずれかを返します。ここで、1
は日曜日、7
は土曜日です。LIST(1, 7)
は、2 つの番号1
および7
のリストを構成します。IN(..., ...)
は、構成されたリスト内に、算出された曜日番号が存在するかどうかを判別します。IF(..., "週末", "平日")
は、曜日番号が1
または7
の場合は週末
を返し、そうでない場合は平日
を返します。
関連情報: IN()
、LIST()
、TODAY()
、WEEKDAY()
構文
IF(論理式, TRUE の場合の値, FALSE の場合の値)
論理式
-TRUE
またはFALSE
に評価されるYes/No
式。TRUE の場合の値
-論理式
がTRUE
として評価された場合に限り、評価される式。FALSE の場合の値
-論理式
がFALSE
として評価された場合に限り、評価される式。
TRUE の場合の値
と FALSE の場合の値
はどちらも、互換性のある型の結果を生成する必要があります(どちらもテキスト型の結果、どちらも数値型の結果など)。結果は単一の値にも、リストにもできます。