Guía técnica de inicio rápido

Productos

AdSense para juegos (AFG)

Guía técnica de inicio rápido

Siguiente: Ejemplo de programa para precargar SWF para AdSense para juegos

Una guía de introducción para ingenieros que usan el SDK de anuncios multimedia interactivos de Google para publicar anuncios de AdSense en Flash.

Breve descripción

AdSense para vídeo y AdSense para juegos funcionan utilizando el mismo producto de Google: el kit de desarrollo de software de anuncios multimedia interactivos (SDK de IMA). Este SDK le permite solicitar anuncios de AdSense a través del lenguaje ActionScript de Flash con el fin de combinar contenido y publicidad de forma más integrada. Dichos productos están sujetos a los Términos y condiciones de AdSense, las Políticas del programa de AdSense y las directrices de uso específicas del producto. Recuerde que los clics erróneos provenientes de implementaciones excesivamente dinámicas o incorrectas provocarán acciones que pueden conllevar incluso la rescisión de la cuenta.

Solicitar y publicar anuncios a través del SDK de IMA consiste en configurar una solicitud de anuncio, cargar el anuncio resultante y reproducirlo en el momento adecuado. Puede intentar utilizar los ID predeterminados del editor “ca-video-afvtest” o “ca-games-test”. Deberá proporcionar un ejemplo de la integración a su administrador de cuentas antes de que se le permita implementar anuncios en sus sitios web.

Instalación

Tiene que empezar por descargarse las bibliotecas SWC o MXP del SDK de anuncios multimedia interactivos de Google. Esta biblioteca viene incorporada en su instalación Flash o Flex y le proporciona acceso a la funcionalidad del SDK. Siga nuestras instrucciones de instalación.

Código de ejemplo

Deberá comprobar que ha añadido todas las expresiones de inclusión en el lugar en el que tenga previsto implementar el SDK de IMA.

Configuración de solicitud de anuncio

Debe crear una solicitud de anuncio con parámetros de orientación contextual, criterios de seguimiento, su ID de editor y otros parámetros necesarios. Cuando tenga preparado el objeto de solicitud de anuncio, será necesario un cargador de anuncios para administrar la solicitud y para dirigir la respuesta de anuncio a un método con el fin de gestionar la devolución de llamada. Cuando se devuelva correctamente un anuncio, el evento AdsLoadedEvent.ADS_LOADED se activará, mientras que si la solicitud de anuncio es incorrecta, se activará un evento AdErrorEvent.AD_ERROR.

Hay otras API disponibles en nuestra guía completa de API.

Parámetros

Obligatorio

Son parámetros necesarios para todas las solicitudes de anuncio. Sin la inclusión y el formato correcto de estos parámetros, las solicitudes de anuncio darán error.

Nombre	Tipo	Descripción
adSlotWidth	Number	Anchura del área en la que se ubicará el anuncio, calculada en píxeles.
adSlotHeight	Number	Altura del área en la que se ubicará el anuncio, calculada en píxeles.
publisherId	String	Su ID de cuenta del producto AdSense para vídeo o AdSense para juegos. Nota: Asegúrese de que el formato de la cadena publisherId sea "ca-games-pub-0123456789012345" o "ca-video-pub-0123456789012345". Nota: Asegúrese de utilizar los publisherId "ca-video-afvtest" o "ca-games-test" durante las pruebas.
contentId	String	Una cadena alfanumérica única específica para un vídeo o un juego. Esta cadena de ID no debe repetirse en ninguna otra parte del contenido. Se utiliza para la orientación de anuncios y para las revisiones de política. Ejemplo: YouTube utiliza un ID de vídeo para distinguir entre vídeos ("0aRIlnQzw-A").
adType	adRequestType	Tipo de anuncio solicitado. Valores AdsRequestType.AUDIO Anuncios de audio, formados por un clip de audio lineal y un banner complementario. AdsRequestType.FULL_SLOT Anuncios rectangulares adecuados para su uso antes de contenido de juegos o después de contenido de vídeo. AdsRequestType.GRAPHICAL Superposición de display o anuncios de espacio publicitario completo (solo imagen/flash). AdsRequestType.GRAPHICAL_FULL_SLOT Anuncios de display en espacio publicitario completo (solo anuncios rectangulares de imagen/flash). AdsRequestType.GRAPHICAL_OVERLAY Anuncios de superposición de display (solo anuncios de banner de imagen/flash). AdsRequestType.OVERLAY Anuncios de banner con una animación adecuados para su uso durante la reproducción de contenido de vídeo. AdsRequestType.TEXT_FULL_SLOT Anuncios de texto en espacio publicitario completo (solo contenido de texto). AdsRequestType.TEXT_OR_GRAPHICAL Anuncios en espacio publicitario completo o de superposición de cualquier tipo. AdsRequestType.TEXT_OVERLAY Anuncios de superposición de texto (solo contenido de texto). AdsRequestType.VIDEO Anuncios de vídeo pre-roll, mid-roll o post-roll.

