次のように Yes/No
式を返します。
-
すべての条件が
TRUE
の場合はTRUE
。 -
FALSE
の条件が 1 つでもある場合はFALSE
。
使用例
AND(FALSE, FALSE)
は FALSE
を返します。
AND(FALSE, TRUE)
は FALSE
を返します。
AND(TRUE, FALSE)
は FALSE
を返します。
AND(TRUE, TRUE)
は TRUE
を返します。
AND(ISNOTBLANK([グレード]), ([グレード] = "A"))
は、グレード
列の値が存在し、かつ、その値が A
と完全に一致する場合にのみ、TRUE
を返します。それ以外の場合は FALSE
を返します。関連情報: ISNOTBLANK()
AND(([名前] = "Acme"), ([評価] > 3), [優先かどうか])
は、行の会社名が Acme
で、その会社の評価が 3 以上であり、かつ優先ベンダーである場合にのみ、TRUE
を返します。それ以外の場合は FALSE
を返します。
AND((LEN([_THIS]) > 3), CONTAINS([_THIS], "@"))
は、現在の列の値(Valid_If
などで取得)が 3 文字以上で、その値に 1 個以上の @
記号が含まれている場合に TRUE
を返します。関連情報: CONTAINS()
, LEN()
最近連絡していない潜在顧客を選択する
コンタクトが必要なアプリの潜在顧客の中から、最近連絡していない顧客を含むテーブル行を選択します。行を選択するために、FILTER()
または SELECT()
関数を使用するか、スライスまたはセキュリティ フィルタを使用します。
AND(
IN([セールス コンサルタント], LIST(USEREMAIL(), "")),
NOT([連絡なし]),
([前回のコンタクト] < (TODAY() - 30))
)
AND(..., ..., ...)
は、すべての条件がTRUE
であることを必須としています。IN([セールス コンサルタント], ...)
は、抽出されたリストの行のセールス コンサルタント
列に値がある場合にのみ一致します。LIST(USEREMAIL(), "")
は、現在のアプリユーザーのメールアドレスの値が空白になっているリストを生成します。上のIN()
は、セールス コンサルタント
が指定されているアプリユーザーを含む行と連絡先が指定されていない行の両方に一致します。NOT([連絡なし])
は、連絡なし
列の値がTRUE
の行を除外します。[前回のコンタクト] < (TODAY() - 30)
は、前回のコンタクト
の値が 30 日以上前の日付になっている行にのみ一致します。
関連情報: IN()
、LIST()
、NOT()
、TODAY()
、USEREMAIL()
日付範囲の重なりを確認する
新しい行の日付範囲が、テーブル内の既存の行で定義されている日付範囲と重なっていないことを確認します。
AND(
([終了] > [開始]),
(COUNT(
FILTER(
"MyTable",
OR(
AND(
([開始] >= [_THISROW].[開始]),
([開始] <= [_THISROW].[終了])
),
AND(
([終了] >= [_THISROW].[開始]),
([終了] <= [_THISROW].[終了])
)
AND(
([開始] < [_THISROW].[開始]),
([終了] > [_THISROW].[終了])
)
)
)
) = 0)
)
AND(..., ...)
: 両方の条件を満たしている必要があります。([終了] > [開始])
: 新しい終了日が開始日の 1 日以上後の日付になっている必要があります。(COUNT(...) = 0)
: 内側のFILTER()
で、一致する行が見つからないこと(既存の開始 / 終了範囲が新しい範囲に含まれないこと)を条件としています。FILTER("MyTable", ...)
:MyTable
で条件に一致する行を探します。OR(..., ..., ...)
: 1 つ以上の条件を満たしている必要があります。AND(..., ...)
: 両方の条件を満たしている必要があります。([開始] >= [_THISROW].[開始])
: 既存の開始日が新しい開始日以降であることを条件としています。([開始] <= [_THISROW].[終了])
: 既存の開始日が新しい終了日以前であることを条件としています。AND(..., ...)
: 両方の条件を満たしている必要があります。([終了] >= [_THISROW].[開始])
: 既存の終了日が新しい開始日以降であることを条件としています。([終了] <= [_THISROW].[終了])
: 既存の終了日が新しい終了日以前であること条件と示しています。AND(..., ...)
: 両方の条件を満たしている必要があります。([開始] < [_THISROW].[開始])
: 既存の開始日が新しい開始日よりも前であることを条件としています。([終了] > [_THISROW].[終了])
: 既存の終了日が新しい終了日よりも後であることを条件としています。
既存の日付範囲が新しい範囲内で開始しているか(6~8 行目)、新しい範囲内で終了しているか(9~11 行目)、または新しい範囲を含んでいる(12~14 行目)場合、フィルタは行を選択し(5 行目)、選択した行のリストを返します(4 行目)。空のリストが生成された場合、既存の日付範囲と新しい範囲が重なっていることを意味します。
新しい終了日が開始日よりも後で(2 行目)、選択した行のリストが空になっている(3 行目)場合、式は TRUE と評価されます(1 行目)。これは、新しい日付が有効で、既存の日付と矛盾していないことを意味します。
構文
AND(条件 1, 条件 2, [条件 3 ...])
条件
-TRUE
またはFALSE
と評価されるYes/No
式。2 つ以上の条件
引数が必要です。