INDEX()

インデックス値に基づいて、リスト内の特定のアイテムの値を返します。アイテムがリストに含まれていない場合は空白を返します。

使用例

INDEX(学生[名前], 1) は、学生テーブルの名前列から任意の値を返します。なぜ任意の値であるかというと、学生[名前] 列リストの値の順序が保証されないからです。ただし、この列が SORT() でラップされている場合は除きます。これは ANY(学生[名前]) と同等です。関連情報: ANY()

INDEX(LIST("赤色", "黄色", "緑色"), 2) は Text 値の黄色を返します。

INDEX({"赤色", "黄色", "緑色"}, 4) は空白を返します（4 はリスト内にないため）。

列内の最大値

最も高い商品価格:

INDEX(SORT(商品[価格], TRUE), 1)

1. 商品[価格] は、商品テーブルの価格列からすべての値のリストを取得します。
2. SORT(..., TRUE) は、降順、つまり大きい値から小さい値の順（TRUE）で価格のリストを並べ替えます。
3. INDEX(..., 1) は、並べ替えされたリストの最初の価格を返します。

MAX(商品[価格]) と同等です。

関連情報: MAX()、SORT()

月の番号を名前に変換する

今日の月の名前（Text 値を返します）:

INDEX(
  {
    "1 月", "2 月", "3 月",
    "4 月", "5 月", "6 月",
    "7 月", "8 月", "9 月",
    "10 月", "11 月", "12 月"
  },
  MONTH(TODAY())
)

1. {"1 月", ...} は、月の名前のリストを構成します。
2. TODAY() は、今日の日付を返します。
3. MONTH(...) は、Date 値を対応する月の番号に変換します。
4. INDEX(..., MONTH(...)) は、月の番号を使用して、リストから月の名前を選択します。

次と同等です。

SWITCH(
  MONTH(TODAY()),
  1, "1 月",
  2, "2 月",
  3, "3 月",
  4, "4 月",
  5, "5 月",
  6, "6 月",
  7, "7 月",
  8, "8 月",
  9, "9 月",
  10, "10 月",
  11, "11 月",
  12, "12 月",
  ""
)

関連情報: MONTH()、TODAY()

優先する値

空白でない携帯電話番号、勤務先電話番号、自宅電話番号から値を選択:

INDEX(
  (
    LIST([携帯電話番号], [勤務先電話番号], [自宅電話番号])
    - LIST("")
  ),
  1
)

1. LIST([携帯電話番号], ...) は、3 つの番号からなるリストを構成します。
2. LIST(...) - LIST("") は、番号のリストから空白のアイテムを削除します。
3. INDEX(..., 1) は、リストの残りのアイテムのうち、最初のアイテムを返します。

次と同等です。

ANY(
  TOP(
    (
      LIST([携帯電話番号], [勤務先電話番号], [自宅電話番号])
      - LIST("")
    ),
    1
  )
)

関連情報: ANY()、LIST()、TOP()

列内の最大値を持つ行

Sandwich 先生のクラスで GPA が最も高い学生の行（Ref を返します）:

INDEX(
  ORDERBY(
    FILTER("学生",
      AND(
        ISNOTBLANK([教師]),
        ([教師] = "Sandwich 先生")
      )
    ),
    [GPA], TRUE
  ),
  1
)

1. FILTER("学生", ...) は、学生テーブルから、条件と一致するキー値のリストを返します。
2. AND(..., ...) は、指定されたサブ条件のすべてと一致する行のみにフィルタを制限します。
3. ISNOTBLANK([教師]) は、教師列の値が空白でないことを条件とします。
4. [教師] = "Sandwich 先生" は、教師列の値が Sandwich 先生であることを条件とします。
5. ORDERBY(..., [GPA], TRUE) は、フィルタされたキーを、対応する GPA 列の値を基準に降順、つまり大きい値から小さい値の順（TRUE）で並べ替えて、最も高い GPA を先頭に配置します。
6. INDEX(..., 1) は、順序付きリストの最初のアイテム（つまり、最も高い GPA を持つ行のキー）を返します。

次と同等です。

MAXROW(
  "学生", "GPA",
  AND(
    ISNOTBLANK([教師]),
    ([教師] = "Sandwich 先生")
  )
)

関連情報: AND()、FILTER()、ISNOTBLANK()、ORDERBY()、MAXROW()

曜日の番号を名前に変換する

今日の曜日の名前（Text 値を返します）:

INDEX(
  {
    "日曜日", "月曜日", "火曜日",
    "水曜日", "木曜日", "金曜日",
    "土曜日"
  },
  WEEKDAY(TODAY())
)

1. {"日曜日", ...} は、曜日の名前からなるリストを構成します。
2. TODAY() は、今日の日付を返します。
3. WEEKDAY(...) は、Date 値を、その日付の曜日に対応する番号に変換します。
4. INDEX(..., WEEKDAY(...)) は、曜日の番号を使用して曜日の名前を選択します。

次と同等です。

SWITCH(
  WEEKDAY(TODAY()),
  1, "日曜日",
  2, "月曜日",
  3, "火曜日",
  4, "水曜日",
  5, "木曜日",
  6, "金曜日",
  7, "土曜日",
  ""
)

関連情報: TODAY()、WEEKDAY()

構文

INDEX(リスト, 選択する値)

• リスト - 任意の型のリスト。
• 選択する値 - 取得するアイテム値のインデックス（Number 値）。リスト内の最初のアイテムのインデックスは 1 です。

関連情報

ANY()

TOP()