Opcional

Estos parámetros son opcionales y útiles para ajustar el modo de solicitud y publicación de los anuncios.

Nombre	Tipo	Descripción
adtest	String	Parámetro de pruebas útil que, cuando está activado, omitirá impresiones y clics para un ID de editor. Esto le permitirá inspeccionar los anuncios activos sin que represente ningún cargo para los anunciantes. Valores on Se omitirán las impresiones y los clics. off (predeterminado) Se contarán las impresiones y los clics del modo habitual.
uniqueAds	Boolean	Cuando se habilita, los anuncios de la carga de una página serán únicos. Resulta útil para la limitación de frecuencia de un único vídeo o juego.
adTimePosition	Number	Este valor establece en qué momento se muestra el anuncio de vídeo en un determinado flujo de contenido. Valores 0 (predeterminado) El anuncio se muestra en posición pre-roll antes del contenido. -1 El anuncio se muestra en posición post-roll cuando ha terminado el contenido. N Número de segundos del flujo de contenido transcurridos los cuales se ejecuta el anuncio mid-roll.

Devoluciones de llamada

Pueden suscribirse estas devoluciones de llamada con el fin de recibir una notificación de eventos de carga de anuncios importantes.

Nombre	Descripción
AdsLoadedEvent.ADS_LOADED	Se lanza el evento cuando se ha realizado una solicitud de anuncio y se han devuelto con éxito uno o más bloques de anuncios individuales para cargar y mostrar.
AdErrorEvent.AD_ERROR	Se lanza el evento cuando se ha realizado una solicitud de anuncio y se ha respondido desfavorablemente con parámetros malformados o si un anuncio no se encuentra disponible. Nota: Existen múltiples motivos por los cuales los anuncios pueden no devolverse así que su integración deberá lidiar con esa posibilidad de forma eficaz.

Código de ejemplo

Con el fin de solicitar un anuncio, debe preparar una solicitud de anuncio con los parámetros relevantes.

var adsRequest:AdsRequest = new AdsRequest();

// Parámetros obligatorios
adsRequest.adSlotWidth = 640;
adsRequest.adSlotHeight = 360;
adsRequest.publisherId= "ca-video-afvtest";
adsRequest.adType = AdsRequestType.VIDEO;
adsRequest.contentId = "0aRIlnQzw-A";

// Parámetros recomendados
adsRequest.channels = ["sports", "entertainment", "0123456789"];
adsRequest.descriptionUrl = "http://www.example.com/description.htm";
adsRequest.age = 1002;
adsRequest.gender = 1;

// Parámetros opcionales
adsRequest.adTest = "on";
adsRequest.language = "ja";
adsRequest.maxTotalAdDuration = 30000;
adsRequest.minTotalAdDuration = 15000;
adsRequest.uniqueAds = true;
adsRequest.adTimePosition = 1;

// Preparar el cargador de anuncios
var adsLoader:AdsLoader = new AdsLoader();
stage.addChild(adsLoader);

// ADS_LOADED cuando los anuncios se devuelven correctamente
// AD_ERROR cuando no se encuentran anuncios para la solicitud
adsLoader.addEventListener(AdsLoadedEvent.ADS_LOADED, onAdsLoaded);
adsLoader.addEventListener(AdErrorEvent.AD_ERROR, onAdError);

// Solicitar los anuncios
adsLoader.requestAds(adsRequest);

Visualización de anuncios

Cuando una solicitud de anuncio haya obtenido una respuesta, su código deberá ser capaz de mostrar el anuncio correctamente o apoyarse en otra fuente de publicidad o en el contenido. Asegúrese de que su integración se rija por eventos y no utilice temporizadores para gestionar la visualización de anuncios.

Antes de enviar la integración para su aprobación, confirme que la visualización de anuncios cumple con nuestras directrices de uso específicas del producto.

Hay otras API disponibles en nuestra guía completa de API.

Propiedades

Se trata de propiedades que el administrador de anuncios puede utilizar para modificar el método de visualización de anuncios.

