ORDERBY()

指示どおりに並べ替えた元の行のキー値（Ref 値のリスト）を返します。

使用例

ORDERBY(製品[製品 ID], [製品名]) は、対応する製品名列の値で並べ替えた製品 ID 列の値（データセットのキー値）のリストを返します。

ORDERBY(製品[製品 ID], [製品価格], TRUE, [製品名]) は、製品行を価格で（TRUE の場合）降順（高から低 / 9-0 / Z-A）に並べ替えます。同じ価格の行は、デフォルトでは製品名でさらに昇順（低から高 / 0-9 / A-Z）に並べ替えられます。

ORDERBY(SELECT(顧客[顧客 ID], ([国] = "ブラジル")), [顧客名]) は、ブラジルの顧客の ID を顧客名で並べ替えます。ORDERBY(FILTER("顧客", ([国] = "ブラジル")), [顧客名]) に相当します。関連情報: FILTER()、SELECT()

最大値を含む行

INDEX(
  ORDERBY(
    FILTER(
      "生徒",
      ([クラス年度] = "2018")
    ),
    [GPA],
    TRUE
  ),
  1
)

1. FILTER("生徒", ([クラス年度] = "2018")) は、2018 年度クラスの生徒のデータセットから行を収集します。
2. ORDERBY(..., [GPA], TRUE) は、フィルタされた行を対応する GPA 列の値で（TRUE の場合）降順（高から低）に並べ替えます。
3. INDEX(..., 1) は、並べ替えられたリストから最初のアイテム（GPA が最も高い生徒の行）を抽出します。

MAXROW("生徒", "GPA", ([クラス年度] = "2018")) に相当します。

関連情報: FILTER()、INDEX()、MAXROW()

構文

ORDERBY(キー, 並べ替えキー, [降順かどうか, [並べ替えキー]]...)

• キー - 行を Ref 値のリストとして並べ替える場合のキー列値のリスト。一般的には FILTER() または SELECT() で収集されます。

• 並べ替えキー - 行の並べ替えキーを生成する式。並べ替えキーを他の行の対応する並べ替えキーと比較して、並べ替えたリストでの行の位置を決定します。式は対象となる行のコンテキストで評価されます（FILTER() や SELECT() の一致式に似ています）。最もシンプルでよくある並べ替えキーの式は並べ替える列の参照（[製品名] や [開始日] など）ですが、さらに複雑にすることもできます。
• 降順かどうか - Yes/No 式。FALSE に設定すると直前の並べ替えキーで昇順（低から高 / 0-9 /A-Z）に並べ替えられ、TRUE にすると降順（高から低 / 9-0 / Z-A）に並べ替えられます。
  
  複数の並べ替えキーで行を並べ替えることができます。追加する各並べ替えキーの式は、降順かどうかの引数を間に置いて前のキーの式と区切る必要があります。最後にある降順かどうかの引数は、値が FALSE になる場合は省略できます。

関連情報

FILTER()

MAXROW()

MINROW()

REF_ROWS()

SORT()