IFS()

最初の一致を取る条件評価の結果を返します。最初の引数が TRUE として評価された場合は、2 番目の引数を評価した結果を返します。

使用例

IFS(TRUE, "はい") は、はいを返します。

IFS(FALSE, "はい") は、空白（値なし）を返します。

IFS(FALSE, "はい", TRUE, "いいえ") は、いいえを返します（IF(FALSE, "はい", "いいえ") と同等）。関連情報: IF()

優先する電話番号

使用可能な電話番号の中から、優先する電話番号を選択します。

IFS(
  ISNOTBLANK([携帯電話番号]), [携帯電話番号],
  ISNOTBLANK([勤務先電話番号]), [勤務先電話番号],
  ISNOTBLANK([自宅電話番号]), [自宅電話番号]
)

次と同等です。

ANY(
  LIST(
    [携帯電話番号]
    [勤務先電話番号],
    [自宅電話番号]
  )
  - LIST("")
)

関連情報: リストでの減算、ANY()、ISNOTBLANK()、LIST()

デリバリー状況の要約

デリバリーやプロジェクトなどの完了期限までどの程度時間があるかをテキストで要約します。

IFS(
  ISBLANK([期限]),
    "スケジュール未設定",
  (TODAY() > [期限]),
    "期限超過",
  (TODAY() = [期限]),
    "今日が期限",
  (TODAY() = ([期限] - 1)),
    "明日が期限",
  TRUE,
    (([期限] - TODAY()) & " 残りの日数")
)

1. ISBLANK([期限]), "スケジュール未設定" は、期限列が空白の場合にスケジュール未設定を返します。これ以上の条件（下記）は考慮されません。関連情報: ISBLANK()

2. (TODAY() > [期限]), "期限超過" は、先行する条件（上記）と一致しない場合に、今日の日付が期限の後であれば期限超過を返します。これ以上の条件は考慮されません。関連情報: TODAY()
3. (TODAY() = [期限]), "今日が期限" は、先行するどの条件とも一致しない場合に、今日の日付が期限であれば今日が期限を返します。これ以上の条件は考慮されません。
4. (TODAY() = ([期限] - 1)), "明日が期限" は、先行するどの条件とも一致しない場合に、今日の日付が期限の前日であれば明日が期限を返します。これ以上の条件は考慮されません。
5. TRUE, (([期限] - TODAY()) & " 残りの日数") は、先行するどの条件とも一致しない場合に、期限までの日数を知らせるメッセージを返します。

曜日の名前

曜日の番号を名前に変換します。

IFS(
  (WEEKDAY(TODAY()) = 1), "日曜日",
  (WEEKDAY(TODAY()) = 2), "月曜日",
  (WEEKDAY(TODAY()) = 3), "火曜日",
  (WEEKDAY(TODAY()) = 4), "水曜日",
  (WEEKDAY(TODAY()) = 5), "木曜日",
  (WEEKDAY(TODAY()) = 6), "金曜日",
  TRUE, "土曜日",
)

次の例は機能的には同等ですが、より効率的です。

SWITCH(
  WEEKDAY(TODAY()),
  1, "日曜日",
  2, "月曜日",
  3, "火曜日",
  4, "水曜日",
  5, "木曜日",
  6, "金曜日",
  "土曜日",
)

関連情報: SWITCH()、TODAY()、WEEKDAY()

構文

IFS(条件 1, 値 1, [条件 2, 値 2 ...])

• 条件 1 - TRUE または FALSE を返す Yes/No 式。
• 値 1 - 条件 1 が TRUE として評価された場合に限り、評価される式。

• 条件 2, 値 2 -（省略可）最初のセットが TRUE に評価されなかった場合の追加の論理式および値。

値の式はすべて、互換性のある型の結果を生成する必要があります（すべてテキスト型の結果、すべて数値型の結果など）。結果はいずれも、単一の値またはリストにできます。

関連情報

IF()

SWITCH()