Nombre	Tipo	Descripción
adSlotHeight	Number	Ajusta u obtiene la altura del área rectangular en la que se muestra un anuncio. No es necesario que este valor coincida con la altura real del anuncio, pero sí que como mínimo la cumpla. Deberá ajustar un nuevo valor siempre que el espacio publicitario modifique sus dimensiones, por ejemplo, un reproductor de vídeo puede tener controles de vídeo que desaparezcan y aparezcan, lo cual modifica el área disponible para el espacio publicitario.
adSlotWidth		Ajusta u obtiene la anchura del área rectangular en la que se muestra un anuncio. No es necesario que este valor coincida con la anchura real del anuncio, pero sí que como mínimo la cumpla. Deberá ajustar un nuevo valor siempre que el espacio publicitario modifique sus dimensiones, por ejemplo, un reproductor de vídeo puede tener controles de vídeo que desaparezcan y aparezcan, lo cual modifica el área disponible para el espacio publicitario.
ads	ad[]	Una lista de anuncios que almacena los datos acerca de los anuncios individuales que devuelve el servidor de anuncios. Puede acceder a todos los anuncios mediante este método.
type	String	Devuelve el tipo de anuncio devuelto. Valores flash Anuncios de superposición y de espacio publicitario completo. video Anuncios de vídeo.
Solo flashAdsManager
decoratedAd	Boolean	Si tiene valor true, el anuncio se mostrará en Chrome proporcionado por Google tal como sea aplicable al tipo de anuncio como, por ejemplo, un botón de cierre, una opción de restablecimiento, animaciones mostrar/ocultar, y de fondo.
volumeAd	Number	Ajusta o establece el volumen de audio que admite un anuncio.
x	Number	Ajusta u obtiene la coordenada del área de visualización de un anuncio Flash. Si un anuncio es menor que el área de visualización del anuncio Flash, también se utilizará el valor de alineación para ubicar mejor el anuncio.
y	Number	Ajusta u obtiene la coordenada y del área de visualización de un anuncio Flash. Si un anuncio es menor que el área de visualización del anuncio Flash, también se utilizará el valor de alineación para ubicar mejor el anuncio.
Sólo videoAdsManager
clickTrackingElement	InteractiveObject	El seguimiento de clics debe estar habilitado en la zona del reproductor de vídeo antes de poder ejecutar el anuncio. Esta propiedad permite obtener y ajustar el elemento sobre el cual se realiza el seguimiento de los clics.
mediaSelectionSettings	MediaSelectionSettings	Esta propiedad obtiene y ajusta la configuración de selección de medios establecida por los usuarios. La configuración de selección de medios sirve para elegir qué archivos multimedia se utilizan en los anuncios de vídeo puesto que estos pueden contener URL a distintos archivos multimedia. Puede especificar qué anchos de banda, tipos MIME y modos de visualización admiten o prefieren. Los anuncios que no contienen varios archivos multimedia hacen caso omiso de esta propiedad.

Métodos

Se trata de métodos que se pueden llamar en el administrador de anuncios para solicitar la carga o la visualización de anuncios.

Nombre	Descripción
(void) load(container?:Object)	Este método permite a los anuncios precargar creatividades que se preparan para visualizarse. Los anuncios de vídeo se precargan en búfer mientras que las creatividades de los anuncios Flash se descargan. Los anuncios no se muestran hasta que se llama play(). El objeto contenedor es necesario únicamente para los anuncios de vídeo y no lo es para los anuncios Flash. Valores Video Utiliza NetStream para precargar el anuncio de vídeo en el búfer y reproducirlo. FLVPlayback Utiliza el componente FLVPlayback para precargar el anuncio de vídeo en el búfer y reproducirlo.
(void) play(container?:Object)	Se mostrarán los anuncios cuando se llame este método. Los anuncios Flash no necesitan ningún parámetro porque ya se utiliza Stage como área de visualización predeterminada. Los anuncios de vídeo requieren un parámetro de objeto contenedor puesto que se ejecutan en el reproductor de vídeo del editor. Valores Video Utiliza NetStream para precargar el anuncio de vídeo en el búfer y reproducirlo. FLVPlayback Utiliza el componente FLVPlayback para precargar el anuncio de vídeo en el búfer y reproducirlo. DisplayObjectContainer Utiliza DisplayObjectContainer para mostrar los anuncios Flash. El posicionamiento es relativo al contenedor de objetos de visualización proporcionado. Una vez se haya proporcionado un contenedor de objetos de visualización, ya no se puede modificar.
(void) unload()	Es posible que los anuncios hayan cargado creatividades en el tiempo de ejecución que deberán eliminarse correctamente cuando haya finalizado el anuncio. Esto es especialmente cierto para anuncios Flash en los que la descarga tiene como resultado la eliminación de creatividades de la lista de visualización. Se recomienda llamar a unload cuando el anuncio se haya visualizado y no vaya a utilizarse más.

Devoluciones de llamada

Se trata de eventos a los que se puede suscribir.

