FILTER()

テーブルまたはスライスの行を選択して Ref のリストとして返します。このリストは、データセットに含まれる行のうち、select-row? 式が TRUE として評価された各行のキーからなるものです。

使用例

FILTER("注文", ([顧客] = [_THISROW].[顧客])) は、注文データセットに含まれる行のうち、顧客列の値が現在のフォームの顧客列の値と等しい（つまり、この顧客の注文）行のキーを返します。

FILTER("商品", ([価格] < 100)) は、商品データセットに含まれる行のうち、価格列の値が 100 未満（つまり、商品の価格が 100 ドル未満）の行のキーを返します。

FILTER("学生", TRUE) は、学生データセットに含まれるすべての行のキーを返します。学生 ID が学生のキー列の場合は、SELECT(学生[学生 ID], TRUE) と同等です。関連情報: SELECT()

FILTER("MyTable", FALSE) は、select-row? 式から常に FALSE が返されるため、すべての行を除外した空のリストを返します。

自分に割り当てられた未解決の問題

FILTER(
  "問題",
  AND(
    ([ステータス] = "未解決"),
    ([割り当て先] = USEREMAIL())
  )
)

1. FILTER("問題", ...) は、問題データセットにある選択行のキーのリストを取得します。
2. AND(..., ...) は、選択する行を、2 つの条件の両方と一致する行に限定します。
3. ([ステータス] = "未解決") は、選択する行を、ステータス列の値が未解決に設定されている行（つまり、未解決の問題のみ）に限定します。
4. ([割り当て先] = USEREMAIL()) はさらに、選択する行を、割り当て先列の値が現在のアプリユーザーのメールアドレスと等しい行（つまり、自分に割り当てられた問題）に限定します。

関連情報: AND()、USEREMAIL()

特別な指示がある注文

FILTER(
  "注文",
  AND(
    ISNOTBLANK([特別な指示]),
    ([完了日] >= [_THISROW].[開始日]),
    ([完了日] < [_THISROW].[終了日])
  )
)

1. FILTER("注文",  ...) は、注文にある選択行の行参照（キー列の値）のリストを取得します。
2. AND(..., ..., ...) は、結果をすべての条件と一致する行のみに限定します。
3. ISNOTBLANK([特別な指示]) は、選択する行を、特別な配送指示を含む行のみに限定します。
4. ([完了日] >= [_THISROW].[開始日]) は、カウントする行を、完了日列の値がレポートの開始日列の値より前になっていない行のみに限定します。
5. ([完了日] < [_THISROW].[終了日]) はさらに、レポートの終了日より前の日付になっている行に限定します。

関連情報: AND()、ISNOTBLANK()

一般的な問題

FILTER(Text, ([Ticket ID] = [_THISROW].[Ticket ID])) のようにすると、「Expression [...] could not be parsed due to exception: #VALUE!」というエラーが発生します。この例では、データセット名の Text が AppSheet 内部で意味を持つため、混乱が生じます。AppSheet または Excel の関数名と同じデータセット名を使用すると、この問題が生じる可能性があります。修正するには、問題となっている名前を引用符で囲んで FILTER("Text", ([Ticket ID] = [_THISROW].[Ticket ID])) とします。

FILTER("イベント", ([開催地] <> [目的の開催地])) を使用すると、「Unable to find column [...]」というエラーが発生します。select-row? 式内の列参照（たとえば、[開催地]）が、データセットの検索時に対象となる行を参照するからです。対象となる行の外部にある列にアクセスするには（列の制約、アプリの数式、初期値、または書式ルールの内部から FILTER() を使用する場合など）、_THISROW を使用して外部列を参照します（例: FILTER("イベント", ([開催地] <> [_THISROW].[目的の開催地]))）。

構文

FILTER(データセット, select-row?)

• データセット - 検索対象のテーブルまたはスライス（「データセット」）の名前を、リテラル Text 値（引用符付きか引用符なし）で指定します。式にすることはできません。
• select-row? - データセットの各行で評価され、TRUE または FALSE を返す Yes/No 式。結果にその行を含める必要がある（TRUE）か、除外する必要がある（FALSE）かを示します。

注意事項

このリストは順不同です。順序付けられているように見えても、偶然そのようになっているとお考えください。

関連情報

LOOKUP()

MAXROW()

MINROW()

ORDERBY()

REF_ROWS()

SELECT()