TIME()

Date 値、DateTime 値、Time 値のいずれかとして認識される場合は変換した値を返し、認識されない場合は空白を返します。Date 値が指定されていて時間コンポーネントがない場合は、12:00:00 AM を返します。

使用例

TIME("3:14")（AM / PM がない場合は 24 時間制）: 3:14:00 AM

TIME("15:14")（24 時間制）: 3:14:00 PM

TIME("3:14 PM")（AM / PM がある場合は 12 時間制）: 3:14:00 PM

TIME(TIMENOW()) : Time 値の現在の時刻。関連情報: TIMENOW()

TIME("4/1/2010") : 12:00:00 AM（Date 値に時間コンポーネントがないためデフォルトが使用されます）。

TIME(TODAY()) : 12:00:00 AM（TODAY() は Date 値を返し、時間コンポーネントがないためデフォルトが使用されます）。

TIME("4/1/2010 3:14"): 3:14:00 AM

TIME(NOW()) : DateTime 値の現在の時刻。関連情報: NOW()

Decimal 値の時間を Duration 値にする

Decimal 値で表された時間数を Duration 値に変換します。

(
  TIME(
    CONCATENATE(
      MOD(FLOOR([時間]), 24),
      ":",
      FLOOR(MOD(((60 * 60) * [時間]), (60 * 60)) / 60),
      ":",
      MOD(((60 * 60) * [時間]), 60)
    )
  )
  - "00:00:00"
)
+ (FLOOR([時間] / 24) * 24)

1. (60 * 60) は 60 分（1 時間）の秒数を返します。
2. (60 * 60) * [時間] は時間列の値で表された期間の秒数を返します。
3. FLOOR([時間] / 24) は日数を返します。関連情報: FLOOR()
4. MOD(FLOOR([時間]), 24) は残りの時間数を返します。関連情報: MOD()
5. FLOOR(MOD(((60 * 60) * [時間]), (60 * 60)) / 60) は残りの分数を返します。
6. MOD(((60 * 60) * [時間]), 60) は残りの秒数を返します。
7. CONCATENATE(..., ":", ..., ":", ...) は、Time 値としてフォーマットされた Text 値を構成します。これには 1 日に満たない時間のみが含まれます。Time 値は 24 時間を超えることはできません。関連情報: CONCATENATE()
8. TIME(...) は Text 値を Time 値に変換します。
9. (... - "00:00:00") は、Time 値から Time 値を引いて Duration 値を返します。Duration 値は 24 時間以上にすることができます。
10. ... + (FLOOR([時間] / 24) * 24) は、時間から丸 1 日の時間数を追加します。

関連情報: CONCATENATE()、FLOOR()、MOD()

一般的な問題

TIME("マーティン、おはよう"): 空白を返します。テキスト入力は認識される時間型ではないため変換できません。

構文

TIME(時間)

• 時間 - Date 値、DateTime 値、または Time 値。

メモ

式の中で日付を定数値として使用する場合は、MM/DD/YYYY 形式で表す必要があります。スプレッドシートのデータはこの形式の日付を使用しなければならないという意味ではありません。スプレッドシートの日付表現はスプレッドシートの言語 / 地域によって決まります。

時間型は特定の形式の Text 値であるため、TIME() に任意のテキスト値を指定できますが、時間以外の値にすると空白になります。

関連情報

日時式

DATE()

DATETIME()