Nombre	Descripción
AdEvent.CONTENT_PAUSE_REQUESTED	Se llama a este evento cuando el reproductor de vídeo o el juego deben detener el contenido (normalmente debido a un clic o al inicio de un anuncio lineal).
AdEvent.CONTENT_RESUME_REQUESTED	Se llama a este evento cuando se permite al reproductor de vídeo o al juego reanudar el contenido (normalmente debido a la finalización de un anuncio lineal).
AdEvent.CLICK	Se llama a este evento cuando se ha hecho clic en un anuncio.
AdEvent.STARTED	Se llama a este evento cuando se ha iniciado un anuncio.
AdEvent.PAUSED	Se llama a este anuncio cuando se ha detenido un anuncio.
AdEvent.STOPPED	Se llama a este evento cuando se ha detenido un anuncio.

Código de ejemplo

Se debe cargar y mostrar el anuncio resultante.

function onAdsLoaded(adsLoadedEvent:AdsLoadedEvent):void
{
    // Obtener AdsManager
    _adsManager = adsLoadedEvent.adsManager;
    _adsManager.addEventListener(AdErrorEvent.AD_ERROR, onAdError);

    // Escuchar y responder a los eventos que requieran que se detenga el contenido o que se reanude su ejecución
    _adsManager.addEventListener(AdEvent.CONTENT_PAUSE_REQUESTED, onPauseRequested);
    _adsManager.addEventListener(AdEvent.CONTENT_RESUME_REQUESTED, onResumeRequested);

    // Comprobar si los vídeos cargados son de vídeo o flash
    if (_adsManager.type == AdsManagerTypes.VIDEO)
    {
        // Crear el administrador de anuncios de vídeo.
        var videoAdsManager:VideoAdsManager = _adsManager as VideoAdsManager;

        // Establecer un elemento visual que servirá para hacer el seguimiento de los clics de los anuncios de vídeo
        videoAdsManager.clickTrackingElement = <object>;

        // Eventos importantes de transferencia
        videoAdsManager.addEventListener(AdEvent.COMPLETE, onVideoAdComplete);
        videoAdsManager.addEventListener(AdEvent.CLICK, onVideoAdClicked);

        // Reproducir los anuncios.
        _adsManager.load(<flvPlayback>);
        _adsManager.play(<flvPlayback>);    
    }
    else if (_adsManager.type == AdsManagerTypes.FLASH)
    {
        // Crear el administrador de anuncios flash.
        var flashAdsManager:FlashAdsManager = _adsManager as FlashAdsManager;

        // Reproducir el anuncio.
        flashAdsManager.load(this);
        flashAdsManager.play(this);
    }  
}
function onAdError(adErrorEvent:AdErrorEvent):void
{
   log("Error de anuncio: " + adErrorEvent.error);
   // Reproducir contenido
}

Banners complementarios

Se puede insertar código de banners complementarios en su página que le permitirá mostrar anuncios de texto, imagen o flash relacionados mientras ejecuta un anuncio de vídeo. Estos anuncios complementarios a veces desencadenan ingresos adicionales puesto que permiten que más anunciantes participen en la subasta. No obstante, son opcionales.

Hay dos maneras de mostrar banners complementarios en AdSense para vídeo o AdSense para juegos.

Inserción en HTML: el banner complementario se encuentra próximo al área flash.
Inserción en Flash: el banner complementario se encuentra en el área flash.

Inserción en HTML

AdSense para vídeo y AdSense para juegos tienen requisitos específicos acerca de cómo insertar los SWF en el HTML. Y lo que es más importante, allowScriptAccess debe ajustarse en “always”. Así, el sistema AFG podrá detectar la URL de la página que realiza la solicitud de anuncio. Los anuncios no se publicarán en juegos si no podemos detectar la URL. Debemos poder detectar la URL de la página para ser capaces de proporcionar información a los anunciantes sobre dónde se están mostrando sus anuncios. La URL de la página también se utiliza con finalidades de revisión según la política y para mejorar la orientación contextual de los anuncios.

Si utiliza etiquetas HTML estándar para insertar su jugador, deberá incluir las etiquetas <object> y <embed> para ajustar allowScriptAccess correctamente tanto para IE (con la etiqueta <object>) como para Firefox (con la etiqueta <embed>).

Código de ejemplo

<object width="320" height="240" classid="clsid:D27CDB6E-AE6D-11cf-96B8-444553540000"
       id="NeedThisParam">
    <param name="movie" value="http://www.example.com/v/?i=11149286"
       type="application/x-shockwave-flash"></param>
    <param name="allowScriptAccess" value="always"></param>
    <param name="wmode" value="transparent"></param>
    <embed src="http://www.example.com/v/?i=11149286"
          type="application/x-shockwave-flash"
          allowScriptAccess="always"
          width="320"
          height="240">
    </embed>
</object>

Siguiente: Ejemplo de programa para precargar SWF para AdSense para juegos

¿Dispone de un sitio web con un tráfico superior a 300.000 visitas mensuales y todavía no es un editor de AdSense? Regístrese aquí para que el equipo de Google AdSense pueda contactarle por teléfono.

AdSense

Productos

AdSense para juegos (AFG)