LEFT()

テキスト値の先頭から、指定された数の文字を返します。返す文字数がテキスト値より長い場合や 0 より少ない場合は、テキスト値をそのまま返します。

使用例

LEFT("123 Maple Dr", 5) は 123 M を返します。

LEFT("123 Maple Dr", 0) は空白を返します。

氏名のイニシャル

氏名のイニシャル:

LEFT([名], 1) & LEFT([姓], 1)

1. LEFT(..., 1) は、指定された列値の最初の文字を返します。
2. LEFT(...) & LEFT(...) は、2 つのイニシャルを 1 つのテキスト値に連結します。

INITIALS(CONCATENATE([名], " ", [姓])) と同等です。

関連情報: CONCATENATE()、INITIALS()

10 進数の整数部分

結果列の Decimal 値の整数部分:

NUMBER(
  LEFT(
    TEXT([結果]),
    (FIND(".", TEXT([結果])) - 1)
  )
)

1. TEXT([結果]) は Decimal 値を Text 値に変換します。この例で使用されているテキスト関数は、テキスト以外の値をそれぞれ異なる方法で解釈します。TEXT() を使用すると、結果列の値が各関数で同じように解釈されます。
2. (FIND(".", ...) - 1) は、小数点の直前の文字を探します。
3. LEFT(..., ...) は整数部分を抽出します。
4. NUMBER(...) は、抽出したテキストを Number に変換します。

FLOOR([Result]) と同等です。

関連情報: FIND()、FLOOR()、NUMBER()、TEXT()

住所の番地

一般的に、住所の最初の単語は番地です。

LEFT([住所], (FIND(" ", [住所]) - 1))

1. FIND(" ", [住所]) は、住所列の値の先頭 / 左端のスペースを探します。
2. FIND(...) - 1 は、最初のスペースの直前にある文字を探します。
3. LEFT([住所], ...) は、最初のスペースの前にある左端のテキストを返します。

INDEX(SPLIT([住所], " "), 1) と同等です。

関連情報: FIND()、INDEX()、SPLIT()

構文

LEFT(テキスト, 文字数)

• テキスト - 任意のテキスト型。
• 文字数  - テキストから返す文字の数（Number 値）。Number 以外の値も許容されますが、想定外の結果になる可能性があります。

関連情報

INITIALS()

MID()

RIGHT()

SUBSTITUTE()

TRIM()